100 ! ALFA.BAS
110 ! Ett program som testar hur snabbt du skriver alfabetet
120 ! Programet av Magnus <8042> 1991
130 ! 
140 ! Uppmaning om att trycka "space",
150 ! ger ej fel om "alfa.dat" ej finns (skapas d}),
160 ! CAPS LOCK sl}s av n{r programmet avslutas,
170 ! "CHAIN 'MENY'" bort, INTEGER : NO EXTEND  - <7759>
180 ! 
190 ! ** Tar man bort "EL" p} rad 440 och 570 fungerar det ev p} 800/802 **
200 ! 
210 INTEGER : NO EXTEND 
220 ON ERROR GOTO 660
230 OPEN "alfa.dat" AS FILE 1
240 FOR I=0 TO 9 : INPUT #1,W$(I),W.(I) : NEXT I 
250 CLOSE 
260 ON ERROR GOTO 
270 OUT 34,136 ! Sl} p} "CAPS LOCK"
280 ; CHR$(12) : F=0
290 ; "Skriv alfabetet fr}n A-Z."
300 ; CUR(10,20);DBLE "A"
310 IF SYS(5)=0 THEN 310
320 GET A$
330 IF A$<>"A" THEN F=F+1 : GOTO 320
340 POKE 65524,0,0 ! Nollst{ll sekunder
350 FOR A=66 TO 90 : ; CUR(10,20) DBLE;CHR$(A)
360   IF SYS(5)=0 THEN 360
370   GET A$
380   IF ASCII(A$)<>A THEN F=F+1 : ; CHR$(7); : GOTO 360
390 NEXT A 
400 T.=PEEK(65524)+(PEEK(65525)/100.)
410 ; RED CUR(15,25);"  Sek:";T.;"   "
420 ; CUR(21,18) 'TRYCK MELLANSLAG F\R ATT FORTS[TTA!'
430 IF F=0 THEN 450
440 ; CUR(19,24);GRN EL;F;"Fel"
450 IF SYS(5)=0 THEN 450
460 GET A$
470 IF A$=" " THEN 480 ELSE 450
480 FOR I=0 TO 9 : IF T.<W.(I) OR W.(I)=0 THEN 500
490 NEXT I : GOTO 530
500 FOR J=9 TO I+1 STEP -1
510 W$(J)=W$(J-1) : W.(J)=W.(J-1) : NEXT J : OUT 34,8
520 ; CHR$(12) : INPUT "Vad heter du ? ";W$(I) : W.(I)=T.
530 ; CHR$(12) : ; TAB(15);GRN "****** Tio i topp ******" : ; : ; 
540 FOR J=0 TO 9
550   IF W.(J)>0 ; TAB(20);W.(J),W$(J)
560 NEXT J : OUT 34,136
570 ; CUR(18,10);BLU EL;"Vill du spela mer. (J/N) "; : GET A$
580 IF A$<>"N" THEN 270
590 PREPARE "ALFA.DAT" AS FILE 1
600 FOR I=0 TO 9
610   PRINT #1,W$(I) "," W.(I)
620 NEXT I : CLOSE 
630 OUT 34,8 ! Sl} av "CAPS LOCK"
640 END 
650 ! 
660 ! "alfa.dat" fanns inte / f|r f} v{rden
670 FOR J=I TO 9 : W$(J)='' : W.(J)=0 : NEXT J 
680 RESUME 250