5 ! ********************************************
6 ! *
7 ! *      T - Start f|r test
8 ! *
9 ! *
10 ! *  prog som kopierar filer till RAM: 
11 ! *
13 ; CHR$(12)
15 XSTM197 0%,0%,2% ! * reservera utrymme f|r HR-bilder
17 ; CUR(5%,0%) YEL 'Kopiering av testprogram till RAM-floppy' : ; : ; 
20 Source$=''
30 Dest$='ram:'
40 READ File$
50 WHILE File$<>'slut'
60   PRINT GRN File$,
70   Felkod%=FNCopy%(Source$,Dest$,File$)
80   IF Felkod%<>0% THEN PRINT RED ' Fel ';Felkod% ELSE PRINT CYA ' Kopiering klar'
90   READ File$
100 WEND 
110 CHAIN 'test806c'
200 DEF FNCopy%(Source$,Dest$,File$)
210   ON ERROR GOTO 280
220   OPEN Source$+File$ AS FILE 1%
230   PREPARE Dest$+File$ AS FILE 2%
240   WHILE -1%
250     GET #1%,Buf$ COUNT 253%
260     PUT #2%,Buf$
270   WEND 
280   ON ERROR GOTO 310
290   IF ERRCODE=38% OR ERRCODE=37% THEN 320
300   CLOSE 1%,2%
310   RETURN ERRCODE
320   ON ERROR GOTO 340
330   PUT #2%,Buf$
340   CLOSE 1%,2%
350   RETURN 0%
360 FNEND 
400 END 
500 ! 
510 ! DATA 
520 DATA SYS806T.BAC
522 DATA TEST806C.BAC
524 DATA TIMESET.BAC
530 DATA slut