10 REM +++++++++++++++++++++++++++++++++
11 REM ! Program ....   MX80PR
12 REM ! Utg}va  1.0    1982-02-07
13 REM ! av  Carl K|vamees
14 REM ! Minne 16 Kbytes f|r printer
15 REM ! Ins{nt av 767
16 REM +++++++++++++++++++++++++++++++++
17 REM 
18 REM Screening och komplettering f|r
19 REM MICROLINE av +TES+ 85 11 17
20 REM 
21 REM +-------------------------------
22 REM !
23 REM !   Subrutin som dumpar sk{rmen
24 REM !   p} printer s} som MX80 eller
25 REM !   liknande som har grafiken 
26 REM !   mellan CHR$(160-223).
27 REM !
28 REM !   Tag bort raden f|r MX80 om
29 REM !   du har en MICROLINE.
30 REM !
31 REM !   Det {r ganska l{tt att {ndra
32 REM !   pgm'et s} man kan ange tex 
33 REM !   filnr, dumpning mellan rader
34 REM !   dumpning mellan kolumner.
35 REM !
36 REM !      VARIABELER
37 REM !      ==========
38 REM !  In- 
39 REM !     I%=TAB till PR
40 REM ! Pgm-
41 REM !     I9%=Rad
42 REM !     I8%=Kolumn
43 REM !     I7%=IF Grafik
44 REM !     I6%=I9%,I8% Tecken
45 REM !     I5%,I4%=variabler beroende
46 REM !             av printertyp
47 REM !     I$=Rad tecken
48 REM !
49 REM +-------------------------------
50 I%=20% : REM TAB(20)
51 GOSUB 64000 : END 
64000 DEFFNA%(I9%,I8%)=PEEK(884%+2%*I9%)+SWAP%(PEEK(885%+2%*I9%))+I8%
64001 OPEN 'PR:' ASFILE 1%
64002 I4%=32% : I5%=0% : REM  MICROLINE
64003 I4%=0% : I5%=-32% : REM  MX80 
64004 FOR I9%=0% TO 5% : REM .            *RADER*
64005 I7%=0% : I$=''
64006 FOR I8%=0% TO PEEK(590%)-1% : REM .  *KOL/RAD*
64007 I6%=PEEK(FNA%(I9%,I8%))
64008 IF I6%=23% I7%=1% : I6%=32% : GOTO 64014
64009 IF I6%=7% I7%=0% : I6%=32% : GOTO 64014
64010 IF I6%<96% IF I6%>63% 64014
64011 IF I7% THEN 64012 ELSE 64014
64012 IF I6%<64% IF I6%>31% I6%=I6%+128%+I4%
64013 IF I6%<128% IF I6%>95% I6%=I6%+128%+I5%
64014 I$=I$+CHR$(I6%)
64015 NEXT I8%
64016 IF (RIGHT$(I$,LEN(I$))=' ' AND LEN(I$)>0%) THEN I$=LEFT$(I$,LEN(I$)-1%) : GOTO 64016
64017 ; #1%,TAB(I%)I$
64018 NEXT I9% : CLOSE 1% : I$='' : RETURN