1 REM Ins{nd av Stefan Gartz <2600>    1987-11-11 08.17.23 (KERMIT)
10 ! SAVE TEXTBYT 87-11-11 sg
20 ! Detta program byter ut text i en textfil,
30 ! tex variabelbyte i ett basic program
40 ! 
50 ! Det kommer ett fr}getecken vid det s|kta ordet 
60 ! och skriver man d} 'j' s} blir det utbytt
70 ! 
80 ! Sist i programmet st}r det filnamn som skall behandlas
90 ! vill man k|ra flera efter varandra s} |ka p} datalistan
100 ! 
110 ! Tabellen f|r utbyte ska skrivas in direkt i detta program
120 ! i funktionen FNInits|k
130 ! 
140 EXTEND : INTEGER 
150 DIM A$=160
160 ! 
170 READ Infil$
180 PRINT CHR$(12) : ; : ; 'TEXTBYT' : ; : ; : ; 'INFIL=UTFIL '
190 PRINT 'INFIL=' Infil$
200 ! 
210 Z=FNMain
220 ; CUR(18,0) 'OK'
230 READ Infil$
240 GOTO 190
250 END 
260 ! 
270 DEF FNInits|k
280   ! **** S\KORD, BYTORD
290   S|k$=' AV' : Byt$=' LY'
300   Z=FNByt
310   S|k$=',AV' : Byt$=',LY'
320   Z=FNByt
330   RETURN 0 ! Klar
340   S|k$='Video' : Byt$='Viedo'
350   Z=FNByt
360   RETURN 0
370   S|k$='R7212$(' : Byt$='T$('
380   Z=FNByt
390   S|k$='R7139$(' : Byt$='Pf$('
400   Z=FNByt
410   S|k$='R7058(' : Byt$='Blockmove('
420   Z=FNByt
430   S|k$='R6944$(' : Byt$='Rise$('
440   Z=FNByt
450   S|k$='R6565(' : Byt$='Stderror('
460   Z=FNByt
470   S|k$='R6380(' : Byt$='Error('
480   Z=FNByt
490   S|k$='R6353(' : Byt$='Terror('
500   Z=FNByt
510   S|k$='R6306$(' : Byt$='Mess$('
520   Z=FNByt
530   S|k$='R5785$(' : Byt$='Readrow$('
540   Z=FNByt
550   S|k$='R5764$' : Byt$='Cursor$'
560   Z=FNByt
570   S|k$='R5531(' : Byt$='Quest('
580   Z=FNByt
590   RETURN 0
600 FNEND 
610 DEF FNMain
620   ON ERROR GOTO 780
630   OPEN Infil$ AS FILE 1
640   PREPARE 'tmp.tmp' AS FILE 2
650   ON ERROR GOTO 730
660   INPUT LINE #1 A$ : A$=LEFT$(A$,LEN(A$)-2)
670   ! 
680   Z=FNInits|k
690   ! 
700   PRINT #2 A$
710   PRINT CUR(7,0) A$ SPACE$(80)
720   GOTO 660
730   ! 
740   IF ERRCODE<>34 THEN PRINT 'FEL ' ERRCODE : STOP 
750   CLOSE 
760   KILL Infil$ : NAME 'tmp.tmp' AS Infil$
770   RETURN 0
780   ! 
790   IF ERRCODE=21 THEN ; Infil$ ' SAKNAS !!' ELSE PRINT 'FEL ' ERRCODE : STOP 
800   RETURN 0
810 FNEND 
820 DEF FNByt
830   P=0
840   ! 
850   PRINT CUR(20,0) S|k$ SPACE$(40)
860   P=INSTR(P+1,A$,S|k$)
870   IF P THEN PRINT CHR$(7) CUR(10,0) A$ SPACE$(80) CUR(11,P); : INPUT J$ : IF J$<>"J" AND J$<>'j' THEN GOTO 840
880   IF P THEN A$=LEFT$(A$,P-1)+Byt$+RIGHT$(A$,P+LEN(S|k$)) : ; CUR(13,0) A$ SPACE$(80) : GOTO 840
890   RETURN 0
900 FNEND 
910 DATA x.bas