1 REM +++++++++++++++++++++++++++++++++
2 REM ! Program ....   COPYLIB
3 REM ! Utg}va  2.1    1982-11-21
4 REM ! av Magnus Jacobsson
5 REM ! {ndrat av Kalle Lindstr|m
6 REM ! Copyright ABC-klubben
7 REM ! Minne 16 Kbytes f|r flexskiva
8 REM ! Ins{nt av 837
9 REM +++++++++++++++++++++++++++++++++
10 REM 
11 REM The Computer Phantome
12 REM 
13 REM Ins{nt av 615
14 REM SAVE CASDISK,3.0,811106,MJ
15 DIM C$=0%,B$=0%,Q0$=253%,S2$=253%
16 DIM D$=4%,E$=12%,E3$=7%,S1$=7%
17 E3$=STRING$(6%,0%)+CHR$(3%)
18 S1$=CHR$(253%,192%,253%,192%)
19 S1$=S1$+CHR$(253%,192%,52%)
20 R%=PEEK(65065%)+SWAP%(PEEK(65066%))
21 POKE R%+4%,18%,0%,0%,0%,18%,0%
22 P%=R%+6%
23 R%=PEEK(R%+2%)+SWAP%(PEEK(R%+3%))
24 POKE R%+4%,253%,0%,0%,0%,253%,0%
25 R%=R%+6%
26 A%=PEEK(65056%)+SWAP%(PEEK(65057%))
27 I%=A% : ONERRORGOTO 32
28 READ D% : POKE I%,D%
29 I%=I%+1% : GOTO 28
30 DATA 123,205,1,9,205,153,8,221
31 DATA 110,8,221,102,9,201,
32 POKE 65056%,I%,SWAP%(I%)
33 ; CHR$(12%)TAB(3%);
34 ; '< ABC80-CASDISK TILL DRIVE ';
35 GET D$ : IF D$<>'1' AND D$<>'0' 35
36 ; D$' >' : D$='DR'+D$+':'
37 ; 'STOPP VID FEL ?'; : GET X$
38 IF X$='J' OR X$='j' F%=1%
39 ; CHR$(13%)TAB(3%)STRING$(30%,61%);
40 IF F% ; CUR(1%,14%)'FELSTOPP';
41 REM  HUVUD-LOOP 
42 PREPARE D$+'TEMP.][\' ASFILE 2%
43 F$='   ' : N%=0%
44 ONERRORGOTO 44 : IF N%=3% GOTO 103
45 IF (INP(56%) AND 95%)=67% GOTO 103
46 N%=N%+1%
47 OPEN 'CAS:' ASFILE 1%
48 ONERRORGOTO 92 : B%=65535%
49 X%=PEEK(65011%)*2%+884%
50 X%=PEEK(X%)+SWAP%(PEEK(X%+1%))
51 POKE P%,X%,SWAP%(X%)
52 E$=RIGHT$(C$,7%)
53 REM  BLOCK-LOOP 
54 Z%=CALL(A%,1%) : B%=B%+1%
55 IF B%=0% T%=PEEK(Z%) ELSE 59
56 IF (T% OR 1%)=131% T%=1% : GOTO 59
57 IF T%=0% T%=3% : GOTO 59
58 IF T%<128% THEN T%=2% ELSE 89
59 POKE R%,Z%,SWAP%(Z%) : S2$=B$
60 IF LEFT$(B$,7%)=S1$ 67
61 Z%=CALL(28666%,2%)
62 Q0$=B$ : Z%=CALL(28670%,B%)
63 P$='SEKTORER KOPIERADE '
64 GOSUB 98
65 ON T% GOSUB 74,79,82
66 IF L%=0% 54
67 REM  SLUT P] FIL 
68 B$=S2$ : CLOSE 1% : CLOSE 2%
69 ONERRORGOTO 71 : KILL D$+E$
70 ONERRORGOTO 0
71 NAME D$+'TEMP.][\' AS D$+E$
72 GOTO 42
73 REM  BAC-FIL 
74 IF B%=0% I%=2% ELSE I%=1%
75 L%=ASC(MID$(B$,I%,1%))
76 IF L%<2% RETURN 
77 I%=I%+L% : GOTO 75
78 REM  TEXTFIL 
79 IF LEFT$(B$,7%)=E3$ L%=1% : RETURN 
80 L%=0% : RETURN 
81 REM  ABS-FIL 
82 I%=1%
83 L%=ASC(MID$(B$,I%,1%))
84 IF L%=255% L%=0% : RETURN 
85 L%=ASC(MID$(B$,I%+1%,1%))
86 IF L%=0% L%=1% : RETURN 
87 I%=I%+L%+8% : GOTO 83
88 REM  FEL FORMAT 
89 P$='FEL FORMAT' : GOSUB 98
90 GOTO 43
91 REM  ERROR 
92 P$='ERR'+NUM$(ERRCODE) : GOSUB 98
93 CLOSE 1% : CLOSE 2%
94 KILL D$+'TEMP.][\'
95 IF F% GET X$
96 GOTO 42
97 REM  SKRIV FILNAMN 
98 F$=' '+NUM$(B%+2%)
99 F$=RIGHT$(F$,LEN(F$)-2%)
100 ; CHR$(13%)E$' 'F$' 'P$TAB(39%);
101 RETURN 
102 REM  AVSLUTNING 
103 CLOSE 1% : CLOSE 2%
104 KILL D$+'TEMP.][\'
105 POKE 65013%,0% : END