10 REM Ins{nd av Gunnar Faith-Ell * <2733>    1985-10-05 23.59.30
20 ! --------------------------------------------------------------
30 ! DAYTIME.800 (c) 1985-10-05 Gunnar Faith-Ell <2733>
40 ! Subrutinen skriver ut vad klockan {r i l{slig form.
50 ! senaste uppdatering 1985-10-05 ver 1,a
60 ! Anropas med ;FNDAYTIME$
70 ! Testad p} ABC800 M.
80 ! --------------------------------------------------------------
90 EXTEND : INTEGER 
100 ; CHR$(12)
110 ; CUR(0,0) 'Klockan {r ' FNDaytime$ SPACE$(15) : GOTO 110
120 DEF FNDaytime$ LOCAL M,M$=2,Dag$=18,Minut$=10,Timme$=10
130   ON ERROR GOTO 360
140   RESTORE 450
150   M$=MID$(TIME$,15,2)
160   IF M$>'01' AND M$<'20' Minut$=FNRead$(VAL(M$)) : GOTO 220
170   RESTORE 470
180   Minut$=FNRead$(VAL(LEFT$(M$,1)))
190   RESTORE 450
200   IF RIGHT$(M$,2)='1' Minut$=Minut$+'en' : GOTO 220
210   Minut$=Minut$+FNRead$(VAL(RIGHT$(M$,2)))
220   RESTORE 450
230   M=VAL(MID$(TIME$,12,2))
240   IF M<25 Dag$='p} kv{llen'
250   IF M<18 Dag$='p} eftermiddagen'
260   IF M<12 Dag$='p} f|rmiddagen'
270   IF M=12 Dag$='p} middagen'
280   IF M<9 Dag$='p} morgonen'
290   IF M<4 Dag$='p} natten'
300   IF M>12 M=M-12
310   IF M=0 M=12
320   Timme$=FNRead$(M)
330   IF Minut$='01' RETURN 'en minut |ver '+Timme$+' '+Dag$+'.'
340   IF Minut$='' RETURN Timme$+' '+Dag$+'.'
350   RETURN Minut$+' minuter |ver '+Timme$+' '+Dag$+'.'
360   RETURN 'TIME READ ERROR'
370 FNEND 
380 DEF FNRead$(Ant) LOCAL I,Tal$=10
390   WHILE I+1<=Ant
400     READ Tal$
410     I=I+1
420   WEND 
430   RETURN Tal$
440 FNEND 
450 DATA ett,tv},tre,fyra,fem,sex,sju,}tta,nio,tio
460 DATA elva,tolv,tretton,fjorton,femton,sexton,sjutton,aderton,nitton
470 DATA tio,tjugo,trettio,fyrtio,femtio
480 END