10 REM +++++++++++++++++++++++++++++++++
11 REM ! Program ....   BES\K
12 REM ! Utg}va  1.0    81.12.17
13 REM ! av (c) Mats \hrman
14 REM ! Minne 16 Kbytes
15 REM +++++++++++++++++++++++++++++++++
16 REM ! Ett makabert sk{mt
17 REM ! Programmet f}r kopieras f|r
18 REM ! privata bruk av ABC-klubbens
19 REM ! medlemmar
20 REM *******************************
21 REM *                             *
22 REM * Mats \hrman  Tel.0498/20811 *
23 REM * Box 58                      *
24 REM * 620 30  Slite               *
25 REM *                             *
26 REM *******************************
27 REM >>> F\RMEDLAT 11/81 - "TOJ" <<<
28 REM *** VARIABLER *****************
29 REM *                             *
30 REM * A%   Startpunkt p} linjen   *
31 REM * B%   Slutpunkt p} linjen    *
32 REM * C%   Linjeplacering         *
33 REM * D%   Ritloop                *
34 REM * D$   Dagens datum           *
35 REM * E%   Detsamma som C%        *
36 REM * E$   Efternamn              *
37 REM * F$   F|rnamn                *
38 REM * L,L% Allm{nna loopvariabler *
39 REM * P$   Stopp                  *
40 REM * T    Tidsloop               *
41 REM *                             *
42 REM *******************************
43 REM 
44 REM *** DATASATSER ****************
45 REM 
46 DATA 25,47,34,25,47,35,25,32,36,39,42,36,25,30,37,39,39,37,25,27,38,29,30,38
47 DATA 45,47,38,25,25,39,42,47,39,25,25,40,40,47,40,25,25,41,42,47,41,25,27,42
48 DATA 29,30,42,45,47,42,25,30,43,39,39,43,25,32,44,39,42,44,25,47,45,25,47,46
49 REM 
50 REM *** DATAINSAMLING *************
51 REM 
52 ; CHR$(12)
53 ; TAB(16)"BES\K"
54 ; CUR(5,0)"VAD HETER DU I F\RNAMN (VERSALER) ?"
55 INPUT F$
56 ; "VAD HETER DU I EFTERNAMN (VERSALER) ?"
57 INPUT E$
58 ; "VILKET DATUM [R DU F\DD ( ]]]],MM,DD ) ?"
59 INPUT G$
60 ; "VAD [R DAGENS DATUM ( ]]]],MM,DD ) ?"
61 INPUT D$
62 REM 
63 REM *** BILD 1 ********************
64 REM 
65 REM PREPARERA SK[RMEN -------------
66 ; CHR$(12)
67 FOR L%=0 TO 23
68 ; CUR(L%,0)CHR$(151)
69 NEXT L%
70 REM KNACK,KNACK -------------------
71 OUT 6,17
72 FOR T=1 TO 2000 : NEXT T
73 OUT 6,0
74 REM RITA --------------------------
75 FOR L%=0 TO 23
76 READ A%,B%,C%
77 IF C%=E% THEN 79
78 FOR T=1 TO 100 : NEXT T
79 FOR D%=A% TO B%
80 SETDOT D%,C%
81 NEXT D%
82 E%=C%
83 NEXT L%
84 FOR T=1 TO 1000 : NEXT T
85 REM PANG --------------------------
86 OUT 6,137
87 REM 
88 REM *** BILD 2 ********************
89 REM 
90 ; CHR$(12)
91 ; 
92 FOR T=1 TO 1000 : NEXT T
93 ; CHR$(151);"`,###############,0"
94 FOR L=2 TO 22
95 ; CHR$(151);"j                 5"
96 NEXT L
97 ; STRING$(39%,127%)
98 ; CUR(9,11-LEN(F$)/2)F$
99 ; CUR(10,11-LEN(E$)/2)E$
100 ; CUR(14,9-LEN(G$)/2)CHR$(131);"* ";G$;CHR$(151)
101 ; CUR(16,9-LEN(D$)/2)CHR$(131);"+ ";D$;CHR$(151)
102 ; CUR(5,5)"VILA I FRID"
103 GET P$
104 ; CHR$(12)
105 REM *** SLUT **********************