10 RANDOMIZE 
20 REM ##############################
30 REM # -ARTILLERI-                #
40 REM #Av :  (c) Morten Christiansen #
50 REM #medlem nr.7456 fra NORGE.   #
60 REM #laget 24/6-88.              #
70 REM #innsendt av <7456>.         #
80 REM #H}per dere synes det er     #
90 REM #"kul" } spille det!!        #
100 REM ##############################
110 ; "TRENGER DU INSTR.?"; : GET T$
120 IF T$="J" OR T$="j" THEN GOTO 130 ELSE GOTO 200
130 ; CHR$(12)
140 ; "Du sitter bak en kanon og skal forsvare fedrelandet mot den slemme fienden."
150 ; "For } kunne gj|re det m} du skyte       fiendens skip med din kanon."
160 ; "Det gj|r du ved } mate inn vinkel       og hastighet nederst etterfulgt av      return."
170 ; "Du har bare 10 skudd p} hvert skip,     og hvor mange skudd du har igjen st}r   |verst i det venstre hj|rnet."
180 ; "Hastigheten kan ikke v{re mer enn 300   (m/sek.), og vinkelen kan selvf|lgelig  ikke v{re mer enn 90 grader."
190 ; : ; "Er du klar?"; : GET Y$
200 ; CHR$(12)
210 K=0
220 ; CUR(12,0);CHR$(151);"#######################################";
230 I=INT(RND*9000) : REM POSISJON SKIP
240 IF I<500 THEN 230
250 IF I<3000 THEN GOSUB 400 : REM STORT SKIP
260 IF I>3000 AND I<6000 THEN GOSUB 440 : REM MIDDELS STORT SKIP
270 IF I>6000 THEN GOSUB 470 : REM LITE   SKIP
280 REM SKJERMBILDE*****************
290 ; CUR(13,20)CHR$(151)"p"
300 ; CUR(14,19)CHR$(151)"j5"
310 ; CUR(15,20)CHR$(151)""
320 ; CUR(16,20)CHR$(151)""
330 ; CUR(17,20)CHR$(151)""
340 ; CUR(18,19)CHR$(151)"h4"
350 ; CUR(19,19)CHR$(151)"~}"
360 ; TAB(16)CHR$(151)"xt"
370 GOSUB 490 : REM SKYT
380 GOSUB 570 : REM SJEKK OM TREFF
390 GOTO 280
400 ; CUR(9,19)CHR$(151)"`|"
410 ; CUR(10,15)CHR$(151)"`ppppp0"
420 ; CUR(11,16)CHR$(151)"+%"
430 RETURN 
440 ; CUR(10,19)CHR$(151)"`t0"
450 ; CUR(11,17)CHR$(151)"l|~}|"
460 RETURN 
470 ; CUR(11,18)CHR$(151)"`xp"
480 RETURN 
490 ONERRORGOTO 490
500 ; CUR(22,0)"Vinkel: "; : INPUT A
510 IF A>90 THEN 500
520 ; CUR(22,20)"Hastighet: "; : INPUT V
530 IF V>300 THEN 520
540 OUT 6,0,6,137
550 S=(V^2)/9.81*SIN((PI/90)*A) : S=INT(S)
560 RETURN 
570 FOR E=1 TO 100
580 IF S+E=I OR S-E=I THEN GOTO 670
590 NEXT E
600 GOSUB 640
610 K=K+1 : ; CUR(0,0)"("K")";
620 IF K=10 THEN GOTO 730
630 RETURN 
640 IF S>I THEN ; CUR(0,10)"Du skj|t "S-I" m. for langt"
650 IF S<I THEN ; CUR(0,10)"Du skj|t "I-S" m. for kort     "
660 RETURN 
670 REM TREFF****************
680 FOR G=0 TO 2000 : OUT 6,11 : NEXT G : OUT 6,0
690 ; CHR$(12)
700 ; CUR(10,10)"DU TRAFF SKIPET!!!"
710 ; : ; "VIL DU PR\VE EN GANG TIL?"; : GET F$
720 IF F$="j" OR F$="J" THEN GOTO 200 ELSE ; CHR$(12);"(C) M.C.-88" : END 
730 ; CHR$(12)
740 ; : ; : ; "DU HAR IKKE MER AMMUNISJON IGJEN."
750 ; : ; "VIL DU PR\VE EN GANG TIL?"; : GET D$
760 IF D$="J" OR D$="j" THEN 200 ELSE ; CHR$(12);"(C) M.C.-88"
770 END