10 REM ++++++++++++++++++++++++++++++++
11 REM ! Program ....   CASDISK3
12 REM ! Utg}va  2.2    1983-10-20
13 REM ! av Magnus Jacobsson
14 REM ! {ndrat av Kalle Lindstr|m
15 REM ! och {nnu en g}ng {ndrat av,
16 REM ! just det, Kalle Lindstr|m
17 REM ! Copyright ABC-klubben
18 REM ! Minne 16 Kbytes f|r flexskiva
19 REM ! Ins{nt av 837
20 REM ++++++++++++++++++++++++++++++++
21 REM 
22 REM The Computer Phantome
23 REM 
24 REM Ins{nt av 615
25 REM SAVE CASDISK,3.0,811106,MJ
26 DIM C$=0%,B$=0%,Q0$=253%,S2$=253%
27 DIM D$=4%,E$=12%,E3$=7%,S1$=7%
28 E3$=STRING$(6%,0%)+CHR$(3%)
29 S1$=CHR$(253%,192%,253%,192%)
30 S1$=S1$+CHR$(253%,192%,52%)
31 R%=PEEK(65065%)+SWAP%(PEEK(65066%))
32 POKE R%+4%,18%,0%,0%,0%,18%,0%
33 P%=R%+6%
34 R%=PEEK(R%+2%)+SWAP%(PEEK(R%+3%))
35 POKE R%+4%,253%,0%,0%,0%,253%,0%
36 R%=R%+6%
37 A%=PEEK(65056%)+SWAP%(PEEK(65057%))
38 I%=A% : ONERRORGOTO 43
39 READ D% : POKE I%,D%
40 I%=I%+1% : GOTO 39
41 DATA 123,205,1,9,205,153,8,221
42 DATA 110,8,221,102,9,201,
43 POKE 65056%,I%,SWAP%(I%)
44 ; CHR$(12%)TAB(3%);
45 ; '< ABC80-CASDISK TILL DRIVE ';
46 GET D$ : IF D$<>'1' AND D$<>'0' 46
47 ; D$' >' : D$='DR'+D$+':'
48 ; 'STOPP VID FEL ?'; : GET X$
49 IF X$='J' OR X$='j' F%=1%
50 ; CHR$(13%)TAB(3%)STRING$(30%,61%);
51 IF F% ; CUR(1%,14%)'FELSTOPP';
52 REM  HUVUD-LOOP 
53 PREPARE D$+'TEMP.][\' ASFILE 2%
54 F$='   ' : N%=0%
55 ONERRORGOTO 55 : IF N%=3% GOTO 114
56 IF (INP(56%) AND 95%)=67% GOTO 114
57 N%=N%+1%
58 OPEN 'CAS:' ASFILE 1%
59 ONERRORGOTO 103 : B%=65535%
60 X%=PEEK(65011%)*2%+884%
61 X%=PEEK(X%)+SWAP%(PEEK(X%+1%))
62 POKE P%,X%,SWAP%(X%)
63 E$=RIGHT$(C$,7%)
64 REM  BLOCK-LOOP 
65 Z%=CALL(A%,1%) : B%=B%+1%
66 IF B%=0% T%=PEEK(Z%) ELSE 70
67 IF (T% OR 1%)=131% T%=1% : GOTO 70
68 IF T%=0% T%=3% : GOTO 70
69 IF T%<129% THEN T%=2% ELSE 100
70 POKE R%,Z%,SWAP%(Z%) : S2$=B$
71 IF LEFT$(B$,7%)=S1$ 78
72 Z%=CALL(28666%,2%)
73 Q0$=B$ : Z%=CALL(28670%,B%)
74 P$='SEKTORER KOPIERADE '
75 GOSUB 109
76 ON T% GOSUB 85,90,93
77 IF L%=0% 65
78 REM  SLUT P] FIL 
79 B$=S2$ : CLOSE 1% : CLOSE 2%
80 ONERRORGOTO 82 : KILL D$+E$
81 ONERRORGOTO 0
82 NAME D$+'TEMP.][\' AS D$+E$
83 GOTO 53
84 REM  BAC-FIL 
85 IF B%=0% I%=2% ELSE I%=1%
86 L%=ASC(MID$(B$,I%,1%))
87 IF L%<2% RETURN 
88 I%=I%+L% : GOTO 86
89 REM  TEXTFIL 
90 IF LEFT$(B$,7%)=E3$ L%=1% : RETURN 
91 L%=0% : RETURN 
92 REM  ABS-FIL 
93 I%=1%
94 L%=ASC(MID$(B$,I%,1%))
95 IF L%=255% L%=0% : RETURN 
96 L%=ASC(MID$(B$,I%+1%,1%))
97 IF L%=0% L%=1% : RETURN 
98 I%=I%+L%+8% : GOTO 94
99 REM  FEL FORMAT 
100 P$='FEL FORMAT' : GOSUB 109
101 GOTO 54
102 REM  ERROR 
103 P$='ERR'+NUM$(ERRCODE) : GOSUB 109
104 CLOSE 1% : CLOSE 2%
105 KILL D$+'TEMP.][\'
106 IF F% GET X$
107 GOTO 53
108 REM  SKRIV FILNAMN 
109 F$=' '+NUM$(B%+2%)
110 F$=RIGHT$(F$,LEN(F$)-2%)
111 ; CHR$(13%)E$' 'F$' 'P$TAB(39%);
112 RETURN 
113 REM  AVSLUTNING 
114 CLOSE 1% : CLOSE 2%
115 KILL D$+'TEMP.][\'
116 POKE 65013%,0%
117 END