1 REM ++++++++++++++++++++++++++++++++
2 REM ! Program ....  TANGENT.BAS
3 REM ! Utg}va         1987.12.06
4 REM ! av  Joakim B{ckstr|m <4421>
5 REM ! Minne 16 Kbytes
6 REM ! Ins{nt av <4421>
7 REM ! Screenat av T.E.S.
8 REM !++++++++++++++++++++++++++++++++
10 REM Ett reaktion-spel.   Samla po{ng
11 REM genom att hitta p} tangentbordet
12 REM s} snabbt som m|jligt.
13 REM 
300 PRINT CHR$(12)"          Tangentbordstortyr"
310 PRINT CHR$(23)"         ##################"
320 PRINT 
330 PRINT " Detta {r ett reaktinsspel, samtidigt   som det {r ett uppfattningspel och ett  'skrivspel'."
340 PRINT " Det g}r ut p} att samla po{ng genom    att hitta p} tangentbordet s} snabbt    som m|jligt."
350 ; "Det {r 20 'heat' som man ska avklara p} tid. Varje heat g}r till s} att en massa nonsens kladdas ut p}";
360 PRINT " sk{rmen. Bland   detta kludder g|mmer sig en versal."
370 PRINT "N{r du hittat bokstaven isolerar du     motsvarande tangent och trycker p} den."
380 PRINT "Du har inte hela dagen p} dig, bara     runt 11 sekunder per 'heat', om du miss"
390 PRINT "lyckas med att klara det p} den tiden   utdelas hela noll(0) po{ng."
400 PRINT " F|rs|k att inte se ner p} tangentbord- et under spelets g}ng."
410 PRINT " Lycka till!                     JB-87"
420 IF INP(56)<128 THEN 420
430 PRINT CHR$(12)
440 RANDOMIZE 
450 A$(1)="o" : A$(2)="." : A$(3)="+"
460 FOR G=1 TO 20
470 FOR A=1 TO 50
480 X=INT(RND*20)
490 Y=INT(RND*30)+5
500 PRINT CUR(X,Y)A$(INT(RND*3)+1)
510 NEXT A
520 S$=CHR$(INT(RND*30)+64)
530 PRINT CUR(X,Y)S$
540 PRINT CUR(22,5)"PO[NG "P
550 FOR Z=1500 TO 0 STEP -1
560 PRINT CUR(22,20)"  "Z"  "
570 IF INP(56%)=ASC(S$)+128% THEN 620
580 NEXT Z
590 PRINT CHR$(7,12,7) : GOTO 630
600 GOTO 640
610 REM 
620 P=P+Z : PRINT CHR$(7,12,7)
630 NEXT G
640 PRINT CHR$(12)
650 PRINT "Du lyckades med bravaden med att samla  in"P" po{ng."
660 PRINT 
670 B$=" Det var otroligt d}ligt!"
680 IF P>6000 THEN B$=" D}ligt..."
690 IF P>17000 THEN B$=" N}ja..."
700 IF P>21000 THEN B$=" Om}ttligt v{l presterat f|r en idiot."
710 IF P>26000 THEN B$=" Utomordentligt."
720 IF P>29000 THEN B$=" Otroligt!"
730 IF P>29500 THEN B$=" Nu f}r vi anse dig full{rd."
740 IF P>30000 THEN B$=" ...s{kert att du inte har fifflat?"
750 PRINT B$
760 PRINT 
770 IF P>R THEN 920
780 PRINT : PRINT 
790 PRINT "Rekordet innehas av "R$" med"R
800 PRINT "po{ng."
810 PRINT : PRINT : PRINT 
820 FOR F=1 TO 1000 : NEXT F
830 PRINT "  Vill du utmana tangentbordet {n en      g}ng, utan bed|vning?";
840 GET S$
850 IF S$="J" OR S$="j" THEN 870
860 END 
870 PRINT : PRINT : PRINT 
880 PRINT "Skyll dig sj{lv!!!"
890 FOR F=1 TO 3000 : NEXT F
900 P=0
910 GOTO 430
920 PRINT : PRINT 
930 PRINT "Du tog rekord. F}r jag be om f|rnamnet?"
940 INPUT R$
950 R=P
960 GOTO 790