11 REM +++++++++++++++++++++++++++++++++
2 REM ! Program ....   HUVUD
3 REM ! Utg}va  2.02   1981-10-16
4 REM ! av (c) Gunnar Tidner
5 REM ! {ndrat av G|ran Sundqvist
7 REM ! Minne 16 Kbytes f|r flexskiva
9 REM +++++++++++++++++++++++++++++++++
10 REM Ett f|rs|k att bilda en standard
11 REM f|r RUBRIKBLOCK till ABC-klub-
12 REM bens program.
13 REM -------------
14 REM En utfil :  "HEADER.BAS" bildas
15 REM som sedan med MERGE sammanfogas
16 REM med huvudprogrammet innan slut-
17 REM giltig programlagring sker.
18 REM ---------------------------
19 REM Vid "Program .... " kan punkter-
20 REM na utbytas mot ett programnummer
21 REM som tillsammans med utg}venummer
22 REM listas om man anv{nder ett spec.
23 REM LIB fr}n Blackebergs Gymnasium.
24 REM --------------------------------
80 PREPARE "HEADER.BAS" ASFILE 1 : L%=1
90 ; "Programnamn:"; : INPUTLINE P$ : ; : P$=LEFT$(P$,LEN(P$)-2%)
100 IF LEN(P$)>8 ; 'max 8 tecken' : GOTO 90
105 IF LEN(P$)<1 THEN 320
110 ; "Datum:"; : INPUTLINE D$ : ; : D$=LEFT$(D$,LEN(D$)-2%)
120 ; "Version:"; : INPUTLINE V$ : ; : V$=LEFT$(V$,LEN(V$)-2%)
130 ; "Upphovsman:"; : INPUTLINE U$ : ; : U$=LEFT$(U$,LEN(U$)-2%)
140 ; "Copyright om annan {n" : ; "upphovsmannen:"; : INPUTLINE C$ : ; : C$=LEFT$(C$,LEN(C$)-2%)
150 ; "[ndrat av  :"; : INPUTLINE P1$ : ; : P1$=LEFT$(P1$,LEN(P1$)-2%)
160 ; "Krav p} utrustning"
170 ; "Flexskiva:"; : GET F$ : IF INSTR(1%,"jJnN",F$)=0 THEN 170
180 IF (ASC(F$) AND 223%)=74 THEN F$=" f|r flexskiva" ELSE F$=""
190 ; "Minnesbehov i Kbytes:"; : INPUT B
200 ; "Ins{nt av:"; : INPUTLINE I$ : ; : I$=LEFT$(I$,LEN(I$)-2%)
210 ; #L%,"1 REM +++++++++++++++++++++++++++++++++"
220 ; #L%,"2 REM ! Program ....   ";P$
230 D$=" Utg}va  "+V$+SPACE$(7-LEN(V$))+D$
240 ; #L%,"3 REM !";D$
250 IF LEN(C$)=0 THEN U$="(c) "+U$
260 ; #L%,"4 REM ! av ";U$
270 IF LEN(P1$) THEN ; #L%,"5 REM ! {ndrat av "P1$
280 IF LEN(C$) THEN ; #L%,"6 REM ! Copyright ";C$
290 ; #L%,"7 REM ! Minne";B;" Kbytes";F$
300 IF LEN(I$) THEN ; #L%,"8 REM ! Ins{nt av ";I$
310 ; #L%,"9 REM +++++++++++++++++++++++++++++++++"
320 ; "extra kommentar rad"10+I% : INPUTLINE M$ : ; : M$=LEFT$(M$,LEN(M$)-2%)
330 IF LEN(M$) THEN ; #L%,RIGHT$(NUM$(10%+I%),2);" REM ";M$ : I%=I%+1% : GOTO 320
340 CLOSE 1