10 ! SPACE.BAC
20 ! Spel program av Magnus <8042> 1991
30 ! 
40 ! "GRED" etc f|r att ge bild p} monokrom sk{rm  <7759>
50 ! 
60 INTEGER : NO EXTEND 
65 ATTRIBUTE 0
70 ; CHR$(12)
80 ; CUR(2,30);GRN DBLE "SPACE"
90 ; CUR(4,15);CYA EL "Ett rymd spel f|r ABC806"
100 ; CUR(6,17);RED "Program av Magnus Nilsson <8042> 1991"
110 ; CUR(9,10);"Spelet g}r utt p} att }ka fr}n v{nster kanten"
120 ; TAB(11);"till h|ger kanten utan att krocka med de gula"
130 ; TAB(11);"sakerna som v{xer fram hela tiden."
140 ; TAB(11);"Du styr med 8(upp) 2(ner) mellanslag(skott)."
150 ; TAB(11);"Tryck val fri tangent n{r du vill b|rja!"
160 IF SYS(5)=0 THEN 160 ELSE GET A$
170 ; CHR$(12) : P=0 : L=1
180 FGCTL BLK+GRED+GBLU+GYEL : FGPOINT 0,0,0 : FGFILL 511,239
190 DEF FNR(X,Y,X1,Y1)
200   FGPOINT X1-1,Y1,0 : FGFILL X1+21,Y1+5
210   FGPOINT X,Y,1 : FGLINE X+21,Y : FGPOINT X,Y+1 : FGLINE X+20,Y+1
220   FGPOINT X,Y+2 : FGLINE X+4,Y+2 : FGPOINT X,Y+3 : FGLINE X+3,Y+3
230   FGPOINT X,Y+4 : FGLINE X+2,Y+4 : FGPOINT X+15,Y+1,2 : FGLINE X+18,Y+1
240   FGPOINT X-1,Y,3
250   RETURN 0
260 FNEND 
270 X1=5 : Y1=100 : X=5 : Y=100
280 IF SYS(5)=0 THEN 350
290 GET A$
300 IF A$="8" THEN Y=Y+5 : IF Y>=200 THEN Y=200
310 X1=X
320 IF A$="2" THEN Y=Y-5 : IF Y<=1 THEN Y=2
330 IF A$="6" THEN X=X+1
340 IF A$=" " THEN 520
350 FOR Q=1 TO INT(X/100)+P
360 X2=INT(RND*411)+90 : Y2=INT(RND*234) : FGPOINT X2,Y2,3 : FGFILL X2+5,Y2+5 : NEXT Q 
370 IF X>485 THEN 490
380 X=X+5
390 IF FGPOINT(X+21,Y)<>0 THEN 430
400 IF FGPOINT(X+20,Y+1)<>0 THEN 430
410 Z=FNR(X,Y,X1,Y1) : X1=X : Y1=Y
420 GOTO 280
430 FGCTL BLK
440 ; CUR(10,15);BLU NWBG RED EL;"Game over  " BLBG
450 ; CUR(12,10);BLU NWBG RED EL;"Du klarade till Level";L BLBG
460 ; CUR(20,10);RED EL;"Ett spel till "; : INPUT A$
470 IF A$="j" OR A$="J" THEN 170
480 END 
490 ; CUR(10,10);BLU NWBG GRN EL;"Du klarade Level";L BLBG
500 GET A$ : ; CHR$(12) : P=P+1 : L=L+1 : FGPOINT 0,0,0 : FGFILL 511,239 : GOTO 270
510 END 
520 FOR X3=X+22 TO 500 STEP 5
530   IF FGPOINT(X3,Y)<>0 THEN 550
540 NEXT X3 : GOTO 350
550 FGPOINT X+22,Y,3 : FGLINE X3,Y : OUT 34,10 : FGPOINT X3-5,Y-5,0 : FGFILL X3+5,Y+5 : OUT 34,9
560 FGPOINT X+22,Y,0 : FGLINE X3,Y : GOTO 350