2 ! +++++++++++++++++++++++++++++++++++
3 ! Program ....     MILJON[R
4 ! Utg}va  1.01     1983-06-12
5 ! fr}n BASIC COMPUTER GAMES
6 ! {ndrat av Karl Hultland(581)
8 ! Ins{nt av Karl Hultland
9 ! +++++++++++++++++++++++++++++++++++
10 ; CHR$(12)
11 RANDOMIZE 
12 O=-1
13 DIM A$(20),Z$(1),M$(36),S(9),Q(16)
14 FOR I=1 TO 4
15   LET S(I)=150
16 NEXT I 
17 INPUT "VAD HETER DU?";A$
18 ; 
19 ; "O.K. " A$ " DETTA [R DITT NYA LIV!"
20 M$="JANFEBMARAPRMAJJUNJULAUGSEPOKTNOVDEC"
21 IF RND>.5 GOTO 24
22 ; "P] EN STOR G]RD";
23 GOTO 25
24 ; "I EN LITEN STAD";
25 T=INT(RND*12)+1
26 ; " DEN ";INT(RND*28)+1;MID$(M$,3*T-2,3);" 1980"
27 ; " BLEV ";A$;" F\DD"
28 ; "DINA F\R[LDRAR [R V[LDIGT ";
29 IF RND>.5 GOTO 33
30 ; "RIKA."
31 M=INT(RND*5000)+10000
32 GOTO 35
33 ; "FATTIGA."
34 M=INT((RND+RND)/2*1000)
35 T=INT(RND*12)+1
36 Y=1996+INT(RND*10)
37 ; "DEN ";T*2;MID$(M$,T*3-2,3);" ";Y;" L[MNAR DU"
38 ; "DINA F\R[LDRAR MED ";M;" KRONOR."
39 GET \$
40 Y=Y+INT(RND*3)+1
41 GOSUB 69
42 FOR J=1 TO 13 : GET \$ : ; CHR$(12)
43   IF (J/3)-INT(J/3)+E=0 GOSUB 69
44   D=INT(28*RND)+1
45   M1=(INT(12*RND)+1)*3
46   ; 
47   ; MID$(M$,M1-2,3);D;",";Y
48   IF Y-1980<70 THEN 52
49   IF RND>.5 GOTO 52
50   ; "DU [R D\D VID EN ]LDER AV " Y-1980 "."
51   GOTO 237
52   IF M>=0 THEN 56
53   I=INT(.07*Y9*(-M))
54   M=M-I
55   ; "R[NTORNA P] DINA L]N [R " I " OCH DU HAR " M " KR."
56   Q=INT(13*RND)+1
57   IF Q(Q)=1 THEN 56
58   Q(Q)=1
59   ON Q GOTO 90,102,111,123,128,143,153,184,193,206,212,224,228
60   ; "DU HAR NU " M " KR"
61   IF O=-2 GOTO 153
62   IF J=1 THEN 65
63   M=M+(E-C)*Y9
64   ; "MED DINA UTGIFTER OCH DIN L\N HAR DU " M " KR."
65   Y9=INT(RND*6)+5
66   Y=Y+Y9
67 NEXT J 
68 GOTO 50
69 REM 
70 ; " DU F]R ETT JOBB SOM ";
71 ON INT(RND*5)+1 GOTO 72,75,78,81,84
72 ; "L[RARE";
73 E=INT(RND*4000)+17000
74 GOTO 86
75 ; "JURIST";
76 E=INT(RND*40000)+80000
77 GOTO 86
78 ; "DATOR PROGRAMMERARE";
79 E=INT(RND*5000)+20000
80 GOTO 86
81 ; "BUSS CHAUFF\R";
82 E=INT(RND*2000)+16000
83 GOTO 86
84 ; "DIREKT\R";
85 E=INT(RND*100000)+100000
86 C=E-10000+INT((RND+RND)*5000)
87 ; ". DU K[NAR " E " KR/]R."
88 ; "DU JUSTERAR DINA UTGIFTER TILL " C " KR/]R."
89 RETURN 
90 ; "DU FAR TILL LAS VEGAS F\R ATT SPELA.    HUR MYCKET SATSAR DU?";
91 INPUT S
92 ; 
93 IF S<=0 GOTO 60
94 IF RND>.7 THEN 98
95 S2=-INT(RND*S)
96 ; "HA! HA! DU F\RLORADE ";-S2
97 GOTO 100
98 S2=INT((RND+RND)*S)
99 ; " DU VANN " S2
100 M=M+S2
101 GOTO 60
102 ; "DU [R ERBJUDEN ATT K\PA ETT MYNT SOM" : ; "MAN TROR [R V[RT 100000 KR."
103 ; "K\PER DU DET?";
104 INPUT Z$ : Z$=Z$+"N"
105 ; 
106 V7=INT(RND*200000+1)
107 IF LEFT$(Z$,1)<>"J" 109
108 M=M-100000+V7
109 ; "MYNTET [R V[RT " V7
110 GOTO 60
111 ; "DU [R ALLVARLIGT SJUK."
112 ; "DU HAR ";
113 ON (INT(RND*3)+1) GOTO 114,116,118
114 ; "DEN ASIATISKA REGIONAL HYPNOTISKA S\MN  SJUKAN.";
115 GOTO 119
116 ; "DATOR FEBER."
117 GOTO 119
118 ; "SMITTSAM,D\DLIG,]TERKOMMANDE,KRONISK    BILDSK[RMS ALLERGI."
119 U=INT(RND*1000)+500
120 M=M-U
121 ; "DIN SJUKDOM KOSTAR DIG ";U " KR"
122 GOTO 60
123 F=INT(RND*100000)+1
124 C8=INT(F/2)-INT(RND*(F/2))
125 ; "DIN MORFAR ULRIK HAR JUST D\TT OCH      L[MNAT DIG " F " KR. MEN BEGRAVNINGS      KOSTNADERNA [R " C8 " KR."
126 M=M-C8+F
127 GOTO 60
128 IF E=0 THEN GOTO 90
129 ; "NYHETER FR]N DIN ARBETSGIVARE:"
130 ON (INT(RND*3)+1) GOTO 131,135,139
131 L=INT(RND*3000)+1
132 E=E-L
133 ; "DIN L\N HAR S[NKTS MED " L " KR DU K[NAR  NU " E " KR."
134 GOTO 60
135 ; "DU [R AVSKEDAD! (HA HA!)"
136 E=0
137 C=INT(C/4)
138 GOTO 60
139 R6=INT(RND*5000)+1
140 E=E+R6
141 ; "DIN L\N AR H\JTS MED " R6 " DU K[NAR NU  " E " KR/]R"
142 GOTO 60
143 ; "DIN L[KARE S[GER ATT DU BEH\VER SEMESTERFAR DU?";
144 INPUT Z$ : Z$=Z$+"J"
145 ; 
146 V=INT(RND*2000)+1000
147 IF LEFT$(Z$,1)="N" 150
148 ; "BRA SEMESTERN KOSTAR " V " KR."
149 GOTO 151
150 ; "DU HAR JUST F]TT ETT NERV\ST SAMMANBROTTKOSTNADER F\R ATT VILA UPP DIG " V " KR."
151 M=M-V
152 GOTO 60
153 FOR I=1 TO 4
154   S(I)=INT((INT(RND*100)+100+2*S(I))/3)
155 NEXT I 
156 ; "#    NAMN       PRIS     ANTAL"
157 ; "1   LUXOR       ";S(1);"   ";S(5)
158 ; "2   CROMENCO    ";S(2);"   ";S(6)
159 ; "3   EPSON       ";S(3);"   ";S(7)
160 ; "4   SAS         ";S(4);"   ";S(8)
161 IF S(9)=1 GOTO 241
162 ; "K\PER/S[LJER ELLER INGET(K,S,I)";
163 INPUT Z$ : Z$=Z$+"I"
164 ; : Z$=LEFT$(Z$,1)
165 IF Z$="S" GOTO 174
166 IF Z$="I" GOTO 180
167 ; "AKTIE NR,ANTAL";
168 INPUT S3,S(0)
169 ; 
170 S(4+S3)=S(4+S3)+S(0)
171 O=-2
172 M=M-S(S3)*S(0)-100
173 GOTO 162
174 ; "AKTIE NR,ANTAL";
175 INPUT S2,S5
176 IF S5>S(4+S2) 174
177 S(4+S2)=S(4+S2)-S5
178 M=M+S(S2)*S5-100
179 GOTO 162
180 S1=S(5)+S(6)+S(7)+S(8)
181 IF S1>0 GOTO 62
182 O=-1
183 GOTO 62
184 ; "NYHETER FR]N TT!!";
185 IF RND<.5 THEN 188
186 ; "EN JORDB[VNING HAR JUST F\RST\RT " A$ "'S HUS";
187 GOTO 189
188 ; "EN" RED "RYMDF[RJA" WHT "HAR JUST KRASHAT     I " A$ "'S HUS."
189 D8=INT(RND*50000)+1
190 M=M-D8
191 ; "VARVID DET UPPSTOD SKADOR F\R " D8
192 GOTO 60
193 ; "]H DU FICK JUST ";
194 IF Y-1980<55 THEN 200
195 IF RND>.4 THEN 198
196 ; "CANCER";
197 GOTO 201
198 ; "EN HJ[RT ATTACK";
199 GOTO 201
200 ; "LEUKEMI";
201 M2=INT(RND*5000)+1000
202 M=M-M2
203 ; "   L[KARR[KNINGEN [R " M2
204 IF RND<.5 THEN 50
205 GOTO 60
206 ; "DU HAR JUST R]KAT UT F\R EN BILOLYCKA   REPARATIONER M.M. G]R P]"
207 M3=INT(RND*3000)+1000
208 Q7=INT(RND*5000)+1000
209 ; M3+Q7 " KR."
210 M=M-M3-Q7
211 GOTO 60
212 IF E=0 THEN 102
213 E2=10000+INT(RND*5000)
214 ; "DU [R ERBJUDEN ETT ANNAT JOBB MED EN L\NP] " E2 "KR/]R"
215 ; "SKULLE DU VILJA JOBBA SVART";
216 INPUT Z$
217 ; 
218 IF Z$="N" THEN 60
219 ON INT(RND*3)+1 GOTO 220,135,222
220 E=E+E2
221 GOTO 60
222 ; "P] GRUND AV \VERANSTR[NGNING F]R DU ";
223 GOTO 198
224 R2=INT(RND*10000)+5000
225 M=M-R2
226 ; "DU HAR BLIVIT R]NAD P] GODS V[RT " R2 "KR"
227 GOTO 60
228 IF O=-1 GOTO 143
229 IF RND>.7 GOTO 143
230 B4=INT(RND*4)+1
231 ; "B\RS KRASH ALLA DINA " S1 " AKTIER [R NU  BARA V[RDA "
232 ; B4 "KR. OCH DU M]STE S[LJA DEM"
233 ; "F\R EN SUMMA AV " S1*B4
234 M=M+S1*B4
235 O=-1
236 GOTO 60
237 ; "DU HADE ";M
238 IF O=-1 GOTO 243
239 S(9)=1
240 GOTO 153
241 M=M+S(1)*S(5)+S(2)*S(6)+S(3)*S(7)+S(4)*S(8)
242 ; "MED AKTIERNAS V[RDE HAR DU " M " KR."
243 IF M<0 GOTO 248
244 IF M<500000 GOTO 250
245 IF M<1.E+06 GOTO 252
246 ; "DU VANN " A$ " DU VAR EN MILJON[R"
247 GOTO 253
248 ; "DU DIN #$%&'*!!! NU M]STE DIN FATTIGA   FAMILJ BETALA AV DINA SKULDER."
249 GOTO 253
250 ; "INTE ILLA " A$
251 GOTO 253
252 ; "GANSKA N[RA " A$ " KANSKE I N[STA LIV."
253 ; "TACK F\R ATT DU HAR SPELAT MILJON[R " A$
254 END