;
;
;
;       HJ[LPPROGRAM med f|ljande:
;       LASSE OLOFSSON 820722
;
;
;       Ctrl/@               TRACE-ON
;       Ctrl/^               VISAR RESTERANDE MINNESUTRYMME
;       Ctrl/]               VISAR GRAFISKA TECKEN
;
;
;
        ORG     63796
KEYB    DEFW    HJALP        ;REM VEKTOR KEYBORD
RECORD  DEFW    1428         ;VEKTOR BANDSPELAREN
;
;
START   PUSH    AF
        LD      A,249
        LD      I,A
        POP     AF
        RET
;
;
;
;
;       START AV HJ[LPPROGRAM
;
;
HJALP   PUSH    HL
        PUSH    DE
        PUSH    AF
        PUSH    IY
        PUSH    BC
        PUSH    IX
        IN      A,(56)
        AND     07FH         ;PARITETSMASK
        CP      00           ;CTRL/@ ?
        JR      Z,TRACON     ;JA, HOPPA TILL RUTIN TRACE-ON
;
        PUSH    AF           ;NEJ, S[TT TRACE-OFF
        LD      A,0
        LD      (65061),A
        POP     AF
;
        CP      030          ;CTRL/^ ?
        JR      Z,MEMORY     ;JA, HOPPA TILL RUTIN
;
        CP      29           ;CTRL/] ?
        JR      Z,GRAFIK
;
;
EXIT    POP     IX
        POP     BC
        POP     IY
        POP     AF
        POP     DE
        POP     HL
        JP      31EH         ;HOPPA TILL NORMAL I/O-RUTIN
;
;
TRACON  LD      A,16
        LD      (65061),A    ;S[TT TRACE-ON
        JR      EXIT
;
;
MEMORY  PUSH    IX
        CALL    577          ;SCROLLA
        LD      HL,(65063)
        LD      BC,(65056)
        SBC     HL,BC
        LD      DE,32720     ;RAD 23
        CALL    6242
        LD      A,6
        LD      (65012),A    ;POS-R[KNARE=6
        LD      BC,13
        LD      HL,TEXT
        CALL    425          ;SKRIV TEXT
        POP     IX
        JR      EXIT
;
TEXT    DEFM    ' BYTES LEFT !'
;
;
GRAFIK  LD      A,32
        LD      C,-6
        LD      IY,884
VISA    LD      L,(IY+0)
        LD      H,(IY+1)     ;H[MTA BILDADRESS
        LD      (GRAF),A
        LD      (HL),151     ;GRAFIK ON
        INC     HL
        CALL    SHOW
        INC     IY
        INC     IY
        LD      L,(IY+0)
        LD      H,(IY+1)
        LD      (GRAF),A
        LD      (HL),32      ;EJ GRAFISKA
        INC     HL
        CALL    SHOW
        INC     IY
        INC     IY
        LD      L,(IY+0)
        LD      H,(IY+1)
        LD      B,-20
OEKA    INC     A
        LD      (HL),32
        INC     HL
        LD      (HL),32
        INC     HL
        INC     B
        JR      NZ,OEKA
        INC     IY
        INC     IY
        INC     C
        JR      NZ,VISA
        JP      EXIT
;
;
SHOW    PUSH    AF
        PUSH    BC
        LD      B,-19
        LD      A,(GRAF)
NR1     LD      (HL),A
        INC     HL
        INC     A
        LD      (HL),32      ;SPACE
        INC     HL
        INC     B
        JR      NZ,NR1
        LD      (HL),32      ;SPACE
        POP     BC
        POP     AF
        RET
;
GRAF    DEFB    0
;
;
;
;
        END