10 REM SAVE CASDISK,3.0,811106,MJ
20 DIM C$=0%,B$=0%,Q0$=253%
30 DIM D$=4%,E$=12%,E3$=7%
40 E3$=STRING$(6%,0%)+CHR$(3%)
50 R%=PEEK(65065%)+SWAP%(PEEK(65066%))
60 POKE R%+4%,18%,0%,0%,0%,18%,0%
70 P%=R%+6%
80 R%=PEEK(R%+2%)+SWAP%(PEEK(R%+3%))
90 POKE R%+4%,253%,0%,0%,0%,253%,0%
100 R%=R%+6%
110 A%=PEEK(65056%)+SWAP%(PEEK(65057%))
120 I%=A% : ONERRORGOTO 170
130 READ D% : POKE I%,D%
140 I%=I%+1% : GOTO 130
150 DATA 123,205,1,9,205,153,8,221
160 DATA 110,8,221,102,9,201,
170 POKE 65056%,I%,SWAP%(I%)
180 ; CHR$(12%)TAB(3%);
190 ; '< ABC80-CASDISK TILL DRIVE ';
200 GET D$ : IF D$<>'1' AND D$<>'0' 200
210 ; D$' >' : D$='DR'+D$+':'
220 ; 'STOPP VID FEL ?'; : GET X$
230 IF X$='J' OR X$='j' F%=1%
240 ; CHR$(13%)TAB(3%)STRING$(30%,61%);
250 IF F% ; CUR(1%,14%)'FELSTOPP';
260 REM  HUVUD-LOOP 
270 PREPARE D$+'TEMP.][\' ASFILE 2%
280 F$='   ' : N%=0%
290 ONERRORGOTO 290 : IF N%=3% GOTO 870
300 IF (INP(56%) AND 95%)=67% GOTO 870
310 N%=N%+1%
320 OPEN 'CAS:' ASFILE 1%
330 ONERRORGOTO 760 : B%=65535%
340 X%=PEEK(65011%)*2%+884%
350 X%=PEEK(X%)+SWAP%(PEEK(X%+1%))
360 POKE P%,X%,SWAP%(X%)
370 E$=RIGHT$(C$,7%)
380 REM  BLOCK-LOOP 
390 Z%=CALL(A%,1%) : B%=B%+1%
400 IF B%=0% T%=PEEK(Z%) ELSE 440
410 IF (T% OR 1%)=131% T%=1% : GOTO 440
420 IF T%=0% T%=3% : GOTO 440
430 IF T%<128% THEN T%=2% ELSE 730
440 POKE R%,Z%,SWAP%(Z%)
450 Z%=CALL(28666%,2%)
460 Q0$=B$ : Z%=CALL(28670%,B%)
470 P$='SEKTORER KOPIERADE '
480 GOSUB 820
490 ON T% GOSUB 580,630,660
500 IF L%=0% 390
510 REM  SLUT P] FIL 
520 CLOSE 1% : CLOSE 2%
530 ONERRORGOTO 550 : KILL D$+E$
540 ONERRORGOTO 0
550 NAME D$+'TEMP.][\' AS D$+E$
560 GOTO 270
570 REM  BAC-FIL 
580 IF B%=0% I%=2% ELSE I%=1%
590 L%=ASC(MID$(B$,I%,1%))
600 IF L%<2% RETURN 
610 I%=I%+L% : GOTO 590
620 REM  TEXTFIL 
630 IF LEFT$(B$,7%)=E3$ L%=1% : RETURN 
640 L%=0% : RETURN 
650 REM  ABS-FIL 
660 I%=1%
670 L%=ASC(MID$(B$,I%,1%))
680 IF L%=255% L%=0% : RETURN 
690 L%=ASC(MID$(B$,I%+1%,1%))
700 IF L%=0% L%=1% : RETURN 
710 I%=I%+L%+8% : GOTO 670
720 REM  FEL FORMAT 
730 P$='FEL FORMAT' : GOSUB 820
740 GOTO 280
750 REM  ERROR 
760 P$='ERR'+NUM$(ERRCODE) : GOSUB 820
770 CLOSE 1% : CLOSE 2%
780 KILL D$+'TEMP.][\'
790 IF F% GET X$
800 GOTO 270
810 REM  SKRIV FILNAMN 
820 F$=' '+NUM$(B%+2%)
830 F$=RIGHT$(F$,LEN(F$)-2%)
840 ; CHR$(13%)E$' 'F$' 'P$TAB(39%);
850 RETURN 
860 REM  AVSLUTNING 
870 CLOSE 1% : CLOSE 2%
880 KILL D$+'TEMP.][\'
890 POKE 65013%,0% : END