1 REM Ins{nd av J|rgen Hansen <5844>    1986-05-21 21.21.44
10 ! +++++++++++++++++++++++++++++++++++++++++++++++++
20 ! Program    WORLDPOW.806
30 ! VER 1.3      86-05-17
40 ! av    (C) Odd Rolander 
50 ! Mod. av Nils H{ggblom
60 ! Screening Tom Sj|berg 2401
70 ! Konverterad till 80X-serien av J|rgen Hansen 5844
80 ! +++++++++++++++++++++++++++++++++++++++++++++++++
90 ; CHR$(12) : RANDOMIZE : INTEGER ! : WIDTH 40 : ATTRIBUTE 0
100 W=3 : S$="KUSTEN"
110 DIM A.(10,10),C.(10,10),N$(10),D$(5),L$(5)
120 DATA N. AMERIKA,AUSTRALIEN,S. AMERIKA,SOVJET,JAPAN,AFRIKA
130 DATA KOREA,KINA,SVERIGE,ENGLAND,TRUPPER,FLYG,ARTILLERI
140 DATA TANKS,RAKETER,NORD,SYD,\ST,V[ST
150 FOR X=1 TO 10 : READ N$(X) : NEXT X 
160 FOR X=1 TO 5 : READ D$(X) : NEXT X 
170 FOR X=1 TO 4 : READ L$(X) : NEXT X 
180 FOR X=1 TO 10 : C.(X,1)=INT((5000*RND)+5000)*10 : NEXT X 
190 FOR X=1 TO 10 : FOR J=2 TO 5 : C.(X,J)=INT(50*RND)+25 : NEXT J : NEXT X 
200 FOR X=1 TO 10 : FOR J=6 TO 10 : C.(X,J)=INT(4*RND)+1 : NEXT J : NEXT X 
210 FOR X=1 TO 5 : FOR J=1 TO 10 : A.(X,J)=C.(X,J) : C.(X,J)=0 : NEXT J : NEXT X 
220 ; "     ------------------------------"
230 ; "     *** W O R L D    P O W E R ***"
240 ; "     ------------------------------"
250 ; : ; ;'V{rlden {r delad i tv} maktblock och tredje' : ;'v{rldskriget har brutit ut.' : ; 
260 ; 'Du har nu den |vergripande makten |ver' : ;'det ena blocket.Du skall genom strate-' : ;'giska "man|vrer"';
270 ; ' f|ra det egna blocket' : ;'till seger.' : ; 
280 Y6=Y6+1 : GOSUB 1590
290 ON ERROR GOTO 290 : ; : ; "MAN\VER "; : INPUT M
300 IF M>5 OR M<(1) 280
310 ON M GOTO 570,320,400,650,800
320 GOSUB 1560
330 ON ERROR GOTO 320 : ; : ; "LAND "; : INPUT R
340 IF R>10 OR R<1 THEN 330
350 ; CHR$(12) "STATUSRAPPORT: " N$(R)
360 ; "F\RSVAR" TAB(14) "ANTAL" : ; : FOR X=1 TO 5
370   ; D$(X) TAB(13) A.(R,X);TAB(28);
380   IF C.(R,X+5)<>0 ; L$(C.(R,X+5)) ELSE ; '----'
390 NEXT X : GOTO 280
400 GOSUB 1560
410 ON ERROR GOTO 410 : ; : ; "ANGE L[NDER:(FR]N,TILL)" : INPUT F,T
420 IF F>10 OR F<1 OR T>10 OR T<(1) 410 ELSE GOSUB 1570
430 ON ERROR GOTO 430 : ; : ; "VILKA STYRKOR "; : INPUT D
440 IF D<1 OR D>(5) 430
450 ON ERROR GOTO 450 : ; : ; "VILKET ANTAL (Max" A.(F,D) ")"; : INPUT Q.
460 IF A.(F,D)>=(Q.) 480
470 ; "DU HAR BARA" A.(F,D) " " D$(D) " I " N$(F) : GOTO 280
480 IF 20000>A.(F,D) 490 ELSE IF Q.<20000 ; 'DU M]STE FLYTTA MINST 20000 TRUPPER.' : GOTO 280 ELSE 500
490 IF A.(F,D)<>(Q.) ; "DU M]STE FLYTTA ALLA " D$(D) : GOTO 280
500 A.(T,D)=A.(T,D)+Q. : A.(F,D)=A.(F,D)-Q. : GOSUB 1580
510 ON ERROR GOTO 510 : ; : ; "ANGE GR[NS/KUST "; : INPUT L
520 IF L<1 OR L>(4) 510
530 A.(T,D+5)=L
540 IF INT(RND*100)>(25) 560
550 GOSUB 1320
560 GOTO 280
570 ; CHR$(12) TAB(12) "--- GLOBAL RAPPORT ---"
580 ; : ; "LAND" TAB(12) "EG.TR." TAB(20) "FI.TR." TAB(27) "EG.LAND ?" : ; 
590 FOR X=1 TO 10 : ; N$(X) TAB(11) A.(X,1);TAB(19) C.(X,1);TAB(27);
600   K2=0 : FOR F2=1 TO 5 : IF C.(X,F2)<>0 K2=K2+1
610   NEXT F2 
620   IF K2>0 ; "NEJ" ELSE ; "JA"
630 NEXT X 
640 GOTO 280
650 GOSUB 1560
660 ON ERROR GOTO 660 : ; : ; "ANGE L[NDER:(FR]N,TILL) "; : INPUT F,T
670 IF F>10 OR F<1 OR T>10 OR T<(1) 660
680 IF A.(F,2)>=(10) 700
690 ; "DU HAR INTE TILLR[CKLIGT FLYG I ";N$(F) : GOTO 280
700 A.(F,2)=A.(F,2)-10
710 ; : ; : ; : ; "SPIONRAPPORT: " N$(T)
720 IF INT(RND*100)>20 THEN 750
730 IF INT(50*RND)<26 ; "ALLA PLAN F\RLORADE \VER HAVET" : GOTO 280
740 ; "PLANEN NEDSKJUTNA \VER ";N$(T) : GOTO 280
750 ; : ; "F\RSVAR" TAB(13) "ANTAL" TAB(20) "BEL[GENHET" : ; : FOR X=1 TO 5
760   ; D$(X) TAB(12) C.(T,X);TAB(20);
770   IF C.(T,X+5)<>0 ; L$(C.(T,X+5)) : GOTO 790
780   ; 
790 NEXT X : GOTO 280
800 K=0 : FOR X=1 TO 10 : FOR J=1 TO 5
810     IF A.(X,J)<>(0) 890
820 NEXT J : NEXT X : IF K>(0) 800
830 K=0 : H=0 : FOR X=1 TO 10 : FOR J=1 TO 5
840     IF C.(X,J)<>0 K=K+1
850     IF A.(X,J)<>0 H=H+1
860 NEXT J : NEXT X : IF K=(0) 1510
870 IF H=(0) 1480
880 GOTO 280
890 C=1
900 IF C.(X,C)<>(0) 930
910 C=C+1 : IF C=(6) 820
920 GOTO 900
930 IF A.(X,J+5)<>C.(X,C+5) 910
940 K=K+1 : ; : ; : ; : ; CHR$(7) "STRID I " N$(X);
950 ; " P] " L$(A.(X,J+5)) S$ "!"
960 ; "FIENDE " D$(C) TAB(18) "EGNA " D$(J)
970 O.=C.(X,C) : O1.=A.(X,J) : E.=O. : E1.=O1.
980 IF J=1 IF C<>(1) 1180
990 IF C=1 IF J<>(1) 1250
1000 ; E.;TAB(18) E1.
1010 GOSUB 1420
1020 IF E1.=(0) E8=1 : GOTO 1070
1030 IF E.=(0) E8=0 : GOTO 1070
1040 IF E1.>(E.*1.7) E8=0 : GOTO 1070
1050 IF E1.>(E.*1.5) E8=1 : GOTO 1070
1060 GOTO 1000
1070 ; E.;TAB(18) E1. : ; : ; "***** SEGER F\R ";
1080 IF E8=1 ; "FIENDEN I "; : GOTO 1100
1090 ; "EGNA TRUPPER I ";
1100 ; N$(X) : ; "P] " L$(A.(X,J+5)) S$
1110 ; "TOTALA F\RLUSTER: "
1120 ; "FIENDE " D$(C) " :  " O.-E.
1130 ; "EGNA   " D$(J) " :  " O1.-E1.
1140 IF E8=1 C.(X,J)=C.(X,J)+A.(X,J) : A.(X,J)=0 : GOTO 1170
1150 A.(X,C)=A.(X,C)+C.(X,C) : C.(X,C)=0 : A.(X,C+5)=C.(X,C+5)
1160 ; E.;" " D$(C) " BLEV TILLF]NGATAGNA." : ; "TRYCK EN TANGENT "; : GET H$ : GOTO 820
1170 C.(X,J+5)=A.(X,J+5) : ; "TRYCK EN TANGENT "; : GET H$ : GOTO 820
1180 ; E.;TAB(18) E1.
1190 GOSUB 1420
1200 IF E.=(0) E8=0 : GOTO 1070
1210 IF E1.=(0) E8=1 : GOTO 1070
1220 IF E1./1000>E. E8=0 : GOTO 1070
1230 IF E.>(E1.*1000) E8=1 : GOTO 1070
1240 GOTO 1180
1250 ; E.;TAB(18) E1.
1260 GOSUB 1420
1270 IF E.=(0) E8=0 : GOTO 1070
1280 IF E1.=(0) E8=1 : GOTO 1070
1290 IF E1./1000>E. E8=1 : GOTO 1070
1300 IF E1.>(E.*1000) E8=1 : GOTO 1070
1310 GOTO 1250
1320 R=INT(100*RND)+1 : X2=INT(10*RND)+2 : IF D=1 X2=INT(100*RND)+2
1330 IF A.(T,D)<=X2 X2=A.(T,D)
1340 A.(T,D)=A.(T,D)-X2
1350 IF R<(33) 1400
1360 IF R<(66) 1410
1370 ; "BAKH]LL UNDER TRANSPORT"
1380 ; "DU F\RLORADE JUST" X2 " " D$(D)
1390 ; "TOTALT ANL[NDA I " N$(T);"= " A.(T,D) : RETURN 
1400 ; "GERILLA P] " L$(A.(T,D+5))+S$ : GOTO 1380
1410 ; "STORM S[NKER ETT FARTYG" : GOTO 1380
1420 E.=E.-INT((E./3)*RND)-2
1430 IF E.<=0 E.=0
1440 E1.=E1.-INT((E1./3)*RND)-2
1450 IF E1.<=(0) E1.=0
1460 A.(X,J)=E1. : C.(X,C)=E.
1470 RETURN 
1480 ; : ; : ; "SORRY, DU MISSLYCKADES."
1490 ; "ALLA DINA STYRKOR [R SLAGNA" : ; 
1500 END 
1510 ; CHR$(12) "---------------------"
1520 ; "G R A T U L E R A R !"
1530 ; "---------------------"
1540 ; : ; "DU HAR ER\VRAT V[RLDEN MED" Y6 " MAN\VRAR."
1550 ; : ; "TRYCK EN TANGENT "; : GET H$ : GOTO 570
1560 ; : FOR X=1 TO 10 : ; X ') ' N$(X) : NEXT X : RETURN 
1570 ; : FOR X=1 TO 5 : ; X ') ' D$(X) : NEXT X : RETURN 
1580 ; : FOR X=1 TO 4 : ; X ') ' L$(X) : NEXT X : RETURN 
1590 ; STRING$(39,45) : ; '1) GLOBAL RAPPORT'
1600 ; '2) STATUSRAPPORT F\R VALFRITT LAND'
1610 ; '3) FLYTTA STYRKOR'
1620 ; '4) FLYGOPERATION'
1630 ; '5) STRID (med styrkorna i nuv.l{ge)'
1640 RETURN