10 REM CASMINI fil|verf|ring till egen ABC-80
15 REM Program ABCMINI av Gunnar Tidner
17 REM Modifiering till kasetthantering av Thomas Bergstam 1980-08-23
19 REM Sm{rre mod 1981-02-05 G Tidner
20 OPEN "V24:KB.1" ASFILE 1% : L%=1%
30 Z$="/*" : REM Filslutm{rke
40 DIM B$=255%,D1$=255%,D2$=255%
50 ; "         ***  Half Duplex  ***"
60 INPUT #L%,A$
70 ; "\verf|ring av fil fr}n monitorn?"
80 ; "Tryck tangent!"; : GET C$ : ; C$
90 ; "Filnamn i MONITORN:"; : INPUT F1$
100 ; "Eget filnamn:"; : INPUT F2$
110 ; #L%,"Hejsan"
120 INPUT #L%,B$
130 IF B$<>"SYNK" THEN 110
140 FOR T%=1% TO 100% : NEXT T%
150 ; #L%,"SYNKSVAR"
160 ; #L%,F1$
170 INPUTLINE #L%,B$ : B$=LEFT$(B$,LEN(B$)-2%)
180 IF B$<>"OPENED" THEN ; B$ : FOR T%=1% TO 3000% : NEXT T% : GOTO 60
190 D0$=F2$ : D0%=3% : GOSUB 410
200 FOR I%=1% TO 10000%
205 FOR T=1 TO 100 : NEXT T
210 ; #L%,'>'
220 INPUTLINE #L%,B$
230 IF LEFT$(B$,2%)=Z$ THEN 270
240 D2$=B$ : D0%=3% : GOSUB 330
250 ; B$;
260 NEXT I%
270 D0%=3% : GOSUB 510
280 ; CHR$(7%)"\verf|ringen klar!"
290 ; "Filnamn: ";F2$;" antal rader=";I%-1%
300 FOR T%=1% TO 2000% : NEXT T%
310 ; #L%,"Tack!"
320 GOTO 60
330 IF LEN(D1$)+LEN(D2$)>253% THEN 360
340 D1$=D1$+D2$+CHR$(13%)
350 GOTO 400
360 GOSUB 570
370 GOSUB 450
380 OUT 58%,INP(58%) AND 223%
390 D1$=D2$+CHR$(13%)
400 RETURN 
410 PREPARE "CAS:"+D0$ ASFILE D0%
420 OUT 58%,INP(58%) AND 223%
430 D1%=PEEK(65021%)
440 RETURN 
450 PRINT #D0%,D1$
460 IF PEEK(65021%)<>D1% THEN GOSUB 480
470 RETURN 
480 FOR Z%=0% TO 1500% : NEXT Z%
490 D1%=PEEK(65021%)
500 RETURN 
510 GOSUB 570
520 GOSUB 450
530 IF D1%<>PEEK(65021%) THEN 550
540 PRINT #D0%,CHR$(0%); : GOTO 530
550 CLOSE D0%
560 RETURN 
570 OUT 58%,INP(58%) OR 32%
580 FOR Z%=0% TO 2000% : NEXT Z%
590 RETURN