10 REM ********************************
20 REM *********  1980.04.05  *********
30 REM ********************************
40 REM ********************************
50 REM ********* EDVARD LAGUS *********
60 REM *********     BOR]S    *********
70 REM ********************************
80 ; CHR$(12) : FOR I%=0% TO 21% : ; CUR(I%,0%)CHR$(151); : NEXT I%
90 A%(1%)=4% : R%(1%)=52% : A%(2%)=78% : R%(2%)=51% : K%(1%)=30% : K%(2%)=51 : U%(1%)=50% : U%(2%)=50%
100 ; CUR(19%,15%)"5";CUR(19%,25%)"j"
110 ; CUR(21%,2%);""
120 ; CUR(20%,2%);"0 `~t ` `~t x}0`~t `~t`~t ` `~t```  `"
130 RANDOMIZE 
140 REM %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% START %%%%%%%%%%%%%%%%%%%%%%%%
150 IF A%(1%)<83% THEN GOSUB 330 ELSE A%(1%)=3% : R%(1%)=INT(50%*RND)+1% : F%(1%)=60%
160 IF A%(2%)>0% THEN GOSUB 390 ELSE A%(2%)=79% : R%(2%)=INT(50%*RND)+1% : F%(2%)=60%
170 P%=INP(56)
180 ; CUR(23%,3%)RIGHT$(NUM$(B%(1%)+10000%),3%);
190 ; CUR(23%,13%)RIGHT$(NUM$(U%(1%)+1000%),3%);
200 ; CUR(23%,34%)RIGHT$(NUM$(B%(2%)+10000%),3%);
210 ; CUR(23%,24%)RIGHT$(NUM$(U%(2%)+1000%),3%);
220 IF P%=218% AND S%(1%)<>1% AND U%(1%)>=0% THEN S%(1%)=1% : U%(1%)=U%(1%)-1% : R%(3%)=55%
230 IF P%=173% AND S%(2%)<>1% AND U%(2%)>=0% THEN S%(2%)=1% : U%(2%)=U%(2%)-1% : R%(4%)=55%
240 FOR I%=1% TO 2%
250 REM %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% SKOTT (1) ?? %%%%%%%%%%%%%%%%%%
260 IF S%(1%)=1% GOSUB 680 ELSE GOSUB 780
270 REM %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% SKOTT (2) ?? %%%%%%%%%%%%%%%%%%
280 IF S%(2%)=1% GOSUB 520 ELSE GOSUB 780
290 NEXT I%
300 IF U%(1%)<0% OR U%(2%)<0% THEN ; CUR(10%,16%)CHR$(135)"S L U T"CHR$(151) : OUT 6,0% : GOTO 300
310 GOTO 150
320 REM %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% FLYGGPLAN (1) %%%%%%%%%%%%%%%%
330 A%(1%)=A%(1%)+1%
340 IF A%(1%)>79% THEN GOTO 360
350 IF F%(1%)>60% THEN SETDOT R%(1%),A%(1%) ELSE F%(1%)=F%(1%)+1%
360 IF A%(1%)<6% THEN GOTO 380
370 CLRDOT R%(1%),A%(1%)-4%
380 RETURN 
390 REM %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% FLYGGPLAN (2) %%%%%%%%%%%%%%%%
400 A%(2%)=A%(2%)-1%
410 IF A%(2%)<4% THEN 430
420 IF F%(2%)>60% THEN SETDOT R%(2%),A%(2%) ELSE F%(2%)=F%(2%)+1%
430 IF A%(2%)>75% THEN GOTO 450
440 CLRDOT R%(2%),A%(2%)+4%
450 RETURN 
460 REM *************************************** TR[FF (2) ********************
470 B%(2%)=B%(2%)+INT(160%-R%(4%)*3%)
480 OUT 6,15%
490 IF R%(4%)=R%(1%) THEN F%(1%)=1%
500 IF R%(4%)=R%(2%) THEN F%(2%)=1%
510 RETURN 
520 REM *************************************** SKOTT (2) ********************
530 IF F%(1%)>10% THEN IF F%(2%)>10% THEN OUT 6,25%
540 CLRDOT R%(4%),K%(2%)
550 R%(4%)=R%(4%)-1%
560 IF DOT(R%(4%),K%(2%)) THEN GOSUB 460
570 IF R%(4%)=0% THEN S%(2%)=0%
580 SETDOT R%(4%),K%(2%)
590 IF S%(2%)=0% THEN CLRDOT R%(4%),K%(2%)
600 IF S%(2%)=0% AND S%(1%)=0% THEN OUT 6,0%
610 RETURN 
620 REM *************************************** TR[FF (1) ********************
630 B%(1%)=B%(1%)+INT(160%-R%(3%)*3%)
640 OUT 6,15%
650 IF R%(3%)=R%(1%) THEN F%(1%)=1%
660 IF R%(3%)=R%(2%) THEN F%(2%)=1%
670 RETURN 
680 REM *************************************** SKOTT (1) ********************
690 IF F%(1%)>10% AND F%(2%)>10% THEN OUT 6,25%
700 CLRDOT R%(3%),K%(1%)
710 R%(3%)=R%(3%)-1%
720 IF DOT(R%(3%),K%(1%)) THEN GOSUB 620
730 IF R%(3%)=0% THEN S%(1%)=0%
740 SETDOT R%(3%),K%(1%)
750 IF S%(1%)=0% THEN CLRDOT R%(3%),K%(1%)
760 IF S%(1%)=0% AND S%(2%)=0% THEN OUT 6,0%
770 RETURN 
780 REM %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% TID %%%%%%%%%%%%%%%%%%%%%%%%%%%
790 FOR J%=1% TO 5% : NEXT J% : RETURN