10 ! GISSAORD.800
20 ! Id` enligt R&TV 
30 ! Bearbetat av B M}rtensson Word & Music Lund.
40 ! ABC 800-802-806 80 tecken.
60 INTEGER : EXTEND : RANDOMIZE 
70 ; CHR$(12.)
80 ; CUR(0.,0.) " GISSAORD.800       Bokstavsomkastning "; : ; TAB(80.) ""
90 ; STRING$(80.,61.)
100 ; : ; : ; 
110 ; "I det h{r spelet matar du in ett eget ord medan motspelaren"
120 ; "ser bort. Datorn ger sedan honom ordet med blandade bokst{ver."
130 ; : ; "Vid r{tt gissad bokstav st}r den kvar ! "
140 ; : ; "Fel gissning ger minuspo{ng."
150 ; 
160 ; "N{r ordet {r klart skrivs antalet felaktiga gissningar ut."
170 ; : ; 
180 ; "Tryck ner valfri tangent f|r start. "; : GET S$
190 DIM B$(100.)
200 ; CHR$(12.)
210 INPUT "Skriv in det hemliga ordet (+ Return) "X$
220 REM 
230 ; CHR$(12.)
240 L.=LEN(X$)
250 F.=0. ! NOLLST[LL FEL
260 S.=1. ! ]TERST[LL TILL 1A POS
270 FOR I.=1. TO L. ! T\M B$(k)
280   B$(I.)=""
290 NEXT I. 
300 REM 
310 ! Blanda
320 FOR I.=1. TO L. : REM ** G] IGENOM DET HEMLIGA ORDET
330   N.=INT(RND*L.+1.) : REM ** SLUMPTAL = NR P] TECKEN I ORDET
340   IF B$(N.)<>"" GOTO 330 : REM ** V[LJ NYTT NR OM DET [R ANV[NT
350   B$(N.)=MID$(X$,I.,1.) : REM ** FYLL P] MED SLUMPVALD BOKSTAV
360 NEXT I. 
370 REM 
380 FOR I.=1. TO L. : REM ** SKRIV UT DET BLANDADE ORDET
390   ; B$(I.);
400 NEXT I. 
410 ; 
420 GET S$
430 REM 
440 IF S$=MID$(X$,S.,1.) GOTO 490 : REM ** HOPPA VID R[TT GISSNING
450 REM 
460 F.=F.+1. : REM ** HIT KOMMER MAN BARA VID FEL
470 GOTO 420 : REM ** H[MTA NY GISSNING
480 REM 
490 ; S$; : REM ** HIT KOMMER MAN VID R[TT GISSNING
500 IF S.<L. GOTO 590 : REM *** HOPPA OM ORDET EJ KLART
510 REM 
520 ; : ; : REM ** HIT KOMMER MAN N[R ORDET [R KLART
530 ; "R[TT SVAR!";CHR$(7.)
540 ; "Bara " F. " fel!"
550 ; : ; : ; : ; 
560 ; "Fler ord (J/N)?"; : GET Q$
570 IF Q$="J" OR Q$="j" GOTO 200 ELSE 610
580 REM 
590 S.=S.+1. : REM ** HIT KOMMER MAN N[R FLER TECKEN
600 GOTO 420 : REM ** N[STA GISSNING
610 END