1 REM Av: David Andersson <5201>    1985-10-13 21.56.00
10 REM .  SAVE [NDRABIG
20 REM 1985-10-12
30 REM DAVID ANDERSSON <5201>
40 REM 
50 REM [NDRA TECKENUTSEENDE
60 REM I PROGRAMMET "F\RSTORA".
70 REM [NDRINGARNA SKER ENDAST I
80 REM PRIM[RMINNET.
90 REM 
100 REM 
110 DEFFNS%(X%,Y%)=PEEK(884%+X%*2%)+SWAP%(PEEK(885%+X%*2%))+Y%
120 A%=61762% : REM ADRESS TILL GRAFIK TECKEN
130 FOR A1%=A% TO A%+8%
140 IF PEEK(A1%)<>32% GOTO 680
150 NEXT A1%
160 REM 
170 ; CHR$(12)
180 ; CUR(20,0)'Vilket tecken:';
190 GET A$ : ; A$
200 A1%=ASC(A$)-32% : IF A1%<1% END 
210 A1%=A%+A1%*9%
220 ; CUR(0,0)CHR$(23%,PEEK(A1%),PEEK(A1%+1%),PEEK(A1%+2%));
230 ; CUR(1,0)CHR$(23%,PEEK(A1%+3%),PEEK(A1%+4%),PEEK(A1%+5%));
240 ; CUR(2,0)CHR$(23%,PEEK(A1%+6%),PEEK(A1%+7%),PEEK(A1%+8%));
250 GOSUB 360 : IF A$<>CHR$(13%) GOTO 160
260 POKE A1%,PEEK(FNS%(0,1))
270 POKE A1%+1%,PEEK(FNS%(0,2))
280 POKE A1%+2%,PEEK(FNS%(0,3))
290 POKE A1%+3%,PEEK(FNS%(1,1))
300 POKE A1%+4%,PEEK(FNS%(1,2))
310 POKE A1%+5%,PEEK(FNS%(1,3))
320 POKE A1%+6%,PEEK(FNS%(2,1))
330 POKE A1%+7%,PEEK(FNS%(2,2))
340 POKE A1%+8%,PEEK(FNS%(2,3))
350 GOTO 160
360 REM GRAFIK EDITOR
370 ; CUR(6,0);
380 ; 'QWE'
390 ; 'A D flyttar mark|ren'
400 ; 'ZXC'
410 ; 
420 ; 'S s{tter dot'
430 ; 'MELLANSLAG tar bort dot'
440 ; 'RETURN avsluta {ndring'
450 ; 'CTRL-X }ngra'
460 X%=0% : Y%=2%
470 GOSUB 610
480 IF ASC(A$)>95% A$=CHR$(ASC(A$)-32%)
490 IF A$='Q' OR A$='W' OR A$='E' X%=X%-1%
500 IF A$='Z' OR A$='X' OR A$='C' X%=X%+1%
510 IF A$='Q' OR A$='A' OR A$='Z' Y%=Y%-1%
520 IF A$='E' OR A$='D' OR A$='C' Y%=Y%+1%
530 IF A$=' ' CLRDOT X%,Y%
540 IF A$='S' SETDOT X%,Y%
550 IF A$=CHR$(13%) OR A$=CHR$(24%) RETURN 
560 IF X%<0% X%=0%
570 IF X%>8% X%=8%
580 IF Y%<2% Y%=2%
590 IF Y%>7% Y%=7%
600 GOTO 470
610 REM 
620 D%=DOT(X%,Y%)
630 IF (PEEK(65008%) AND 12%)<>0% XOR D% CLRDOT X%,Y% ELSE SETDOT X%,Y%
640 IF PEEK(65013%)=0% GOTO 630
650 GET A$
660 IF D% SETDOT X%,Y% ELSE CLRDOT X%,Y%
670 RETURN 
680 REM ERROR
690 ; 
700 ; 'Fel version eller inget F\RSTORA'
710 ; 'program {r inladdat.'
720 STOP