1 REM +++++++++++++++++++++++++++++++
2 REM ! Program ....   JULSTAR.BAS
3 REM ! Utg}va         80-12-14
4 REM ! av David Andersson <5201>
5 REM ! Minne 16 Kbytes
6 REM ! Screening TES
7 REM +++++++++++++++++++++++++++++++
8 REM 
10 REM Visar roterande stor stj{rna i
11 REM grafik.Formen variabel.
100 REM 
110 REM N0%=ANTAL BILDER
120 N0%=7
130 REM N=ANTAL UDDAR
140 N=5
150 REM N1=TILL VILKEN UDD EN LINJE SKA G]
160 N1=2
170 X0=35 : Y0=30
180 X9=36 : Y9=41
190 DIM B$(N0%-1%)=912%,A$=38%
200 REM TESTA ERR 3
210 FOR X%=0% TO N0%-1% : B$(X%)='-' : NEXT X%
220 B%=0%
230 P=2*PI
240 FOR V0=0 TO P/N*.9999 STEP P/N/N0%
250 REM T\M SK[RM
260 ; CHR$(12%); : FOR X%=0% TO 23%
270 ; CUR(X%,0%)CHR$(23%); : NEXT X%
280 REM G\R STJ[RNA
290 FOR V=V0 TO V0+P*.9999 STEP P/N
300 W=V+2*PI/N*N1
310 X1%=X9+X0*SIN(V) : Y1%=Y9+Y0*COS(V)
320 X2%=X9+X0*SIN(W) : Y2%=Y9+Y0*COS(W)
330 GOSUB 1000
340 NEXT V
350 ; CUR(12%,19%)'ABC';
360 REM SPARA BILDEN
370 GOSUB 2000 : B%=B%+1%
380 NEXT V0
390 B0%=B%-1%
400 ; CHR$(7%);
500 REM VISA BILDER
510 FOR B%=0% TO B0%
520 ; B$(B%);
530 FOR X%=0% TO 0% : NEXT X%
540 NEXT B% : GOTO 500
1000 REM LINJE MELLA (X1%,Y1%) OCH (X2%,Y2%)
1010 X3=X2%-X1% : Y3=Y2%-Y1%
1020 IF X3=0 AND Y3=0 LET X3=.5
1030 IF ABS(X3)<ABS(Y3) GOTO 1100
1040 X=Y3/X3 : FOR X%=X1% TO X2% STEP SGN(X3) : SETDOT X%,Y1%+(X%-X1%)*X+.5 : NEXT X%
1050 RETURN 
1100 REM 
1140 X=X3/Y3 : FOR Y%=Y1% TO Y2% STEP SGN(Y3) : SETDOT X1%+(Y%-Y1%)*X+.5,Y% : NEXT Y%
1150 RETURN 
2000 REM SPARA BILD I B$(B%)
2010 B$(B%)=''
2020 FOR R%=0% TO 23%
2030 REM P% PEKAR P] RAD R% I BILDMINNET
2040 P%=PEEK(884%+R%+R%)+SWAP%(PEEK(885%+R%+R%))
2050 A$=''
2060 FOR K%=4% TO 35% : A$=A$+CHR$(PEEK(P%+K%)) : NEXT K%
2070 B$(B%)=B$(B%)+CUR(R%,4%)+A$
2080 NEXT R%
2100 RETURN