1 REM +++++++++++++++++++++++++++++++++
2 REM ! Program ....   MATRIX
3 REM ! Kommenterad i ABC- BLADET 1984:2
4 REM ! av        Sven Wickberg <1384> 
6 REM ! Minne 16 Kbytes
7 REM ! Ins{nt av Sven Wickberg
8 REM +++++++++++++++++++++++++++++++++
10 REM SAVE MATRIX    84 02 06 SW
20 REM bokstavspussel efter en id` fr}n
30 REM More Basic Computer Games
40 GOTO 120
50 REM h{nvisingar-----------------------
60 GOTO 150 : REM h{mta ord
70 GOTO 290 : REM blanda bokst{verna
80 GOTO 420 : REM skriv bokstavsmatris
90 GOTO 580 : REM skriv ruta f|r l|saren
100 GOTO 710 : REM printerrutin
110 REM ---------------------------------
120 ; CHR$(12%)'MATRIX ORDPUSSEL'
130 GOSUB 800 : REM information
140 GOSUB 710 : REM printer?
150 REM H[MTA ORD ----------------------
160 ; 'HUR M]NGA ORD'; : INPUT A
170 ; 'HUR L]NGA'; : INPUT L
180 IF INP(56%)>127% THEN 180
190 H1=A*L
200 DIM A$=H1,A$(H1)=1,A(H1),B$=H1,B$(H1)=1,B(H1),C(H1)
210 ; 'Ord 1:  ';
220 FOR I=1 TO H1
230 GET W$ : ; W$;
240 A$=A$+W$
250 A$(I)=W$ : A(I)=I
260 IF I<H1 IF I/L=INT(I/L) ; : ; 'Ord'INT(I/L)+1':  ';
270 NEXT I
280 ; 
290 REM BLANDA BOKST[VER------------------
300 H=H1
310 FOR I=1 TO A
320 FOR J=1 TO L
330 X=INT(RND*H+1)
340 B$=B$+A$(X)
350 A$(X)=A$(H)
360 C(A(X))=I+J : REM MINNS VAR BOKSTAVEN HAMNAT 
370 A(X)=A(H) : REM FLYTTA SISTA TILL H]LET
380 H=H-1
390 NEXT J
400 NEXT I
410 ; 
420 REM SKRIV MATRISER--------------------
430 FOR I=1 TO L
440 ; TAB(3)I' '; : REM siffror ovanf|r
450 IF P% THEN ; #P%TAB(13%)I' ';
460 NEXT I
470 ; : ; : IF P% ; #P% : ; #P%
480 ; ' 1 '; : IF P% ; #P%TAB(10)' 1 ';
490 FOR I=1 TO H1
500 ; ' 'MID$(B$,I,1)' ';
510 IF P% ; #P%' 'MID$(B$,I,1)' ';
520 IF I=H1 THEN 550 : REM ingen v{nstersiffra efter sista
530 IF P% IF I/L=INT(I/L) THEN ; #P% : ; #P% : ; #P%TAB(10%)INT(I/L)+1' ';
540 IF I/L=INT(I/L) THEN ; : ; : ; INT(I/L)+1' ';
550 NEXT I
560 IF P%=0% ; : ; : ; 'SKRIV AV - TRYCK RETURN' : GET W$
570 ; : ; : IF P% ; #P% : ; #P% : ; #P% : ; #P%
580 REM L\SNINGSRUTAN
590 FOR I=1 TO A
600 ; TAB(1%); : IF P% ; #P%TAB(10);
610 FOR J=1 TO L
620 K=K+1 : ; C(K)'    '; : IF P% ; #P%C(K)'      ';
630 NEXT J
635 ; : ; : IF P% ; #P% : ; #P%
640 FOR J=1 TO L
650 ; '_____ '; : IF P% ; #P%TAB(9)'_____   ';
660 NEXT J
670 ; : ; : IF P% ; #P% : ; #P%
680 NEXT I
690 END 
700 REM ---------------------------------
710 REM printer
720 ; : ; 'Utskrift p} PRINTER (J)'; : INPUT W$
730 IF NOT (W$='j' OR W$='J' OR W$='') THEN 780
740 P$='PR:VSA30A72.5' : ; 'Vad heter printern ('P$') '; : INPUT W$
750 IF W$<>'' THEN P$=W$
760 P%=1% : OPEN P$ ASFILE P%
770 ; 'Printer EJ KLAR'; : ; #P%CHR$(13%); : ; CHR$(13%)TAB(25%)CHR$(13);
780 RETURN 
790 REM ---------------------------------
800 REM information
810 ; : ; 'Du skriver in ett antal lika l}nga ord.'
820 ; : ; 'Datorn blandar om bokst{verna och visar'
830 ; 'resultatet i en fyrkant med rader och'
840 ; 'kolumner numrerade.'
850 ; : ; '(Om du ej anv{nder printer skriver du'
860 ; 'av denna fyrkant.)'
870 ; : ; 'Sedan visas prickade linjer med plats'
880 ; 'f|r de ursprungliga orden. Man f}r tips'
890 ; 'om du aktuella bokst{verna genom ett'
900 ; 'tal som {r summan av rad och kolumn i'
910 ; 'bokstavsfyrkanten.'
920 ; : ; '(Tryck RETURN f|r att b|rja)'
930 GET W$ : RETURN