1 ! Kristoffer Eriksson <5357>    1985-10-19 00.55.18
10 ! save KEYPROG
20 ! ----------------------------------------
30 ! KEYPROG. Tillbeh|r till KEY.BAC
40 ! F|r ABC800-serien
50 ! Av Kristoffer Eriksson ABCklubben<5357>
60 ! Ver 2.1 Augusti 1985
70 ! ----------------------------------------
80 ! Programmering av tangenter vid start av KEY.
90 INTEGER 
100 ! 
110 ! Ange i denna DATA-sats vilket program som ska chainas:
120 DATA ""
130 ! 
140 ! Skriv in |nskade programmeringar h{r:
150 ! 
160 KEY "&#3","_LLIST_M"
170 KEY "&6","_XLOAD "
180 KEY "&_#1","_XED_M_I_I_I_I_X_I_I_I_I_I_I_I_I_I_I_I_I_I_I_I_I_I_I_I_I_I_I_M"
190 KEY "_[","_I_I_I_I_I"
200 KEY "_K","_XKEY_M"
210 KEY "_U","_XRUN UFD_M"
220 KEY "^","LIST "
230 KEY "_R","_XRUN_M"
500 ! 
510 IF FNAbc99=0 THEN 1000
520 ! 
530 ! Skriv in s{rskild programmering f|r ABC99 h{r:
540 ! 
550 KEY CHR$(172),CHR$(8) ! Fyrkant, bak}t
560 KEY CHR$(164),CHR$(9) ! Fyrkant, fram}t
570 KEY CHR$(161),"&5" ! Fyrkant, upp}t
580 KEY CHR$(163),"&7" ! Fyrkant, ned}t
590 KEY CHR$(137),CHR$(9) ! -->!
600 KEY CHR$(136),CHR$(8) ! !<--
610 KEY CHR$(128),"&#2" ! HELP
620 KEY CHR$(129),"_C" ! STOP
630 KEY CHR$(130),"&_#8" ! PRINT
640 KEY CHR$(206),"&8" ! PF15
650 KEY CHR$(132)," " ! INS
1000 ! 
1010 KEY 
1020 KEYMODE ,1 ! Programmering p}
1030 ! 
1040 ! --------- Chaining ---------
1050 READ F$
1060 IF LEN(F$) THEN 1140
1070 ! 
1080 I=63747 : WHILE PEEK(I)<>255
1090   IF I>63765 THEN F$="" : GOTO 1160
1100   IF PEEK(I)<48 OR PEEK(I)>126 THEN 1160
1110   F$=F$+CHR$(PEEK(I))
1120 I=I+1 : WEND 
1130 ! 
1140 ON ERROR GOTO 1160
1150 IF F$<>"" THEN CHAIN F$
1160 CHAIN "NUL:"
1170 END 
1180 ! 
1190 DEF FNAbc99 LOCAL I$=1,I
1200   WHILE SYS(5)>127 : GET I$ : WEND ! T|m buffert
1210   OUT 34,24
1220   WHILE I<20 : I=I+1 : WEND 
1230   IF SYS(5)=0 THEN RETURN 0
1240   WHILE SYS(5)>127 : GET I$ : WEND 
1250   RETURN -1
1260 FNEND