10 REM ********* H[NGD *********
20 REM *  Id` samt utf|rande : *
30 REM *                       *
40 REM *   MICHAEL WIDENIUS    *
50 REM *                       *
60 REM *  Data : KAJ + K[THE   *
65 REM *           MICHAEL     *
70 REM *************************
71 REM OMR]DE : 
74 REM REKREATION   - ELLER HUR
75 REM 
76 DIM A%(100%),A$=120%,B$=1%,C$=35%
80 ; CHR$(12%)TAB(17%)"H[NGD" : ; : ; 
90 ; "Spelet g}r ut p} att hitta ett ord.     Bokst{verna fr}gas en och en och"
100 ; "om ordet inneh}ller bokstaven i "
110 ; "fr}ga s{tts den ut p} sin r{tta plats " : ; " ( platser ??) . F|r varje bokstav som"
120 ; "inte finns i ordet blir galgen allt" : ; "fullkomligare {nda tills man {r h{ngd."
130 ; : ; "Spelet spelas i tio ronder med ett nytt ord f|r varje rond."
135 ; : ; "OBS !  Anv{nd endast STORA BOKST[VER !" : ; 
140 ; : ; "Trevlig spelstund !!"
150 ; : ; "Tryck p} 'RETURN' f|r b|rjan !"; : INPUTLINE A$
155 B1%=-1% : RANDOMIZE 
160 D1%=0% : FOR D%=1% TO 10%
170 REM *** RAMEN ***
180 ; CHR$(12%) : FOR I%=2% TO 22% : ; CUR(I%,16%)CHR$(151%); : NEXT I%
190 FOR I%=6% TO 67% : SETDOT I%,38% : SETDOT I%,79% : NEXT I%
200 FOR I%=38% TO 79% : SETDOT 6%,I% : SETDOT 67%,I% : NEXT I%
210 A%=0% : X%=0%
220 ; CUR(0%,34%)"("D%" )"
230 B%=400% : REM ANTAL ORD I DATA !!
240 REM *** ORD S\KES ***
250 C%=RND*B%
260 FOR I%=0% TO B1% : IF A%(I%)=C% 250
270 NEXT I% : B1%=I% : A%(B1%)=C%
280 REM 
290 REM B\R F\RSTORAS VID TILL[GG !!!
300 ON C%/100%+1% RESTORE 1120,1220,1320,1420,1520
310 FOR I%=0% TO C%-C%/100%*100% : READ A$ : NEXT I%
330 REM *** GISSANDET B\RJAR ***
340 ; CUR(12%,0%)STRING$(LEN(A$),95%)CUR(0%,0%)"Du har anv{nt bokst{verna:"
350 C$=" " : B2%=0% : B5%=0% : POKE 65013%,0%
360 ; CUR(1%,B2%); : GET B$
370 IF B$>"^" OR B$<"@" OR INSTR(1%,C$,B$) THEN 360
380 C$=C$+B$ : ; B$ : B2%=B2%+2%
400 B3%=0% : B4%=0%
410 B3%=INSTR(B3%+1%,A$+"?",B$)
420 IF B3% THEN 460 ELSE IF B4% THEN 360 ELSE A%=A%+1% : ; CHR$(7%);
430 ON A% GOSUB 570,640,680,720,760,820,870,910,960
440 IF A%<>9% THEN 360
450 ; CUR(10%,0%)"TYV[RR ORDET VAR" : ; : ; A$ : GOTO 1000
460 B4%=1% : ; CHR$(7%)CUR(12%,B3%-1%)B$ : B5%=B5%+1%
470 IF B5%<>LEN(A$) THEN 410 ELSE D1%=D1%+1% : ; : ; "BRAVO - R[TT !!"
480 FOR I=1% TO 3000% : NEXT I
490 NEXT D% : REM N[STA ORD
499 REM 
500 REM *** SPELET SLUT ***
501 REM 
510 IF B1%>=99% THEN FOR I%=0% TO 89% : A%(I%)=A%(I%+10%) : NEXT I% : B1%=89%
520 ; CHR$(12%)CUR(10%,5%)"Av 10 f|rs|k klarade du"D1%" st."
530 ; CUR(14%,2%)"Vill du spela ett spel till (J) "; : INPUT A$
540 IF (ASC(A$) AND 223%)<>78% THEN 160
550 ; : ; "  Hoppas du har haft trevligt !!!" : END 
560 REM *** PLATTFORMEN ***
570 FOR I%=1% TO 10%
580 SETDOT 67%-I%,I%+40% : SETDOT 67%-I%,68%-I% : SETDOT 68%-I%,I%+40% : SETDOT 68%-I%,68%-I%
590 NEXT I%
600 FOR I%=1% TO 8% : SETDOT 57%,I%+50% : NEXT I%
610 ; CUR(3%,20%)"DET VAR PLATTFORMEN"
620 RETURN 
630 REM *** P]LEN ***
640 FOR I%=15% TO 57% : SETDOT I%,53% : NEXT I%
650 ; CUR(3%,20%)" P]LEN [R P] PLATS "
660 RETURN 
670 REM *** SKAFTET P] P]LEN ***
680 FOR I%=54% TO 69% : SETDOT 15%,I% : NEXT I%
690 ; CUR(3%,20%)"   [VEN TV[RSL]N   "
700 RETURN 
710 REM *** REPET ***
720 FOR I%=1% TO 8%+X% : SETDOT I%+14%,69% : NEXT I%
730 IF X%=0% THEN ; CUR(3%,20%)"REPET [R FASTKNUTET"
740 RETURN 
750 REM *** HUVUDET ***
760 FOR I%=1% TO 7% : SETDOT 23%+X%,I%+65% : SETDOT 28%+X%,I%+65% : NEXT I%
770 FOR I%=1% TO 4% : SETDOT 23%+I%+X%,66% : SETDOT 23%+I%+X%,72% : NEXT I%
780 SETDOT 25%+X%,68% : SETDOT 25%+X%,70% : SETDOT 27%+X%,69%
790 IF X%=0% THEN ; CUR(3%,20%)"NU RITAR VI HUVUDET"
800 RETURN 
810 REM *** HALS+HAND ***
820 FOR I%=1% TO 3% : SETDOT I%+28%+X%,69% : NEXT I%
830 FOR I%=1% TO 5% : SETDOT 31%+I%+X%,69%-I% : NEXT I%
840 IF X%=0% ; CUR(3%,20%)"   OCH ENA ARMEN   "
850 RETURN 
860 REM *** ANDRA HANDEN ***
870 FOR I%=1% TO 5% : SETDOT 31%+I%+X%,69%+I% : NEXT I%
880 IF X%=0% ; CUR(3%,20%)" ANDRA [R P] PLATS "
890 RETURN 
900 REM *** ENA BENET+MAGEN ***
910 FOR I%=1% TO 6% : SETDOT I%+31%+X%,69% : NEXT I%
920 FOR I%=1% TO 7% : SETDOT 37%+I%+X%,69%-I% : NEXT I%
930 IF X%=0% ; CUR(3%,20%)"AJ AJ  ETT BEN KVAR"
940 RETURN 
950 REM *** SISTA BENET !!!!!!! ***
960 FOR I%=1% TO 7% : SETDOT 37%+I%+X%,69%+I% : NEXT I%
970 ; CUR(3%,20%)"ARRGH   DU [R H[NGD"
980 RETURN 
990 REM *** F\RLORAT :  ( HOPP ) ***
1000 FOR J%=1% TO 3% : FOR J2%=1% TO 4%
1010 IF J%/2=J%/2% THEN X%=5%-J2% ELSE X%=J2%
1020 OUT 6%,83%
1030 FOR J1%=7%+X%/3% TO 15%+X%/3% : ; CUR(J1%,31%)"        "; : NEXT J1%
1040 GOSUB 720 : GOSUB 760 : GOSUB 820 : GOSUB 870 : GOSUB 910 : GOSUB 960
1050 FOR I=1% TO 400% : NEXT I
1060 NEXT J2% : NEXT J%
1070 OUT 6%,0% : GOTO 490
1080 REM 
1090 REM DATA SKALL PLACERAS MED 
1100 REM 100 ORD F\R VARJE 100 STEG
1110 REM 
1120 DATA FLEXIBEL,PLEXIGLAS,YTTERMERA,]SKV[DER,CLOWN,OD\R,PL]TBURK,CYKLOID,UPPH[VA,H[VST]NG
1130 DATA EXPEDIERA,ORD,MEDE,HUS,HES,T\S,VIT,BL],FOSTERL[NDSK,TYG
1140 DATA METEORIT,VERB,BIFF,\STER,HYVEL,H]RSTR],BYTE,BYGGE,BYGEL,FYND
1150 DATA AKTIEPORTF\LJ,KONSERV,KONSERVATIV,R[NTEFOT,RASTAFARIAN,R]G,TRYFFEL,XYLOFON,DREJSKIVA,G\K
1160 DATA HUMAN,HUK,HUMANIORA,LUSTHUS,\K[ND,LONDONBO,MORMON,CIRKUMFLEX,VIRVELVIND,F\RB]L
1170 DATA KL[RVOAJANS,CINNOBER,CITADELL,QUISLING,SKR[CK,SKROCKFULL,SM\R,LJUS,MJ\LK,MJ[LTE
1180 DATA VEGETABILISK,FETT,BERG,SUND,MEJERISM\R,LECITIN,INGREDIENS,ST[RKELSE,KONDENSATOR,VANILLIN
1190 DATA NOBELPRIS,SNOPEN,H[PEN,DYSTER,EN,BY,\,G]NG,KUNSKAP,METERSYSTEM
1200 DATA KLOROFORM,SULFA,TERM,B[DD,HYTT,ORM,GYMNASTISERA,ST\PSEL,FYSIOTERAPEUT,TYFON
1210 DATA SEKRET[R,FL[DER,M\BEL,\L,ECHAUFFERAD,FUTT,F[RM,EMPIRE,CYPRESS,\VERMAGA
1215 REM 100 ORD
1220 DATA [VENTYR,SK[RBR[DE,KONTRAREVOLUTION,FISKM]S,BR\DKNIV,R[VSVANS,PLUS,]KERSORK,PUMPHUS,H[FTE
1230 DATA SJ\MAN,BRUDGUM,V[RNL\S,KNACKKORV,DJ[KNE,TR[DG]RD,GRANKOTTE,CYMBAL,H[RVA
1240 DATA YRKE,FJ[SKA,FL[SKS]S,B\NGRODD,V[NLIG,R\DBETA,SAFTKR[M,PORTUGIS,KOLSTYBB,MARSCH
1250 DATA \VERSTE,MAJOR,L\JTNANT,BL]B[R,GRUS,GR\NSKA,KULMEN,FNITTRA,BEHAG,SKAVS]R
1260 DATA FLYH[NT,DUBBD[CK,BERGSR]D,N]LVENTIL,SK[RM,SKOGSTJ[RN,TROLLSL[NDA,KJOLF]LL,F\RKL[DE,PERMANENT
1270 DATA SYNDFULL,SJ[LVST[NDIG,M[RKV[RDIG,KOSMONAUT,B\RJAN,K]LSOPPA,P[RTTAK,HYVELB[NK,CYPRIOT,PLOGF]RA
1280 DATA SN\GUBBE,BYKPINNE,BUFFELHUD,NERTZP[LS,KNYPPLA,\NSKEM]L,GR\NG\LING,SK]DESPEL,BINGO,LAXSTJ[RT
1290 DATA BR]DST\RTAD,PUDDING,NYSPULVER,N[SDUK,JULAFTON,HJUL]NGARE,F]GELFR\,F\RSUMMA,FISKGJUSE,KALABALIK
1300 DATA INTERVENTION,SNYTBAGGE,ORMTJUSARE,TR[SLEV,FRYSBOX,GN[LLIG,H\[NG,FLUGSM[LLA,TJUVAKTIG,VINNL[GGA,GRYTA
1310 DATA H\NSHUS,TUPPFJ[T,F\RNIMMELSE,BRANDV[RN,UTRYCKNING,DRYCKESVISA,LIVV[ST,F[RJF\RARE,ROCKSK\RT,J[RNS[NG
1315 REM 200 ORD
1320 DATA HUND,M[NNISKA,SPARGRIS,VELOCIPED,H\GTALARE,PIZZA,BUDGET,TRIANGEL,EXEMPEL,SERGERANT
1330 DATA HERTZ,PSYKOLOG,SPRIT,SL\JA,R]TTF]NGARE,MYRSLOK,STACKMYRA,DATORFANTAST,BANKKONTO,GOLFBOLL
1340 DATA AUTENTISK,SPEAKER,EKORRE,J[RNV[G,SOLSTR]LE,SUFL\R,KORTHAJ,SPORTFISKARE,SCHACKSPELARE,BANKR]NARE
1350 DATA GROSSIST,SUFL@,TEORI,STANSARE,KVARN,STJ[RNA,BANDSPELARE,SKRIVMASKIN,VALP,SEXSYMBOL
1360 DATA ROCKS]NGARE,SYMFONI,D[CK,STR\M,NAKEN,KARP,G[DDA,FLUNDRA,FICKLAMPPA,R[KNEDOSA
1370 DATA SVAMP,M[STARE,R]NARE,BLOMMA,SL\FOCK,GRODYNGEL,KASSASKRIN,BRILJANT,KAFFE,GULDTACKA
1380 DATA FOTBOLL,SPORT,SLAGSM]L,DISKUS,VATTEN,VATUSKR[CK,KANIN,F\REM]L,SUBSTANTIV,ADJEKTIV
1390 DATA DYNAMIT,GLYSERIN,KVANTTEORI,GRODBLAD,KYLSK]P,FRYS,DISKMASKIN,SPRITE,KOKA,KOKAIN
1400 DATA KOKS,KLOR,SULFAT,CELLULOSA,PAPPER,KUVER,PENNA,GUMMI,ST\VEL,STRUMPPA
1410 DATA GLASS,F\NSTER,RUTA,DAGG,SALPETER,KRUT,DUNK,BENSIN,MOTOR,SOFFA
1415 REM 300 ORD
1420 DATA KAKTUS,KAMEL,DROMEDAR,FLASKA,\KEN,BEDUIN,SJ\R\VARE,BLOD,HEMOGLOBIN,BLODKROPP
1430 DATA BIOLOG,ZOOLOGI,BABIAN,SPR]KFORSKARE,HISTORIA,KEMI,SVENSK,ENGELSKA,GENTLEMAN,IDIOT
1440 DATA LADY,LAVIN,KAVAJ,BLASER,KOSTYM,FRACK,HATT,HUVUDBONAD,CYLINDER,TETRAEDER
1450 DATA B[LTE,VARULV,H[NGD,V]LNAD,SP\KE,BLODHUND,BL[CK,R]TTA,OSTBIT,KVICKSILVER
1460 DATA LAKE,LONDON,JUDO,VILDSVIN,PULLOVER,SPALT,TIDNING,HALLON,SMULTRON,HJORTRON
1470 DATA LITTERATUR,FIL@,TRILLING,BALLONG,B\NA,T\S,KLO,BOK,DUN,DUK
1480 DATA MOLUSK,VIND,STORM,CYKLON,VIRVEL,TORNADO,TRASDOCKA,TOMTE,\GA,N[SA
1490 DATA URAN,DUSCH,FRANSOS,CENTRUM,RAGG,STINS,KVALITET,GLASYR,GLACI[R,GLANSPERIOD
1500 DATA SLAGF[LLT,BLYKULA,LABB,LIGIST,KOMPROMISS,SENSOR,LAGUN,LAPPGUMMA,FRAKTAL,LEGION[R
1510 DATA FEMININ,KOLOSS,IMPULS,FLANK,SERI\S,SERIE,HOLK,MASKULIN,PIANIST,MAXIM
1515 REM 400 ORD
1520 DATA