2 REM INS[NT AV 4492
10 REM  PROGRAMNAMN : RYMDGEOM 
20 REM TOFTASKOLAN LYCKGATAN 4 [NGELHOLM
30 REM 841031 PI 0431-28124
40 REM F]R KOPIERAS MED ANGIVANDE AV K[LLA
50 GOSUB 7000 : REM VINJETT
60 GOSUB 8000 : REM MENY
70 GOSUB 9000 : REM UTSKRIFT AREA/VOLYM
80 GOTO 60 : REM ]TER MENYN
90 REM  SLUT HUVUDPROGRAM 
100 REM ************************************
1000 REM ************************* R[TBLOCK ****
1010 ; CHR$(12),'R[TBLOCK' : A$='R[TBLOCKETS'
1020 ; CUR(3,0)'DATORN ARBETAR MED FORMLERNA'
1030 ; CUR(5,0)'A=2*l*b+2*l*h+2*b*h   6 sidoytor'
1040 ; CUR(7,0)'V=l*b*h'
1050 ; CUR(11,0)'ANGE L[NGDEN l='; : INPUT L
1060 ; CUR(13,0)'ANGE BREDDEN b='; : INPUT B
1070 ; CUR(15,0)'ANGE H\JDEN  h='; : INPUT H
1080 A=2*(L*B+L*H+B*H) : REM TOTALA AREAN
1090 V=L*B*H : REM VOLYMEN
1100 RETURN 
1110 REM ***************************************
2000 REM ************************* KUBEN *******
2010 ; CHR$(12),'KUB' : A$='KUBENS'
2020 ; CUR(3,0)'DATORN ARBETAR MED FORMLERNA'
2030 ; CUR(5,0)'A=6*s*s','6 sidoytor'
2040 ; CUR(7,0)'V=s*s*s'
2050 ; CUR(11,0)'ANGE SIDAN s='; : INPUT S
2060 A=6*S*S : REM TOTALA AREAN
2070 V=S*S*S
2080 RETURN 
2090 REM ***************************************
3000 REM ************************* PRISMAT *****
3010 ; CHR$(12),'PRISMA(BASYTA=TRIANGEL)'
3015 A$='PRISMATS'
3020 ; CUR(3,0)'DATORN ARBETAR MED FORMLERNA'
3030 ; CUR(5,0)'A=2*(b*h/2)+H*a+H*b+H*c'
3035 ; CUR(6,0)'2 trianglar + 3 rektanglar'
3040 ; CUR(8,0)'V=B*H=(b*h/2)*H'
3050 ; CUR(11,0)'[R BASYTAN K[ND (J/N)'; : INPUT S$
3060 IF S$='J' THEN ; CUR(13,0)'ANGE PRISMATS BASYTA B='; : INPUT B1
3070 IF S$='J' THEN ; CUR(14,0)'ANGE PRISMATS H\JD   H='; : INPUT H
3080 IF S$='J' THEN ; CUR(15,0)'ANGE BASYTANS SIDOR SOM a,b,c'; : INPUT A,B,C
3090 IF S$='J' THEN A=2*B1+H*(A+B+C)
3100 IF S$='J' THEN V=B1*H : RETURN 
3110 REM BASYTAN OK[ND
3120 ; CUR(11,0)'                        ' : REM TAR BORT TEXTRAD OM BASYTAN'
3125 ; CUR(10,0)'ANGE BASEN(b) SOM H\JDEN DRAGITS MOT'; : INPUT B
3130 ; CUR(12,0)'ANGE H\JDEN(h) MOT BASEN(b)'; : INPUT H1
3140 ; CUR(14,0)'ANGE BASYTANS \VRIGA SIDOR SOM  a,c'; : INPUT A,C
3150 ; CUR(16,0)'ANGE PRISMATS H\JD H='; : INPUT H
3160 A=B*H1+H*(A+B+C) : REM TOTALA AREAN
3170 V=B*H1/2*H : REM VOLYMEN
3180 RETURN 
3190 REM ***************************************
4000 REM ************************CYLINDER ******
4010 ; CHR$(12),'CYLINDER' : A$='CYLINDERNS'
4020 ; CUR(3,0)'DATORN ARBETAR MED FORMLERNA'
4030 ; CUR(5,0)'BASYTAN','B=PI*r*r'
4040 ; CUR(6,0)'MANTELYTAN','M=PI*2*r*H'
4050 ; CUR(7,0)'TOTALAREA','A=M+2*B'
4060 ; CUR(8,0)'VOLYMEN','V=B*H=PI*r*r*H'
4070 ; CUR(11,0),'ANGE RADIEN r='; : INPUT R
4080 ; CUR(13,0),'ANGE H\JDEN H='; : INPUT H
4090 B=PI*R*R : REM BASYTANS AREA
4100 M=PI*2*R*H : REM MANTELYTANS AREA
4110 A=M+2*B : REM TOTAL AREA
4120 V=B*H : REM VOLYMEN
4130 ; CUR(15,0)'BASYTANS AREA   ';B
4140 ; CUR(16,0)'MANTELYTANS AREA';M
4150 RETURN 
4160 REM ***************************************
5000 REM ************************ AVSLUTNING ***
5010 ; CHR$(12)
5020 ; CUR(11,12),'TACK F\R IDAG !'
5030 END 
5040 REM ***************************************
7000 REM TEXT INOM RAMEN
7005 ; CHR$(12)
7010 ; CUR(11,14);CHR$(135)'RYMDGEOMETRI'CHR$(151)
7030 FOR F=1 TO 3000 : NEXT F
7040 ; CUR(14,12);CHR$(135)'ETT PROGRAM FR]N'CHR$(151)
7050 ; CUR(15,12);CHR$(135)'TOFTA MATHEMATICAL 'CHR$(151)
7060 ; CUR(16,12);CHR$(135);'CENTER'CHR$(151)
7070 FOR F=1 TO 8000 : NEXT F
7080 ; CHR$(135)
7090 RETURN 
8000 REM *************************** MENY ***
8010 ; CHR$(12),'RYMDGEOMETRI'
8020 ; CUR(3,7)'Med hj{lp av detta program'
8030 ; CUR(4,7)'kan Du enkelt ber{kna area'
8040 ; CUR(5,7)'och volym f|r nedan angivna'
8050 ; CUR(6,7)'rymdgeometriska kroppar.'
8060 ; CUR(9,0),'MENY'
8070 ; CUR(12,7)'R[TBLOCK........... 1'
8080 ; CUR(14,7)'KUB................ 2'
8090 ; CUR(16,7)'PRISMA............. 3'
8100 ; CUR(18,7)'CYLINDER........... 4'
8110 ; CUR(20,7)'AVSLUTA............ 5'
8115 ONERRORGOTO 8115
8120 ; CUR(23,0)'V[LJ SIFFRA 1-5 F\R \NSKAD AKTIVITET';
8130 INPUT I
8135 ON I GOSUB 1000,2000,3000,4000,5000
8140 RETURN 
8150 REM ************************************
9000 REM ************************ UTSKRIFT *****
9010 ; CUR(18,0)A$' TOTALA AREA [R 'A
9020 ; CUR(20,0)A$' VOLYM [R       'V
9030 ; CUR(23,0)'TRYCK M=MENY,A=AVSLUTA';
9040 GET S$
9090 IF S$='A' THEN END 
9100 IF S$='M' THEN RETURN ELSE 9030
9110 REM ***************************************