1 REM Ins{nd av Patric Ljung <5455>    1985-01-23 20.06.58
6000 ! *----
6010 ! * Ins{nd av <5455> Patric Ljung 850123
6020 ! * Rutinen anropas med I$=FNInline$(Text$)
6030 ! * In$ = Inmatad text
6040 ! * Text$ = Eventuell text skickas med
6050 ! *   Man kan utel{mna Text$ men d} m}ste man skriva ''
6060 ! *   inom parentesen. In$=FNInline$('')
6065 ! * \vrig info finns tillg{nglig i MSG-systemet
6067 ! * Text nr 441 i Monitorm|tet
6070 ! *
6080 ! * INLINE  .BAS - Vers 2.0 f|r ABC800/802/806
6090 ! *---------------------------------------------------------
6100 ! 
6110 ! 
6120 ! 
7000 ! ----- INLINE Vers. 2.0 -----
7010 DEF FNInline$(Txt$) LOCAL Line$=35,Pos,Mxpos,Jpt$=8
7020   Jpt$=CHR$(8,9,13,24,192,196,198,199)
7030   IF Txt$<>'' Line$=Txt$ : ; Line$+STRING$(LEN(Line$),8);
7040   Mxpos=LEN(Line$)+1 : Pos=1
7050   GET Q$ : Q=ASCII(Q$)
7060   ON INSTR(1,Jpt$,Q$)+1 GOTO 7070,7150,7160,7200,7180,7200,7200,7200,7210
7070   IF Q<32 OR Q>127 GOTO 7050
7080   IF Pos<Mxpos AND Mxpos<35 Q=Q ELSE 7120
7090   Line$=LEFT$(Line$,Pos-1)+Q$+RIGHT$(Line$,Pos)
7100   ; RIGHT$(Line$,Pos)+STRING$(LEN(RIGHT$(Line$,Pos+1)),8); : Pos=Pos+1
7110   Mxpos=LEN(Line$)+1 : GOTO 7050
7120   IF Pos<Mxpos OUT 34,7 : GOTO 7050
7130   IF Pos=34 OUT 34,7 : GOTO 7050 ELSE ; Q$; : Pos=Pos+1
7140   Line$=Line$+Q$ : Mxpos=LEN(Line$)+1 : GOTO 7050
7150   IF Pos>1 Pos=Pos-1 : ; Q$; : GOTO 7050 ELSE 7050
7160   IF Pos<Mxpos Pos=Pos+1 : POKE 65362,PEEK(65362)+1
7170   GOTO 7050
7180   ; STRING$(Pos-1,8)+SPACE$(Mxpos-1)+STRING$(Mxpos-1,8); : Mxpos=1 : Pos=1
7190   Line$='' : GOTO 7050
7200   ; : RETURN Line$
7210   IF Mxpos<2 GOTO 7050
7220   IF Pos<Mxpos GOTO 7250
7230   Pos=Pos-1 : Line$=LEFT$(Line$,LEN(Line$)-1) : Mxpos=LEN(Line$)+1
7240   ; CHR$(8,32,8); : GOTO 7050
7250   Line$=LEFT$(Line$,Pos-1)+RIGHT$(Line$,Pos+1)
7260   ; RIGHT$(Line$,Pos)+' '+STRING$(Mxpos-Pos,8); : Mxpos=LEN(Line$)+1
7270   GOTO 7050
7280 FNEND