1 REM ++++++++++++++++++++++++++++++++
2 REM ! Program ....   KALENDR.BAS
3 REM ! Utg}va  1.1    1983
4 REM ! av (c) Lars-Erik N{sman
5 REM ! screenat av Tom Sj|berg 2401
7 REM ! Minne 16 Kbytes,Skrivare
8 REM ! Ins{nt av 1007
9 REM ++++++++++++++++++++++++++++++++
100 ; CHR$(12)
110 ; 'Programmet anv{nds f|r att p} skrivare' : ; 'f} utskrift av en kalender f|r ett' : ; 'angivet }rtal.'
120 ; CUR(10,0)"F\R VILKET ]R"
130 ; : ; "VILL DU HA KALENDERN >";
140 INPUT Y9
150 OPEN "PR:" ASFILE 1
160 X=Y9
165 M=15
170 C=6
180 FOR J=1600 TO X STEP 1
190 IF J=X THEN 250
200 IF J/4<>INT(J/4) THEN 240
210 IF (J-1700)*(J-1800)*(J-1900)*(J-2100)*(J-2200)*(J-2300)=0 THEN 240
220 C=C+2
230 GOTO 250
240 C=C+1
250 IF C<7 THEN 270
260 C=C-7
270 NEXT J
280 ; #1,CHR$(13)
290 FOR R=1 TO 12
300 READ A$
310 ; #1,TAB(M+12)A$;" ";X
320 READ B
330 IF X/4<>INT(X/4) THEN 360
340 IF A$<>"FEBRUARI" THEN 360
350 B=B+1
360 REM 
370 ; #1,TAB(M)"======================================="
380 ; #1,TAB(M)"S\N   M]N   TIS   ONS   TOR   FRE   L\R"
390 ; #1,TAB(M)"======================================="
400 FOR D=1 TO B
410 ; #1,TAB(M+6*C)D;
420 C=C+1
430 IF C<7 THEN 460
440 ; #1,CHR$(13)
450 C=0
460 NEXT D
470 ; #1,CHR$(13)
480 ; #1,TAB(M)"========================================"
490 FOR P=1 TO 3
500 ; #1,CHR$(13)
510 NEXT P
520 NEXT R
530 DATA "JANUARI",31,"FEBRUARI",28,"MARS",31,"APRIL",30,"MAJ",31
540 DATA "JUNI",30,"JULI",31,"AUGUSTI",31,"SEPTEMBER",30,"OKTOBER",31
550 DATA "NOVEMBER",30,"DECEMBER",31
560 END