1 REM CASMINI
10 REM ################################
11 REM ## ABCMINI fil|verf|ring       #
12 REM ## till egen ABC-80.           #
13 REM ##                             #
14 REM ## Program av Gunnar Tidner.   #
15 REM ##                             #
16 REM ## Specialprogram f|r kassett- #
17 REM ## hantering.                  #
18 REM ##                             #
19 REM ## Program modif. och kompl.   #
20 REM ## av Thomas Bergstam 800823.  #
21 REM ################################
22 OPEN "V24:KB.1" ASFILE 1% : L%=1%
23 Z$="/*" : REM Filslutm{rke
24 DIM B$=255%,D1$=255%,D2$=255%
25 ; "         ***  Half Duplex  ***"
26 INPUT #L%,A$
27 ; "\verf|ring av fil fr}n monitorn?"
28 ; "Bekr{fta:"; : GET C$ : ; C$
29 ; "Filnamn i MONITORN:"; : INPUT F1$
30 ; "Eget filnamn:"; : INPUT F2$
31 ; #L%,"Hejsan"
32 INPUT #L%,B$
33 IF B$<>"SYNK" THEN 31
34 FOR T%=1% TO 100% : NEXT T%
35 ; #L%,"SYNKSVAR"
36 ; #L%,F1$
37 INPUTLINE #L%,B$ : B$=LEFT$(B$,LEN(B$)-2%)
38 IF B$<>"OPENED" THEN ; B$ : FOR T%=1% TO 3000% : NEXT T% : GOTO 26
39 D0$=F2$ : D0%=3% : GOSUB 61
40 FOR I%=1% TO 2000%
41 ; #L%,'>'
42 INPUTLINE #L%,B$
43 IF LEFT$(B$,2%)=Z$ THEN 47
44 D2$=B$ : D0%=3% : GOSUB 53
45 ; I%
46 NEXT I%
47 D0%=3% : GOSUB 71
48 ; CHR$(7%)"\verf|ringen klar!"
49 ; "Filnamn: ";F2$;" antal rader=";I%-1%
50 FOR T%=1% TO 2000% : NEXT T%
51 ; #L%,"Tack!"
52 GOTO 26
53 IF LEN(D1$)+LEN(D2$)>253% THEN 56
54 D1$=D1$+D2$+CHR$(13%)
55 GOTO 60
56 GOSUB 77
57 GOSUB 65
58 OUT 58%,INP(58%) AND 223%
59 D1$=D2$+CHR$(13%)
60 RETURN 
61 PREPARE "CAS:"+D0$ ASFILE D0%
62 OUT 58%,INP(58%) AND 223%
63 D1%=PEEK(65021%)
64 RETURN 
65 PRINT #D0%,D1$
66 IF PEEK(65021%)<>D1% THEN GOSUB 68
67 RETURN 
68 FOR Z%=0% TO 1500% : NEXT Z%
69 D1%=PEEK(65021%)
70 RETURN 
71 GOSUB 77
72 GOSUB 65
73 IF D1%<>PEEK(65021%) THEN 75
74 PRINT #D0%,CHR$(0%); : GOTO 73
75 CLOSE D0%
76 RETURN 
77 OUT 58%,INP(58%) OR 32%
78 FOR Z%=0% TO 2000% : NEXT Z%
79 RETURN