1 REM Ins{nd av Leif Gaude <3999>    1985-12-21 00.34.44
10 ! ***********************************************************
15 ! * Ett litet meny-program att ha p} sina favoritskivor.    *
20 ! * Skriv in namnen p} de program du vill ha med i menyn    *
25 ! * i datasatserna i programet (max 20 program).            *
30 ! * Sen {r det bara att tuta och k|ra. Om man vill kan man  *
35 ! * ju l{gga programet med autostart s} beh|ver man bara    *
40 ! * g|ra reset f|r att k|ra ig}ng det.                      *
45 ! *                                                         *
50 ! * Programet {r gjort av:                                  *
55 ! * Leif gaude <3999>                                       *
60 ! *                                                         *
65 ! ***********************************************************
70 ! 
75 ; CHR$(12) : EXTEND 
80 DIM Pg$(30),Filnamn$(30)
85 Rad=9 : Kol=10 : Pg=0 : N=0
90 ; CUR(3,0) STRING$(80,61)
95 ; CUR(2,2) ' MINIMENY    A=v{nster  S=h|ger  W=upp  Z=ned  C=avbryt  Q=anropa DOS'
100 READ Pg$(N) : N=N+1
105 Z$=FNKonv$
110 ON ERROR GOTO 310
115 GOTO 100
120 FOR I=0 TO 9 : ; CUR(Rad+I,12) Filnamn$(I) : NEXT I 
125 FOR I=0 TO 9 : ; CUR(Rad+I,42) Filnamn$(I+10) : NEXT I 
130 ; CUR(Rad,Kol) ''
135 ON ERROR GOTO 315
140 ; CUR(22,10);'Tryck p} <RETURN> n{r du har gjort ditt val '; : GET Styr$ : Styr=ASCII(Styr$)
145 IF Styr=90 OR Styr=122 Rad=Rad+1 : P=P+1 : ; CUR(Rad-1,Kol) ' ' : IF Rad>18 Rad=9 : P=0
150 IF Styr=87 OR Styr=119 Rad=Rad-1 : P=P-1 : ; CUR(Rad+1,Kol) ' ' : IF Rad<9 Rad=9 : P=0
155 IF Styr=83 OR Styr=115 Kol=Kol+30 : G=G+10 : ; CUR(Rad,Kol-30) ' ' : IF Kol>56 Kol=10 : G=0
160 IF Styr=65 OR Styr=97 Kol=Kol-30 : G=G-10 : ; CUR(Rad,Kol+30) ' ' : IF Kol<10 Kol=10 : G=0
165 Pg=P+G
170 IF Styr=81 OR Styr=113 GOTO 250
175 IF Styr=67 OR Styr=99 ; CHR$(12) : CHAIN 'nul:'
180 IF Styr=13 ; CHR$(12) : CHAIN Pg$(Pg)
185 GOTO 130
190 ! 
195 ! h{r ska du stoppa in dina programnamn (h|gst 20st)
200 ! se till att extensionen p} filnamnet {r 3 tecken l}ng
205 ! 
210 ! 
215 DATA LIB.BAC,VARLIST.BAC,UFD.BAC
220 DATA PSET.BAC,MASK.BAC,REPROT.BAC
225 DATA VISA.BAC,CONFIG.BAC
230 DATA DISKCHEK.BAC,TRANS.BAC
235 DATA ************,************,************,************
240 DATA ************,************,************,************
245 DATA ************,************
250 BYE 
255 DEF FNKonv$
260   ! En snutt bara f|r att g|ra alla filnamn lika l}nga p} sk{rmen
265   L{ngd=LEN(Pg$(N-1))-4
270   Ext$=MID$(Pg$(N-1),L{ngd+1,4)
275   Namn$=LEFT$(Pg$(N-1),L{ngd)
280   Filnamn$(N-1)=Namn$+SPACE$(8-L{ngd)+Ext$
285   RETURN ''
290 FNEND 
295 ! 
300 ! felhantering
305 ! 
310 RESUME 120
315 ; CHR$(12,7) CUR(11,15) 'Filen ' Filnamn$(Pg) ' finns ju inte p} skivan!! '
320 RESTORE 
325 FOR V{nta=0 TO 3000 : NEXT V{nta 
330 RESUME 75