1 REM Ins{nd av Jinge Fl~cht <4716>    1985-09-01 10.40.24
2 ! LIST MO0:SORT800.BAS
100 ! 
105 ! 
110 ! 
115 ! LIST MO0:SORT800.BAS
120 ! 
125 ! 
130 ! Resultatsortering f|r t{vlingar o. spel.
135 ! Nedknackat av Jinge Fl~cht <4716> p} en
140 ! ABC-802 1985-08-30. Endast testat p} 802.
145 ! 
150 ! Ins{nt av <4716> Jinge Fl~cht (SM0LRN)
155 ! 
160 ! Rutinen l{mplig att knycka till tex. redovisning
165 ! av resultat i spel eller annat. Som programmet
170 ! {r nu, s} {r det INTE komprimerat till minsta
175 ! antal rader. (N}got skall man g|ra sj{lv...)
180 ! 
185 ! 
190 ! Programmet {r sj{lvinstruerande.
195 ! 
200 ! 
205 ! Programmet {r en strippad version av mitt eget
210 ! pgm f|r 'ranking' av BT-spelare.
215 ! 
220 ! 
225 ! N{r Du gjort f|rb{ttringar skicka d} in den
230 ! nya versionen till ABC-Klubbens monitor!!
235 ! 
240 ! 
245 ! ++++++++++++++++++++++++++++++++++++++++
250 ! +                                      +
255 ! +  SORT800.BAS av Jinge Fl~cht <4716>  +
260 ! +              0750-31341              +
265 ! +                                      +
270 ! ++++++++++++++++++++++++++++++++++++++++
275 ! 
280 ! Version 1.1
285 ! 
290 ! 
295 ! 
300 ! 
305 ! 
310 ! -------------------------------------------------------
315 ! 
320 EXTEND 
325 DIM N$(20),Na$(20)
330 DIM N(20),X(20),O(20)
335 Z=FNInput
340 Z=FNScore
345 Z=FNSort
350 GOTO 340
355 ! 
360 ! -------------------------------------------------------
365 ! 
370 DEF FNSort
375   ! 
380   ! Sorteringsrutinen. OBS! H{r m}ste 'moddas' om Du
385   ! t{nker bygga ut programmet. Varje index i FNScore
390   ! m}ste {ndras i denna rutin.
395   ! 
400   FOR Ap=1 TO A-1
405     FOR B=Ap+1 TO A
410       IF VAL(N$(Ap))>VAL(N$(B)) THEN GOTO 445
415       H$=N$(Ap)
420       H1$=Na$(Ap)
425       N$(Ap)=N$(B)
430       Na$(Ap)=Na$(B)
435       N$(B)=H$
440       Na$(B)=H1$
445     NEXT B 
450   NEXT Ap 
455   RETURN 0
460 FNEND 
465 ! 
470 ! -------------------------------------------------------
475 ! 
480 DEF FNScore
485   ! 
490   ! Presentation av resultatet.
495   ! 
500   ; CHR$(12)
505   ; '   --------------------------------'
510   ; '   Plac  Summa      Namn'
515   ; '   --------------------------------'
520   O=4 : N=1 : X=1
525   FOR I=1 TO A
530     ; CUR(O,3) X : ; CUR(O,9) N$(N) : ; CUR(O,20) Na$(N)
535     O=O+1
540     X=X+1
545     N=N+1
550   NEXT I 
555   ; '   --------------------------------'
560   ; CUR(21,0)
565   Z=FNUppdat
570   RETURN 0
575 FNEND 
580 ! 
585 ! -------------------------------------------------------
590 ! 
595 DEF FNInput
600   ! 
605   ! Inmatningsrutinen.
610   ! 
615   ; CHR$(12)
620   INPUT 'Hur m}nga deltagare 'A
625   FOR N=1 TO A
630     ; 'Nummer ' N ' namn '; : INPUT Na$(N)
635     N$(N)='0'
640   NEXT N 
645   RETURN 0
650 FNEND 
655 ! 
660 ! -------------------------------------------------------
665 ! 
670 DEF FNUppdat
675   ! 
680   ! Rutinen f|r att v{lja inf|r uppdatering.
685   ! 
690   O=3
695   N=-1
700   ; CUR(21,0)
705   FOR I=1 TO A
710     O=O+1
715     N=N+1
720     ; CUR(O,0) 'j/n'; : GET W$
725     IF W$='J' OR W$='j' THEN Z=FNU
730   NEXT I 
735   RETURN 0
740 FNEND 
745 ! 
750 ! -------------------------------------------------------
755 ! 
760 DEF FNU
765   ! 
770   ! H{mtar in uppgift f|r uppdatering.
775   ! 
780   ON ERROR GOTO 825
785   N=N+1
790   IF N>A THEN 825
795   ; CUR(22,0) 'Hur m}nga po{ng skall ' Na$(N) ' ha '; : INPUT X$
800   ; CHR$(12)
805   N$(N)=ADD$(N$(N),X$,0)
810   Z=FNSort
815   Z=FNScore
820   GOTO 830
825   ; Chr(7)
830   RETURN 0
835 FNEND 
840 ! 
845 ! -------------------------------------------------------
850 ! 
855 ! Programmet slut.
860 !