1 REM Ins{nd av Lars B. Cid <7390>    1988-01-05 02.33.33 (SEND)
1000 ! SCRAM (ABC800/?)
1010 ! 
1020 ! ]terigen ett on|digt program!
1030 ! Chiffrerar en fil mha RND-
1040 ! funktionen. Filen kan endast
1050 ! dekrypteras med den dator(typ)
1060 ! som den krypterades p}.
1070 ! 
1080 ! ABC80x,ABC83x
1090 ! 
1091 ! Om enhetsnamn anges p} filnamnet, {r det inte s{kert att
1092 ! att utfilen hamnar p} samma enhet. /Progred
1093 !
1100 INTEGER : EXTEND 
1110 DIM F$=16,T$=40,A$=253,B$=253
1120 ; '** Auto text scrambling utility **'
1130 ; '   Ver 4.02, 1988-01-05'
1140 ; '   Public Domain'
1150 ; 
1160 ON ERROR GOTO 1480
1170 T$='Programme terminated.'
1180 INPUT 'File to scramble/ descramble',F$
1190 IF F$='' ; VAL('')
1200 T$='-Wrong security code.'
1210 INPUT 'Security code (0 to 255):         ',A
1220 IF A<0 OR A>255 ; VAL('')
1230 FOR I=0 TO A : Z=RND : NEXT I 
1240 ! 
1250 T$='-File not found.'
1260 IF INSTR(1,F$,'.')=0 F$=F$+'.BAC'
1270 OPEN F$ AS FILE 1
1280 ! 
1290 T$='-Error when creating temporary file.'
1300 PREPARE 'TEMPORY.QWE' AS FILE 2
1310 ! 
1320 ON ERROR GOTO 1450
1330 WHILE -1
1340   GET #1 A$ COUNT 253
1350   ; CHR$(13);'Scramble block:' Bl+1; : Bl=Bl+1
1360   ! 
1370   B$=''
1380   FOR I=1 TO 253
1390     B$=B$+CHR$(ASCII(MID$(A$,I,1)) XOR INT(RND*256))
1400   NEXT I 
1410   ! 
1420   PUT #2 B$
1430 WEND 
1440 ! 
1450 IF ERRCODE<>38 AND ERRCODE<>37 ; VAL('')
1460 ; : ; 'Ready.' CHR$(13); : CLOSE : T$=''
1470 KILL F$ : NAME 'tempory.qwe' AS F$
1480 IF PEEK(65362)<>0 ; 
1490 ; T$
1500 END