10REM .  SAVE ARKEOLOG
20REM 
30REM <><>ARKEOLOG<><>
40REM <
50REM < DAVID ANDERSSON
60REM <
70REM < 810215
80REM <
90REM <><><><><><><><>
100REM 
110REM 
120REM 
150RANDOMIZE
160;CHR$(12%)' <><><><><>';
170;' ARKEOLOG <><><><><>':;
180;'Du {r en ber|md arkeolog som ';
190;'ska':;'utforska en faraoisk';
200;' pyramid.':;
210;'I pyramiden finns det ett ';
220;'myller':;'av g}ngar som du ';
230;'ska f|lja tills'
240;'du kommer till mitten,'
250;'d{r SKATTEN finns.'
260;CUR(22%,0%)'*)  Har du aldrig spelat ARKEOLOG n}gon'
270;'    g}ng s} tryck p} +';
280;CUR(10%,0%)' <><><><><> ';
290;'SV]RHET <><><><><>':;
300;'V{lj pyramidstorlek *) (1-5)';
310GETA$:IFA$='+'ORA$='?'CHAIN'ARKEOLOG.HLP'
320IFA$<'1'ORA$>'5'THEN310
330;A$:V%=VAL(A$)
340FORZ%=0%TO3000%:NEXTZ%
350;CHR$(12%)' <><><><><> ARKEOLOG <><><><><>':;
360;:;'TANGENTBORDET :'
370;:;' g} 4 meter fram}t =   S':;' vrida 90 gr. h|ger  = X'
380;' vrida 90 gr. v{nster= Z'
382;' n|d utg}ngning =      U':;:;
390;'Observera att livsl{ngden p}'
400;'ficklamps-batteriet {r begr{nsad.'
410;:;:;
420;'Kom i h}g! Det du ser p} sk{rmen {r'
430;'en TV-bild inifr}n pyramiden.'
440;CUR(22%,0%)'(v{nta 'MID$(' ett tv} trefyra fem',V%*4%-3%,4%)' |gonblick)';
450X0%=3%+V%*2%:Y0%=2%+V%*2%
460REM LABYRINT
470X%=240%
480DIMG%(15%,14%),X%(X%),Y%(X%),X1%(4%),Y1%(4%),S%(4%),A%(32%)
490R%=-1%:F%=-1%:M%=1%
500X%=X0%/2%:Y%=Y0%/2%:RESTORE520
510READX1%,Y1%,A%:IFA%LETG%(X%+X1%,Y%+Y1%)=A%:GOTO510
520DATA-1,0,2,0,-1,6,0,0,31,0,1,3
530DATA1,-1,12,1,0,13,1,1,9,0,0,0
540X%=X0%:G%(X%,Y%)=2%
550REM 
560IFM%IFY%<>Y0%/2%LETZ%=SGN(Y%-Y0%/2%):M%=0%
570R%=R%+1%:X%(R%)=X%:Y%(R%)=Y%:GOTO600
580F%=F%+1%:IFF%>R%THEN720
590X%=X%(F%):Y%=Y%(F%)
600K%=0%:Y1%=Y%
610X1%=X%+1%:S%=2%:IFX1%<=X0%GOSUB700
620X1%=X%-1%:S%=8%:IFX1%>=0%GOSUB700
630X1%=X%:Y1%=Y%+1%:S%=4%:IFY1%<=Y0%GOSUB700
640Y1%=Y%-1%:S%=1%:IFY1%>=0%GOSUB700
650IFK%=0%THEN580
660K%=1%+RND*K%:X1%=X1%(K%):Y1%=Y1%(K%)
670G%(X%,Y%)=G%(X%,Y%)ORS%(K%)
680G%(X1%,Y1%)=G%(X1%,Y1%)OR(S%(K%)*17%/4%AND15%)
690X%=X1%:Y%=Y1%:GOTO550
700IFG%(X1%,Y1%)RETURN
710K%=K%+1%:S%(K%)=S%:X1%(K%)=X1%:Y1%(K%)=Y1%:RETURN
720IFZ%=-1%LETS%=4%ELSES%=1%
730X%=X0%/2%-1%:Y%=Y0%/2%
740G%(X%,Y%)=G%(X%,Y%)ORS%:Y%=Y%-Z%
750G%(X%,Y%)=G%(X%,Y%)OR(S%*17%/4%AND15%)
760FORD1%=0%TO3%
770X%=RND*(X0%+1%):Y%=RND*(Y0%+1%)
780IFG%(X%,Y%)AND(481%OR2%^D1%)THEN770
790G%(X%,Y%)=G%(X%,Y%)OR2%^D1%*32%
800NEXTD1%
810Q0%=RND<.1
820;CUR(22%,0%)'TRYCK RETURN N[R DU L[ST KLART';
830GETA$:IFA$<>CHR$(13%)THEN830
840T1%=255%:T2%=255%:T3%=255%
850S%=0%:M%=0%
860REM ING]NG
870IFM%THEN2480
880R%=33%:Q1%=1%:Q2%=0%
890;CHR$(12%)' <><><><><> ARKEOLOG <><><><><>'
900FORX%=11%TO21%:;CUR(X%,0%)CHR$(23%);:NEXTX%
910;CUR(21%,2%)STRING$(36%,112%);
920;CUR(11%,15%)STRING$(11%,35%);
930FORX%=33%TO65%:SETDOTX%,30%
940SETDOTX%,52%:NEXTX%
950;CUR(2%,0%);
960IFS%;'  Skatten {r kvar d{rinne'ELSE;'Detta {r ing}ngen till pyramiden'
970;:;'Har du kompass med dig (J/N)';:GOSUB2680:Q2%=A%
980;'Har du ficklampa ?     (J/N)';
990GOSUB2680:IFA%LETQ1%=0%ELSEQ1%=1%
1000;'Vill du se kartan ?    (J/N)';
1010GOSUB2680:IFA%=0%THEN1150
1020SETDOTR%,2%
1030FORX1%=0%TOX0%:X%=X1%*2%+R%+1%
1040FORY1%=0%TOY0%:Y%=Y1%*2%+3%
1050F%=G%(X1%,Y1%):SETDOTX%+1%,Y%+1%
1060IFX1%<>0%ANDY1%THEN1100
1070SETDOTX%+1%,Y%-1%:SETDOTX%-1%,Y%+1%
1080IF(F%AND1%)=0%SETDOTX%,Y%-1%
1090IF(F%AND8%)=0%SETDOTX%-1%,Y%
1100IF(F%AND4%)=0%SETDOTX%,Y%+1%
1110IF(F%AND2%)=0%SETDOTX%+1%,Y%
1120NEXTY1%:NEXTX1%
1130X%=X0%/2%*2%+R%+2%:Y%=Y0%/2%*2%+2%
1140CLRDOTX%,Y%:CLRDOTX%,Y%+2%
1150;:;'TRYCK S N[R DU G]R IN';
1160GETA$:IFA$<>'S'ANDA$<>'s'THEN1160
1170RESTORE1200:S%=0%:M1%=35%:M2%=40%
1180FORS%=0%TO11%:READA%(S%):NEXTS%
1190FORS%=S%TO32%:A%(S%)=2%:NEXTS%
1200DATA35,29,19,14,11,9,7,6,5,4,3,2
1210POKE65008%,T1%,T2%,T3%
1220X%=X0%+1%:Y%=Y0%/2%:D%=3%:G%=1:S9%=8%:GOTO1320
1230REM KRYPA
1240;CUR(22%,0%);:GETA$:G%=0%
1250IFINSTR(1%,'uU',A$)LETM%=0%:S%=1%:GOTO860
1252Z%=NOTPEEK(65009%)+SWAP%(PEEK(65010%))
1254S9%=7%-Z%/16%
1260IFINSTR(1%,'Zz',A$)LETD%=D%+1%AND3%:GOTO1320
1270IFINSTR(1%,'Xx',A$)LETD%=D%-1%AND3%:GOTO1320
1280IFINSTR(1%,'Ss',A$)LETG%=1%ELSE;CHR$(7);:GOTO1230
1290IFG%(X%,Y%)AND2%^D%THEN1320
1300;CUR(22%,6%)CHR$(1%)'Det {r en V[GG i v{gen'CHR$(23%,7%);
1310GOTO1230
1320REM 
1330RESTORE1340
1340DATAV[STER,0,-1,S\DER,1,0,\STER,0,1,NORR,-1,0
1350FORD1%=0%TOD%:READA$,X2%,Y2%:NEXTD1%
1360IFG%LETX%=X%+X2%:Y%=Y%+Y2%
1370IFX%>X0%LETS%=1%:GOTO860
1380IFG%(X%,Y%)AND16%THEN2130
1390REM SYNBILD
1400;CHR$(12%);:FORZ%=0%TO23%:;CUR(Z%,0%)CHR$(23%);:NEXTZ%
1410S%=0%:IFQ2%;CUR(22%,17%)A$;
1420X1%=X%+X2%*S%/2%:Y1%=Y%+Y2%*S%/2%
1430Z0%=A%(S%):Z1%=A%(S%+1%):G%=G%(X1%,Y1%)
1440IFX1%>X0%THEN1770
1450IFG%AND16%THEN1900
1460F%=2%^D%
1470IFQ1%ORS%>S9%THEN1730
1480F1%=2%^(D%+1%AND3%):F2%=2%^(D%-1%AND3%)
1490IFS%=2%ANDF1%*32%ANDG%;CUR(11%,12%)'5';
1500IF(G%ANDF1%)=0%FORZ%=Z1%TOZ0%:SETDOTM1%-Z%,M2%-Z%:SETDOTM1%+Z%,M2%-Z%:NEXTZ%:GOTO1550
1530IFS%FORZ%=-Z0%TOZ0%:SETDOTM1%+Z%,M2%-Z0%:NEXTZ%
1540FORZ%=Z1%TOZ0%:SETDOTM1%-Z1%,M2%-Z%:SETDOTM1%+Z1%,M2%-Z%:NEXTZ%
1550IFS%=2%ANDF2%*32%ANDG%;CUR(11%,28%)'j';
1560IF(G%ANDF2%)=0%FORZ%=Z1%TOZ0%:SETDOTM1%-Z%,M2%+Z%:SETDOTM1%+Z%,M2%+Z%:NEXTZ%:GOTO1610
1590IFS%FORZ%=-Z0%TOZ0%:SETDOTM1%+Z%,M2%+Z0%:NEXTZ%
1600FORZ%=Z1%TOZ0%:SETDOTM1%-Z1%,M2%+Z%:SETDOTM1%+Z1%,M2%+Z%:NEXTZ%
1610IFG%ANDF%*32%IFS%=0%GOSUB2040ELSEIFS%=2%;CUR(11%,20%)'';ELSEIFS%=4%;CUR(11%,20%)'0';
1650IF(F%ANDG%)=0%FORZ%=-Z1%TOZ1%:SETDOTM1%+Z1%,M2%+Z%:SETDOTM1%-Z1%,M2%+Z%:NEXTZ%:GOTO1230
1680FORZ%=A%(S%+2%)TOZ1%
1690SETDOTM1%-Z%,M2%-Z%:SETDOTM1%-Z%,M2%+Z%:SETDOTM1%+Z%,M2%-Z%:SETDOTM1%+Z%,M2%+Z%:NEXTZ%
1710IFF1%ANDG%FORZ%=-Z1%TOZ1%:SETDOTM1%+Z%,M2%-Z1%:NEXTZ%
1720IFF2%ANDG%FORZ%=-Z1%TOZ1%:SETDOTM1%+Z%,M2%+Z1%:NEXTZ%
1730IF(G%ANDF%)=0%THEN1230
1750S%=S%+2%:GOTO1420
1760REM EXIT
1770IFS%>6%THEN1870
1780FORZ%=-Z0%TOZ0%
1790SETDOTM1%+Z%,M2%-Z0%:SETDOTM1%+Z%,M2%+Z0%
1800SETDOTM1%-Z0%,M2%+Z%:NEXTZ%
1810RESTORE1840
1820FORD1%=2%TOS%STEP2%
1830READZ%:NEXTD1%
1840DATA32274,32658,31930
1850POKEZ%,197%,216%,201%,212%
1860GOTO1230
1870FORZ1%=M1%-Z0%TOM1%+Z0%
1880FORZ%=-Z0%TOZ0%
1890SETDOTZ1%,M2%+Z%:NEXTZ%:NEXTZ1%:GOTO1230
1900REM FARAO
1910FORZ%=-Z0%TOZ0%:SETDOTM1%+Z%,M2%-Z0%
1920SETDOTM1%+Z%,M2%+Z0%:SETDOTM1%-Z0%,M2%+Z%:NEXTZ%
1930;CUR(6%,16%)'4   4   4';
1940;CUR(7%,16%)'*0  5  :';
1950;CUR(8%,17%)'i  5 h!';
1960;CUR(9%,12%)',p    e 5`%   `8$';
1970;CUR(10%,14%)'#,p "456 `8&!  ';
1980;CUR(11%,14%)'`p #,zo8&!';
1990;CUR(12%,14%)'5 ),,,,,ppp<4';
2000;CUR(13%,14%)'uppssssupppp5';
2010;CUR(14%,12%)'#!5<,,,,,,,,,45#!';
2020;CUR(15%,14%)'ussssssssssq5';
2030GOTO1230
2040REM M]LNING
2050OND%+1%RESTORE2060,2070,2080,2090
2060DATA'  h8!',' `n','eqzp:',' ###'
2070DATA' `p','h! i','"dp&','& 4"$'
2080DATA'` t4','e {!','h0',''
2090DATA'"cmg#','(!j )','  j',''
2100FORD1%=10%TO13%:READA$
2110;CUR(D1%,18%)A$;:NEXTD1%
2120RETURN
2130REM FRAMME
2140IFPEEK(65008%)<4%2140ELSET1%=PEEK(65008%):T2%=PEEK(65009%):T3%=PEEK(65010%)
2150;CHR$(12%)' <><><><> GRAVKAMMAREN <><><><><><>':;
2160;CHR$(17%)'wwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwww5':;
2170IFM%THEN2410
2180IFQ0%THEN2430
2190;' Nu {r du framme hos gamle farao.'
2200;CHR$(23%)STRING$(32%,35%)
2210REM FOR Z%=0% TO 3000% : NEXT Z%
2220A$=CHR$(23%)+'    ':;A$'     `  0'
2230;A$'   (#d!: p'
2240;A$'   `,$%%&(!'
2250;A$'j#   k##7   #5'
2260;A$'*xp8)6  i&dpt%'
2270;A$'    =,,n   '
2280;A$' 74  e  :  hk'
2290;A$' uj0 ",,! `5z':;
2300;'Har du kameran med dig (J/N)';
2310GOSUB2680:IFA%=0%;:;']]]]]]!':;'N}ja.';:GOTO2330
2320;:;'Ta nu n|dv{ndiga foton och'
2330;'ta s} mycket guld du orkar b{ra.'
2340;:;'Nu ska du ut ur pyramiden !'
2350;CUR(21%,0%)'klar ?(J/N)';:GOSUB2680
2360IFA%GOTO2390
2370;CUR(21%,0%)' JAS] !       ';
2380FORZ%=0%TO5000%:NEXTZ%:GOTO2350
2390POKE65008%,T1%,T2%,T3%
2400X%=X0%/2%-1%:Y%=Y0%/2%:D%=1%:G%=0%:M%=1%:GOTO1320
2410;'H{r har du redan varit':;
2420GOTO2340
2430;' TOMT !  INGENTING !':;
2440OUT6%,7%
2450FORZ%=0%TO6000%:NEXTZ%:OUT6%,0%
2460;'Tusan ocks} !!':;'H{r har ju varit gravplundrare.':;
2470GOTO2340
2480REM KLAR
2490;CHR$(12%)' <><><><><> ARKEOLOG <><><><><>':;
2500IFPEEK(65008%)<4%2500ELSET1%=PEEK(65008%)XOR255%:T2%=PEEK(65009%)XOR255%:T3%=PEEK(65010%)XOR255%
2510T=(T3%*65536+T2%*256+T1%)/50
2520T1%=T/60:T2%=T-60*T1%
2530;'Det tog';:IFT1%;T1%' minuter och';
2540;T2%' sekunder.':;:;
2550IFQ0%;'B{ttre lycka n{sta g}ng (gravg}ng haha)':;:;:GOTO2600
2560T3%=T/V%:IFT3%<14%;'Du {r en faraologisk sensation!':GOTO2600
2570IFT3%<25%;'Nu blir du {nnu mera ber|md':GOTO2600
2580IFT3%<60%;'Det var ju bra gjort':GOTO2600
2590;'Du kom ut till slut !'
2600;:;
2610;'Vill Du forts{tta utforska ? (J/N)';
2620GOSUB2680:IFA%=0%END:CHAIN'MENY'
2630;:IFQ0%THEN2660
2640;'Ny pyramid ? (J/N)';
2650GOSUB2680:IFA%=0%THEN840
2660FORX%=0%TOX0%:FORY%=0%TOY0%:G%(X%,Y%)=0%:NEXTY%:NEXTX%
2670GOTO160
2680REM GET
2690GETA$:IFINSTR(1%,'Nn',A$)LETA%=0%:;'Nej':RETURN
2700IFINSTR(1%,'Jj'+CHR$(13%),A$)LETA%=1%:;' Ja':RETURNELSE2690