10 REM Ins{nt av 1789
11 ! **********************************************************************
12 ! Program          ELIZA.800        Utg}va  1.1      1983-07-12
13 ! av "More BASIC Computer Games" av David Ahl, {ndrad av Karl-Gunnar Hultland
14 ! Ins{nd av Karl-Gunnar Hultland (581)
15 ! F|r ABC800C ABC802 ABC806, med ASCII-grafik
16 ! Testad p} ABC800C ABC806
17 ! Programmet kan l{tt {ndra till ABC800 M, ta bara bort n}gon rad med
18 ! ASCII-grafik!
19 ! **********************************************************************
20 ! [ndrad till ABC800 CHR och |versatt till svenska av Karl-Gunnar Hultand
21 ! [ngsdatan 4, 953 00  HAPARANDA, Tel 0922-10101
22 ! =================================
23 DEF FNInit
24   DIM I$=1000,P$=1000,C$=1000,\$=1000,In$=1
25   DIM S(40),R(40),N(40)
26   N1=40 : N2=14 : N3=119
27   Fr}ga=16
28   RESTORE 259
29   FOR X=1 TO N1
30     READ S(X),L : R(X)=S(X) : N(X)=S(X)+L-1
31   NEXT X 
32   ; CHR$(12);
33   ! ******** INSTRUCTIONS ********
34   PUT "HEJ JAG [R ELISABETH.VAD [R DITT PROBLEM"
35   ; 
36   GET A$ COUNT 0
37   RETURN 0
38 FNEND 
39 DEF FNIn
40   \$=""
41   ; STRING$(PEEK(65364),ASCII("+"));
42   ; "";
43   In$=""
44   WHILE In$<>CHR$(13)
45     GET In$
46     IF In$=CHR$(8) AND LEN(\$)<1 THEN 45
47     IF In$=CHR$(8) THEN ; CHR$(8,32,8); : \$=LEFT$(\$,LEN(\$)-1) : GOTO 45
48     IF ASCII(In$)>127 THEN 45
49     IF In$=CHR$(13) THEN ; CHR$(10); : GOTO 51
50     IF ASCII(In$)<32 THEN 45
51     ; In$;
52     \$=\$+In$
53   WEND 
54   \$=LEFT$(\$,LEN(\$)-1)
55   ; STRING$(PEEK(65364),ASCII("="));
56   I$=\$ : In$=""
57   I$="  "+I$+"  "
58   ! INGA APOSTROFER
59   FOR L=1 TO LEN(I$)
60   IF MID$(I$,L,1)<>"'" THEN NEXT L ELSE I$=LEFT$(I$,L-1)+RIGHT$(I$,L+1) : GOTO 59
61   IF INSTR(1,I$,"H]LL K[FT") THEN ; "H]LL K[FTEN..." : ; "o.k.!!!" : GOTO 65
62   IF I$=P$ THEN ; "Var sn{ll att inte upprepa dig!!" ELSE RETURN 0
63   PRINT GRED;"             ####"
64   GOTO 40
65   CLOSE 
66   END 
67 FNEND 
68 DEF FNKey
69   RESTORE 130
70   S=0
71   FOR K=1 TO N1
72     READ K$
73     IF S>0 THEN GOTO 76
74     L=INSTR(1,I$,K$)
75     IF L THEN S=K : T=L : F$=K$
76   NEXT K 
77   IF S>0 THEN K=S : L=T ELSE K=36
78   IF K=36 AND INSTR(1,I$,"?")<>0 THEN K=Fr}ga
79   \99=L : RETURN 0
80 FNEND 
81 DEF FNKonv
82   RESTORE 137
83   C$=" "+RIGHT$(I$,\99+LEN(F$))+" "
84   FOR X=1 TO N2/2
85     READ S$,R$
86     FOR L=1 TO LEN(C$)
87       IF L+LEN(S$)>LEN(C$) THEN 92
88       IF MID$(C$,L,LEN(S$))<>S$ THEN 92
89       C$=LEFT$(C$,L-1)+R$+RIGHT$(C$,L+LEN(S$))
90       L=L+LEN(R$)
91       GOTO 96
92       IF L+LEN(R$)>LEN(C$) THEN 96
93       IF MID$(C$,L,LEN(R$))<>R$ THEN 96
94       C$=LEFT$(C$,L-1)+S$+RIGHT$(C$,L+LEN(R$))
95       L=L+LEN(S$)
96     NEXT L 
97   NEXT X 
98   IF MID$(C$,1,2)="  " C$=RIGHT$(C$,2)
99   FOR L=1 TO LEN(C$)
100     IF MID$(C$,L,1)="!" C$=LEFT$(C$,L-1)+RIGHT$(C$,L+1) : GOTO 99
101   NEXT L 
102   RETURN 0
103 FNEND 
104 DEF FNReply
105   RESTORE 140
106   FOR X=1 TO R(K) : READ F9$ : NEXT X 
107   R(K)=R(K)+1 : IF R(K)>N(K) THEN R(K)=S(K)
108   IF INSTR(1,F9$,"*") RETURN -1
109   RETURN 0
110 FNEND 
111 DEF FNPrint
112   EXTEND : IF Flag=0 THEN PRINT F9$ : P$=I$ : RETURN 0
113   PRINT LEFT$(F9$,INSTR(1,F9$,"*")-1);C$
114   P$=I$ : RETURN 0
115 FNEND 
116 DEF FNMain
117   A=FNInit
118   A=FNIn
119   A=FNKey
120   Flag=FNReply
121   IF Flag A=FNKonv
122   A=FNPrint
123   GOTO 118
124   RETURN 0
125 FNEND 
126 ! ********************************
127 ! *****   START OF PROGRAM   *****
128 ! ********************************
129 A=FNMain ! Only one line
130 DATA "KAN DU","KAN JAG","DU [R","DU [R","JAG INTE","JAG K[NNER"
131 DATA "DU INTE","VARF\R KAN JAG INTE","[R DU","JAG KAN INTE","JAG [R","JAG [R"
132 DATA "DU","JAG VILL","VAD","HUR","VEM","VAR","N[R","VARF\R"
133 DATA "NAMN","D[RF\R","URS[KTA","DR\M","GODDAG","HEJ","KANSKE"
134 DATA " NEJ"," DIN","ALLTID"," TRO" ," LIK"," JA ","V[N"
135 DATA "DATOR","NOKEYFOUND"
136 DATA "IDIOT","FLICKOR","POJKAR","ARBETE"
137 DATA " MITT "," DITT ","VAR ","VAR "," DU "," JAG ","DIN","MIN"
138 DATA " JAG HAR "," DU HAR "," JAG [R "," DU [R "
139 DATA " MIG "," DIG ","  "
140 DATA "TROR DU INTE ATT JAG KAN*"
141 DATA "KANSKE DU SKULLE VILJA KUNNA*"
142 DATA "VILL DU ATT JAG SKULLE KLARA*"
143 DATA "KANSKE DU INTE VILL*"
144 DATA "BLIR DU N\JD AV ATT TRO ATT JAG [R*"
145 DATA "VAD F]R DIG ATT TRO ATT JAG [R*"
146 DATA "ROAR DET DIG ATT TRO ATT JAG [R*"
147 DATA "KANSKE DU SKULLE VILJA VARA*"
148 DATA "\NSKAR DU N]GON G]NG ATT DU VAR*"
149 DATA "KAN DU VERKLIGEN INTE*"
150 DATA "VARF\R KAN DU INTE*"
151 DATA "SKULLE DU \NSKA ATT DU KUNDE*"
152 DATA "OROAR DET DIG?"
153 DATA "BER[TTA MER OM DEM K[NSLORNA"
154 DATA "K[NNER DU OFTA ATT*"
155 DATA "GILLAR DU ATT K[NNA*"
156 DATA "TROR DU VERKLIGEN ATT JAG INTE*"
157 DATA "KANSKE JAG SNART SKA*"
158 DATA "VILL DU ATT JAG SKA*"
159 DATA "TROR DU ATT DU SKULLE KUNNA*"
160 DATA "VARF\R KAN DU INTE*"
161 DATA "VARF\R [R DU INTRESERAD OM JAG [R ELLER INTE [R*"
162 DATA "SKULLE DU F\REDRA OM JAG INTE VAR*"
163 DATA "KANSKE I DINA FANTASIER JAG [R*"
164 DATA "HUR VET DU ATT DU INTE KAN*"
165 DATA "HAR DU F\RS\KT"
166 DATA "NU KANSKE DU KAN*"
167 DATA "KOM DU TILL MIG F\R ATT DU [R*"
168 DATA "HUR L[NGE HAR DU VARIT*"
169 DATA "TROR DU ATT DET [R NORMALT ATT VARA*"
170 DATA "GILLAR DU ATT VARA*"
171 DATA "VI DISKUTERADE DIG--- INTE MIG"
172 DATA "OH!,JAG*"
173 DATA "DU TALAR V[L INTE OM MIG??"
174 DATA "VAD SKULLE DET BETYDA F\R DIG OM DU FICK*"
175 DATA "VARF\R VILL DU INTE*"
176 DATA "T[NK OM DU SNART FICK*"
177 DATA "T[NK OM DU ALDRIG KOMMER ATT F]*"
178 DATA "JAG VILL OCKS] N]GON G]NG*"
179 DATA "VARF\R FR]GAR DU"
180 DATA "INTRESERAR DEN D[R FR]GAN DIG?"
181 DATA "VILKET SVAR SKULLE GL[DJA DIG MEST?"
182 DATA "VAD TROR DU SJ[LV?"
183 DATA "T[NKR DU OFTA P] S]DANA FR]GOR"
184 DATA "VAD [R DET SOM DU VERKLIGEN VILL VETA"
185 DATA "HAR DU FR]GAT N]GON ANNAN?"
186 DATA "HAR DU FR]GAT S]DANA H[R FR]GOR TIDIGARE??"
187 DATA "VAD MERA T[NKER DU P] N[R DU FR]GAR DET D[R?"
188 DATA "NAMN INRESSERAR MIG INTE"
189 DATA "JAG BRYR MIG INTE OM NAMN MEN F\RTS[TT [ND]"
190 DATA "[R DET DEN RIKTIGA ORSAKEN?"
191 DATA "KAN DU INTE KOMMA P] N]GRA ANDRA ORSAKER?"
192 DATA "F\RKLARAR DEN D[R ORSAKEN N]GOT ANNAT?"
193 DATA "VILKA ANDRA ORSAKER KAN DET FINNAS?"
194 DATA "VAR SN[LL ATT INTE BE OM URS[KT"
195 DATA "URS[KTER [R INTE N\DV[NDIGA"
196 DATA "VILKA K[NSLOR HAR DU N[R DU BER OM URS[KT"
197 DATA "VAR INTE S] DEFENSIV!"
198 DATA "VAD F]R DEN D[R DR\MMEN DIG ATT T[NKA P]?"
199 DATA "DR\MMER DU OFTA"
200 DATA "VILKA PERSONER UPPTR[DER I DINA DR\MMAR?"
201 DATA "ST\R DINA DR\MMAR DIG N]GONG]NG?"
202 DATA "HEJ!! HUR M]R DU..VAR SN[LL ATT BER[TTA F\R MIG OM DINA PROBLEM."
203 DATA "DU VERKAR INTE RIKTIGT S[KER"
204 DATA "VARF\R DEN D[R OS[KRA TONEN?"
205 DATA "KAN DU INTE VARA MERA POSITIV?"
206 DATA "[R DU INTE S[KER?"
207 DATA "VET DU INTE?"
208 DATA "S[GER DU NEJ BARA F\R ATT VARA NEGATIV?"
209 DATA "DU [R LITE NEGATIV"
210 DATA "VARF\R INTE?"
211 DATA "[R DU S[KER
212 DATA "VARF\R 'NEJ'?"
213 DATA "VARF\R BRYR DU DIG OM MIN*"
214 DATA "HUR [R DET MED DIN EGEN*"
215 DATA "KAN DU N[MNA ETT EXEMPEL?"
216 DATA "N[R?"
217 DATA "VAD T[NKER DU P]?"
218 DATA "VERKLIGEN,ALLTID?"
219 DATA "TROR DU VERKLIGEN DET?"
220 DATA "MEN DU [R INTE S[KER ATT DU*"
221 DATA "TVIVLAR DU ATT DU*"
222 DATA "P] VILKET S[TT?"
223 DATA "VILKA LIKHETER SER DU?"
224 DATA "VAD F]R LIKHETEN DIG ATT T[NKA P]?"
225 DATA "VILKA ANDRA SAMBAND SER DU?"
226 DATA "KAN DET VERKLIGEN FINNAS ETT SAMBAND?"
227 DATA "HUR?"
228 DATA "DU VERKAR GANSKA POSITIV"
229 DATA "[R DU S[KER?"
230 DATA "JAHA"
231 DATA "JAG F\RST]R"
232 DATA "VARF\R B\RJAR DU ATT PRATA OM V[NNER?"
233 DATA "OROAR DINA V[NNER DIG?"
234 DATA "BR]KAR DINA V[NNER MED DIG?"
235 DATA "[R DU S[KER ATT DU HAR N]GRA V[NNER?"
236 DATA "IMPONERAR DU P] V[NNER?"
237 DATA "KANSKE DIN K[RLEK TILL DINA V[NNER OROAR DIG"
238 DATA "OROAR DATORER DIG?"
239 DATA "[R DET MIG DU MENAR?"
240 DATA "BLIR DU SKR[MD AV MASKINER?"
241 DATA "VARF\R N[MNER DU DATORER?"
242 DATA "VAD TROR DU ATT MASKINER HAR MED DINA PROBLEM ATT G\RA?"
243 DATA "TROR DU INTE ATT DATORER KAN HJ[LPA M[NNISKOR?"
244 DATA "VAD [R DET MED MASKINER SOM OROAR DIG?"
245 DATA "S[G,HAR DU N]GRA PSYKISKA PROBLEM?"
246 DATA "VAD F]R DET DIG ATT T[NKA P]?"
247 DATA "FORTS[TT"
248 DATA "JAG [R INTE S] S[KER ATT JAG F\RST]R DIG"
249 DATA "RENSA UPP I DINA TANKAR"
250 DATA "KAN DU UTVECKLA DET LITE N[RMARE"
251 DATA "DET L]TER GANSKA INTRESSANT"
252 DATA "DET [R DU SOM HAR PROBLEM,INTE JAG!!"
253 DATA "DET [R BRA ATT DU GER UTLOPP F\R DINA AGRESSIONER."
254 DATA "HAR DU F\RS\KT ATT [GNA DIG LITE MER ]T DITT ARBETE?"
255 DATA "HAR DU KONTAKT PROBLEM?"
256 DATA "HAR DU PROVAT MED SUBSTITUT?"
257 DATA "SKAPAR DET PROBLEM MED DITT ARBETE?"
258 DATA "HAR DU KONTAKTPROBLEM P] DIN ARBETSPLATS?"
259 DATA 1,3,4,2,6,4,6,4,10,4,14,3,17,3,20,2,22,3,25,3
260 DATA 28,4,28,4,32,3,35,5,40,9,40,9,40,9,40,9,40,9,40,9
261 DATA 49,2,51,4,55,4,59,4,63,1,63,1,64,5,69,5,74,2,76,4
262 DATA 80,3,83,7,90,3,93,6,99,7,106,7
263 DATA 113,2,115,3,115,3,118,2
264 END