1 REM Ins{nd av 5499 Ny Medlem <5499>    1985-01-29 22.37.20
10 ! LIST BASCOMP
20 ! BASCOMP VER 1   27-jan-1985
30 ! 
40 ! Program f|r att j{mf|ra tv} .BAS-filer.
50 ! 
60 ! Skillnaderna mellan de tv} angivna filerna skrivs ut p} sk{rmen och
70 ! om s} |nskas {ven p} en skrivare.
80 ! 
90 ! Ange de tv} filnamnen och skillnaden skrivs ut
100 ! 
110 ! 
120 ! Ins{nt av Lars-Ove Larsson (5499)
130 ! 
140 ! 
150 DIM Q1$=200,Q2$=200
160 EXTEND : INTEGER 
170 ! 
180 ! \ppna filerna
190 OPEN "PR:.88" AS FILE 9
200 ; "Ange fil 1 (Utan .BAS) "; : INPUT Fil1$
210 IF LEN(Fil1$)=0 THEN Fil1$="FIL1.BAS"
220 OPEN Fil1$+".BAS" AS FILE 1
230 ; "Ange fil 2             "; : INPUT Fil2$
240 IF LEN(Fil2$)=0 THEN Fil2$="FIL2.BAS"
250 OPEN Fil2$+".BAS" AS FILE 2
260 ! Testa radskrivarutskrift
270 ; "Utskrikt p} printer (j)"; : INPUT Ans$
280 IF LEN(Ans$)=0 THEN P=1 : GOTO 305
290 Ans$=LEFT$(Ans$,1)
300 IF Ans$="n" OR Ans$="N" THEN P=0 ELSE P=1
305 IF P=1 THEN ; #9 "Skillnader mellan filerna ";Fil1$;".BAS och ";Fil2$;".BAS"
310 ! 
320 ! L{s en rad fr}n filerna
330 ON ERROR GOTO 720
340 INPUT LINE #1,Q1$
350 ON ERROR GOTO 790
360 INPUT LINE #2,Q2$
370 ! 
380 ! Best{m radnummer
390 I1=INSTR(1,Q1$," ")
400 I2=INSTR(1,Q2$," ")
410 N1=VAL(LEFT$(Q1$,I1))
420 N2=VAL(LEFT$(Q2$,I2))
430 IF N1=N2 THEN 470 ! Lika radnummer, kolla skillnader
440 IF N1<N2 THEN 600 ELSE 660 ! Ej lika radnummer
450 ! 
460 ! Lika radnummer
470 L1=LEN(Q1$)
480 L2=LEN(Q2$)
490 IF L1<>L2 THEN 540
500 FOR L=1 TO L1
510   IF ASCII(MID$(Q1$,L,1))<>ASCII(MID$(Q2$,L,1)) THEN 540
520 NEXT L 
530 GOTO 330
540 REM #######  FEL SKRIV B]DA
550 ; "1# ";Q1$;
560 IF P=1 THEN ; #9,"1# ";Q1$;
570 ; "2# ";Q2$
580 IF P=1 THEN ; #9,"2# ";Q2$
590 GOTO 330
600 REM #######  FEL SKRIV 1
610 ; "1# ";Q1$
620 IF P=1 THEN ; #9,"1# ";Q1$
630 ON ERROR GOTO 740
640 INPUT LINE #1,Q1$
650 GOTO 390
660 REM ######## FEL SKRIV 2
670 ; "2# ";Q2$
680 IF P=1 THEN ; #9,"2# ";Q2$
690 ON ERROR GOTO 810
700 INPUT LINE #2,Q2$
710 GOTO 390
720 IF P=1 THEN ; #9 "SLUT FIL 1"
730 ; "SLUT FIL 1"
735 IF Q1$=Q2$ THEN GOTO 760
740 ; "2# ";Q2$;
750 IF P=1 THEN ; #9,"2# ";Q2$;
760 ON ERROR GOTO 860
770 INPUT LINE #2,Q2$
780 GOTO 740
790 IF P=1 THEN ; #9 "SLUT FIL 2"
800 ; "SLUT FIL 2"
805 IF Q1$=Q2$ THEN GOTO 830
810 ; "1# ";Q1$;
820 IF P=1 THEN ; #9,"1# ";Q1$;
830 ON ERROR GOTO 860
840 INPUT LINE #1,Q1$
850 GOTO 810
860 END