10 REM CASTODSK
15 REM Program av Gunnar Tidner 1980-10-21
20 DIM B$=119 : N0%=3 : REM antal f|rs|k att hitta fil p} bandet
30 Z$="Q2W3E4R.TMP" : REM tempor{rfil
40 ; CHR$(12)CUR(2,0);;"Detta program kopierar textfiler fr}n"
50 ; "kassett till disk"
60 ; CUR(5,0)"Filer med ext.=BAC kopieras ej!"
70 ; CUR(10,0);"Till drive:"; : GET C$ : ; C$
80 IF C$<'0' OR C$>'1' THEN 70
90 IF C$='0' THEN D$="DR0:" ELSE D$="DR1:"
100 ; "[r bandspelaren klar?  (J/N):"; : GET C$ : ; C$
110 IF (ASC(C$) AND 223%)<>74 THEN 100
120 B0%=32720% : REM rad 23 i bildminnet
130 ; CUR(22,0)
140 F$="" : N%=N0%
150 ONERRORGOTO 380
160 PREPARE D$+Z$ ASFILE 2
170 OPEN "CAS:" ASFILE 1
180 FOR T=1 TO 100 : NEXT T
190 FOR I%=B0% TO B0%+17
200 F$=F$+CHR$(PEEK(I%))
210 NEXT I%
220 IF LEFT$(F$,5)="FOUND" THEN F$=RIGHT$(F$,7) : ; ELSE F$=""
230 IF INSTR(1%,F$,"BAC") THEN 170
240 ONERRORGOTO 290
250 FOR I%=1 TO 10000%
260 INPUTLINE #1,B$
270 ; #2,B$;
280 NEXT I%
290 IF ERRCODE=34 THEN CLOSE 1 : CLOSE 2 ELSE 380
300 POKE -456%,0
310 ONERRORGOTO 330
320 KILL D$+F$
330 IF ERRCODE=21 THEN POKE -456%,0
340 IF ERRCODE<>-1 THEN ; "Fel nr";ERRCODE : END 
350 NAME Z$ AS F$
360 ; CHR$(7);F$;" kopierad!"
370 GOTO 140
380 IF ERRCODE<>21 THEN ; "Fel nr";ERRCODE : END ELSE N%=N%-1
390 IF N% THEN KILL D$+Z$ ELSE 170
400 ; "Ingen mer fil p} bandet trots";N0%;" f|rs|k!"
410 OUT 6,7 : OUT 58%,INP(58%) AND 223% : FOR T=1 TO 3000 : NEXT T
420 OUT 6,0 : END