2 ! **********************************************************************
3 ! Program          RAMINI.BAS       Utg}va  1.4      1986-11-30
4 ! av Bo Kullmar, <1789>
5 ! Ins{nd av Bo Kullmar
6 ! F|r ABC806
8 ! Testad p} ABC806
9 ! **********************************************************************
60 INTEGER : EXTEND : ATTRIBUTE 3
300 DIM Block$=253
500 DATA LIB.BAC,T.BAC,TV.BAC,TVMAIN.BAC,TVSUB800.ABS
510 DATA VISA.BAC,UFD.ABS,UFD.BAC,DIR.BAC,LIB.ABS
520 DATA BACKUP.ABS,BACKUP.BAC,K.BAC,
1000 ! Huvudprogram
1010 FGPICTURE 0,0,4
1060 ; CHR$(12);DBLE YEL 'ABC806 RAMINI' : ; : ; BLU STRING$(80,61) : ; : ; 
1070 Enhet$=FNRunenh$ : Antal=FNReadname : Fel=FNCopylib
1080 ; : ; 
1090 ! IF NOT Fel CHAIN 'ERRINI.BAC'
1100 CHAIN 'NUL:' ! *** Man kan startat ett givit program ocks}
1105 DEF FNReadname LOCAL I
1110   DIM Filnamn$(50)=12
1120   READ Filnamn$(I)
1130   WHILE Filnamn$(I)<>''
1140     I=I+1
1150     READ Filnamn$(I)
1160   WEND 
1170   RETURN I-1
1180 FNEND 
1190 DEF FNCopylib LOCAL Block$=253,I,Fel
1200   ON ERROR GOTO 1320
1210   WHILE I<=Antal
1220     OPEN Enhet$+Filnamn$(I) AS FILE 1
1230     PREPARE 'RAM:'+Filnamn$(I) AS FILE 2
1240     ; YEL Filnamn$(I),'Kopieras nu till RAM:';
1250     WHILE -1
1260       GET #1,Block$ COUNT 253
1270       PUT #2,Block$
1280     WEND 
1290     I=I+1
1300   WEND 
1310   RETURN Fel
1320   IF ERRCODE=21 ; RED Filnamn$(I),'Finns ej p} skivorna!' : Fel=-1 : RESUME 1290
1330   IF ERRCODE=38 THEN ; CUR(PEEK(65363),14) YEL '[r kopierad till RAM:' : RESUME 1290
1340   ; RED 'Fel nr' ERRCODE : RESUME 1310
1350 FNEND 
2000 DEF FNRunenh$ LOCAL Drive,Adrenhl,Enh$=4,Dselect
2010   Drive=PEEK(64769) AND 31
2020   Adrenhl=PEEK2(SYS(10)+123)
2030   WHILE Adrenhl<>0
2040     Enh$=CHR$(PEEK(Adrenhl+2),PEEK(Adrenhl+3),PEEK(Adrenhl+4),58)
2050     Dselect=PEEK(Adrenhl+7)
2060     IF Drive=Dselect THEN RETURN Enh$
2070     Adrenhl=PEEK2(Adrenhl)
2080     I=I+1
2090   WEND 
2100 FNEND