10 ! POEGEN.GAM (POE-DIKT-GENERATOR-SPEL)
20 ! Bertil M}rtensson Word & Music LUND (Efter Ahl Basic Games 1)
30 ! F|r ABC 800-806.
40 ! --------------------------------------------
50 FLOAT : EXTEND : RANDOMIZE 
60 ; CHR$(12)
70 ; " POEGEN.GAM    skriver dikter i POEs anda ";TAB(80) ""
80 ; STRING$(80,61)
90 ; : ; : ; 
100 ; "\nskat antal dikter "; : INPUT X
110 PREPARE "PR:" AS FILE 1
120 FOR A1=1 TO X ! ANTALSOPERATOR ****
130   ; #1, : ; #1,
140   ; #1,TAB(10) "Datordikt i POE-stil" A1 "."
150   ; #1,
160   ! FOR-SLINGAN KAN B\RJA H[R, GER L[NGRE DIKT ****
170   GOTO 480
180   ON I GOTO 190,200,210,220,230
190   ; #1,"midnight dreary"; : GOTO 430
200   ; #1,"fiery eyes"; : GOTO 430
210   ; #1,"bird or fiend"; : GOTO 430
220   ; #1,"thing of evil"; : GOTO 430
230   ; #1,"prophet"; : GOTO 430
240   ON I GOTO 250,260,270,280,290
250   ; #1,"beguiling me"; : U=2 : GOTO 430
260   ; #1,"thrilled me"; : GOTO 430
270   ; #1,"still sitting..."; : GOTO 450
280   ; #1,"never flitting"; : U=2 : GOTO 430
290   ; #1,"burned"; : GOTO 430
300   ON I GOTO 310,320,330,340,350
310   ; #1,"and my soul"; : GOTO 430
320   ; #1,"darkness there"; : GOTO 430
330   ; #1,"shall be lifted"; : GOTO 430
340   ; #1,"quoth the raven"; : GOTO 430
350   IF U=0 GOTO 430
360   ; #1,"sign of parting"; : GOTO 430
370   ON I GOTO 380,390,400,410,420
380   ; #1,"nothing more"; : GOTO 430
390   ; #1,"yet again"; : GOTO 430
400   ; #1,"slowly creeping"; : GOTO 430
410   ; #1,"...evermore"; : GOTO 430
420   ; #1,"nevermore";
430   IF U=0 OR RND>.19 THEN 450
440   ; #1,","; : U=2
450   IF RND>.65 THEN GOTO 470
460   PRINT #1," "; : U=U+1 : GOTO 480
470   ; #1, : U=0
480   I=INT(INT(10*RND)/2)+1
490   J=J+1 : K=K+1
500   IF U>0 OR INT(J/2)<>J/2 THEN 520
510   ; #1,"     ";
520   ON J GOTO 180,240,300,370,530
530   J=0 : ; #1, : IF K>20 GOTO 550
540   GOTO 480
550   ; #1, : U=0 : K=0
560 NEXT A1 
566 ; #1,
567 ; #1,"Av Edwin Allan Poe"
570 CLOSE 1
580 ; : ; "Klart! Fler dikter (j/n)? "; : GET S$
590 S$=LEFT$(S$,1)
600 IF S$="j" OR S$="J" GOTO 10
610 END