10 REM +++++++++++++++++++++++++++++++++
11 REM ! Program ....   DXGUIDE
12 REM ! Utg}va  1.1    1982-02-11
13 REM ! av (c) Christer Andreasson
14 REM ! Minne 16 Kbytes
15 REM +++++++++++++++++++++++++++++++++
16 REM 
17 REM L{mnat av amat|rradiosekt. M.G.
18 REM G}va fr}n Luxor AB/Div. datorer
19 REM 
20 REM 
21 ; CHR$(12%)CUR(10%,8%);
22 ; "***** DX - GUIDE *****"
23 FOR I=1% TO 3000% : OUT 6%,209%
24 NEXT I : OUT 6%,0%
25 GOTO 97
26 ; CHR$(12%) : GOSUB 90
27 ; "Hur m}nga start och stopp.. ";
28 ONERRORGOTO 27
29 INPUT N%
30 DIM U1%(N%),U2%(N%),U3%(N%),C1%(N%),C2%(N%),C3%(N%)
31 FOR E%=1% TO N%
32 ONERRORGOTO 32
33 ; : ; "START No "E%" (HH,MM,SS)"
34 INPUT U1%(E%),U2%(E%),U3%(E%)
35 ONERRORGOTO 35
36 ; "STOPP No"E%" (HH,MM,SS)"
37 INPUT C1%(E%),C2%(E%),C3%(E%)
38 NEXT E%
39 ; CHR$(7%,12%) : GOTO 41
40 ; CHR$(12%)"VILL DU [NDRA N]GON INST[LLNING" : INPUT K$ : IF K$="J" OR K$="j" GOSUB 74
41 REM klocka
42 ; CHR$(12%)CUR(15%,0%)"Vill du st{lla klockan?" : GET A$
43 IF A$="J" OR A$="j" THEN GOSUB 53
44 ; CHR$(12%)
45 IF INP(56%)=152% 40 ELSE GOSUB 62
46 FOR E%=1% TO N%
47 IF H%=U1%(E%) AND M%=U2%(E%) AND S%=U3%(E%) GOSUB 72
48 IF H%=C1%(E%) AND M%=C2%(E%) AND S%=C3%(E%) GOSUB 73
49 NEXT E%
50 ; CUR(22%,25%)RIGHT$(NUM$(100%+H%),3%)":"RIGHT$(NUM$(100%+M%),3%);
51 ; ":"RIGHT$(NUM$(100%+S%),3%)
52 GOTO 45
53 REM set clock
54 ONERRORGOTO 54
55 ; "HH,MM,SS" : INPUT H%,M%,S%
56 Z=H%*3600+M%*60+S%
57 Z1%=Z*50/256
58 Z%= NOT (50*(Z-Z1%/50*256))
59 Z1%= NOT Z1%
60 POKE 65008%,Z%,Z1%,SWAP%(Z1%)
61 RETURN 
62 REM read clock
63 FOR I%=0% TO 2%
64 Z%(I%)=255% XOR PEEK(65008%+I%)
65 NEXT I%
66 Z=((Z%(2%)*256)+Z%(1%))*5.12+Z%(0%)/50
67 IF Z>86400 THEN Z=Z-86400 : D%=D%+1% : GOTO 67
68 H%=Z/3600 : Z=Z-3600*H%
69 M%=Z/60 : S%=Z-60%*M%
70 IF D%<>0% THEN GOSUB 56
71 RETURN 
72 OUT 58%,32% : RETURN 
73 OUT 58%,1% : RETURN 
74 FOR E%=1% TO N%
75 ; CHR$(7%,12%)
76 ; "START"E%;TAB(20%)RIGHT$(NUM$(100%+U1%(E%)),3%)":"RIGHT$(NUM$(100%+U2%(E%)),3%)":"RIGHT$(NUM$(100%+U3%(E%)),3%)
77 ; : ; "[ndras?"; : GET K$
78 IF K$="J" OR K$="j" 79 ELSE 82
79 ; : ; "HH,MM,SS"
80 ONERRORGOTO 80
81 INPUT U1%(E%),U2%(E%),U3%(E%)
82 ; CHR$(7%,12%)
83 ; "STOPP"E%;TAB(20%)RIGHT$(NUM$(100%+C1%(E%)),3%)":"RIGHT$(NUM$(100%+C2%(E%)),3%)":"RIGHT$(NUM$(100%+C3%(E%)),3%)
84 ; : ; "[ndras?"; : GET K$
85 IF K$="J" OR K$="j" 86 ELSE 89
86 ; : ; "HH,MM,SS"
87 ONERRORGOTO 87
88 INPUT C1%(E%),C2%(E%),C3%(E%)
89 NEXT E% : ; CHR$(12%) : RETURN 
90 ; CHR$(7%,12%)"V[LKOMMEN !!"
91 ; : ; : ; "Med hj{lp av detta pgm kan du starta" : ; "och stoppa (t.ex.) din bandspelare."
92 ; "Hur m}nga g}nger du vill!" : ; "Du kan st{lla in din DX-radio p} en" : ; " frekvens,och l}ta bandspelaren"
93 ; "spela in vid |nskade tidpunkter p}" : ; "natten (men {ven dagen f|rst}s)."
94 ; : ; : ; "Om du misst{nker att du gjort en fel-" : ; "inmatning av n}got klockslag,"
95 ; "Tryck ------------ Control-X"
96 ; : ; "s} kan du l{tt {ndra.  (return)" : GET K$ : ; CHR$(12%) : RETURN 
97 ; CHR$(12%)" DX GUIDE INDEX "
98 ; STRING$(36%,45%) : ; : ; 
99 ; " 1  AUTOMATISK BANDINSPELNING"
100 ; : ; : ; " 2  AVST]NDS-BER[KNINGAR"
101 ; : ; : ; " 3  ANTENN-RIKTNING"
102 ; : ; : ; " 4  H\GFREKVENS-'SIKT'"
103 ; : ; : ; " 5  Hz-METER OMVANDLING"
104 ; : ; : ; " 6  V[RLDS-KLOCKA"
105 ; : ; : ; : ; "V[LJ";
106 ONERRORGOTO 97
107 INPUT K%
108 IF K%<1% OR K%>6% THEN 97
109 ON K% GOTO 26,110,131,147,162,179
110 ; CHR$(12%)TAB(8%)"AVST]NDS-BER[KNINGAR"
111 X%=0%
112 ; STRING$(38%,45%) : ; : ; : ; : ; 
113 ; "Detta pgm ger avst}ndet i Km mellan tv}"
114 ; "orter p} jordytan."
115 ; "OBS att sydlig latitud och |stlig long-"
116 ; "itud ska vara negativa."
117 ; : ; : ; : ; "Din Latitud";
118 ONERRORGOTO 117
119 INPUT L1 : ; "Din Longitud";
120 INPUT L3 : ; "Motstations Latitud";
121 INPUT L2 : ; "Motstations Longitud";
122 INPUT L4
123 IF L1+L2+L3+L4=0% 117
124 K=PI/180%
125 L=SIN(L1*K)*SIN(L2*K)+COS(L1*K)*COS(L2*K)*COS((L4-L3)*K)
126 L5=ATN(SQR(1%-L*L)/L)*180%/PI
127 IF L5<=0% L5=L5+180%
128 IF X% RETURN 
129 ; CUR(22%,0%)"AVST]NDET [R"L5*111.111" Km      FLER";
130 GET K$ : IF K$<>"J" 97 ELSE 110
131 ; CHR$(12%)TAB(12%)"ANTENN-RIKTNING"
132 X%=1%
133 ; STRING$(38%,45%) : ; : ; : ; : ; 
134 ; "Detta pgm ger r{tt antenn-riktning till"
135 ; "|nskad ort p} jordytan."
136 ; "\ST=90,SYD=180,V[ST=270,NORD=360"
137 GOSUB 115
138 ONERRORGOTO 143
139 L6=((SIN(L2*K)-SIN(L1*K)*COS(L5*K))/(SIN(L5*K)*COS(L1*K)))
140 L7=ATN(SQR(1%-L6*L6)/L6)*180%/PI
141 IF L7<=0% L7=L7+180%
142 GOTO 144
143 L7=0%
144 IF SIN((L4-L3)*K)>=0% THEN L7=360%-L7
145 ; CUR(22%,0%)"RIKTNINGEN [R"L7" GRADER      FLER";
146 GET K$ : IF K$<>"J" 97 ELSE 131
147 ; CHR$(12%)TAB(12%)"FREKVENS-SIKT"
148 ; STRING$(38%,45%) : ; : ; : ; : ; 
149 ; "Denna f|reteelse {r m{rkbar redan vid"
150 ; "s} l}ga frekvenser som 100 MHz."
151 ; "Vid allt h|gre frekvenser blir den"
152 ; "optiska sikten n{ra nog identisk med"
153 ; "den utbredningsm|jlighet dessa"
154 ; "frekvenser har."
155 ; : ; : ; "Hur m}nga meter |ver havet sitter"
156 ; "din antenn";
157 ONERRORGOTO 147
158 INPUT H
159 S=SQR(ABS(H))*3.85216
160 ; CUR(22%,0%)"FREKVENS-SIKTEN [R"S" Km      FLER";
161 GET K$ : IF K$<>"J" 97 ELSE 147
162 ; CHR$(12%)TAB(8%)"Hz/METER OMVANDLING"
163 ; STRING$(38%,45%) : ; : ; : ; : ; 
164 ; "[n idag finns radioapparater med meter-"
165 ; "skala. Allm{n praxis {r dock att"
166 ; "anv{nda Hz, men en del radiostationer"
167 ; "uppger sina s{ndningsfrekvenser i meter"
168 ; "och h{r kan du l{tt omvandla."
169 ; : ; : ; "MHz/meter (1), meter/MHz (2)"
170 ONERRORGOTO 162
171 INPUT H% : IF H%=1% 172 ELSE 176
172 ; "MHz"; : INPUT H
173 S=2.99792E+8/(H*1E+6)
174 ; CUR(22%,0%)H" MHz ="S" METER.       FLER";
175 GET K$ : IF K$<>"J" 97 ELSE 162
176 ; "METER"; : INPUT H
177 S=299.792/H
178 ; CUR(22%,0%)H" METER ="S" MHz.       FLER"; : GOTO 175
179 ; CHR$(12%)"HUR MYCKET [R KLOCKAN?"; : ; : ; 
180 ONERRORGOTO 179
181 GOSUB 55
182 ; CHR$(12%)TAB(12%)"V[RLDS-KLOCKA"
183 ; STRING$(38%,45%)
184 GOSUB 62 : Y%=H%
185 I%=-1% : ; CUR(6%,0%)"LONDON     "; : GOSUB 211
186 I%=0% : ; "STOCKHOLM  "; : GOSUB 211
187 I%=1% : ; CUR(7%,0%)"KAIRO      "; : GOSUB 211
188 I%=2% : ; "MOSKVA     "; : GOSUB 211
189 I%=3% : ; CUR(8%,0%)"TEHERAN    "; : GOSUB 211
190 I%=4% : ; "NEW DELHI  "; : GOSUB 211
191 I%=5% : ; CUR(9%,0%)"DACCA      "; : GOSUB 211
192 I%=6% : ; "SUMATRA    "; : GOSUB 211
193 I%=7% : ; CUR(10%,0%)"TAIPEI     "; : GOSUB 211
194 I%=8% : ; "TOKYO      "; : GOSUB 211
195 I%=9% : ; CUR(11%,0%)"SYDNEY     "; : GOSUB 211
196 I%=10% : ; "WAKE ISLAND"; : GOSUB 211
197 I%=11% : ; CUR(12%,0%)"NEW ZEALAND"; : GOSUB 211
198 I%=-2% : ; "CAP VERDE  "; : GOSUB 211
199 I%=-3% : ; CUR(13%,0%)"GR\NLAND   "; : GOSUB 211
200 I%=-4% : ; "SAO PAULO  "; : GOSUB 211
201 I%=-5% : ; CUR(14%,0%)"SANTIAGO   "; : GOSUB 211
202 I%=-6% : ; "NEW YORK   "; : GOSUB 211
203 I%=-7% : ; CUR(15%,0%)"MEXICO     "; : GOSUB 211
204 I%=-8% : ; "DENVER     "; : GOSUB 211
205 I%=-9% : ; CUR(16%,0%)"LOS ANGELES"; : GOSUB 211
206 I%=-10% : ; "TUAMOTO    "; : GOSUB 211
207 I%=-11% : ; CUR(17%,0%)"HONOLULU   "; : GOSUB 211
208 I%=-12% : ; "SAMOA ISL. "; : GOSUB 211
209 ; CUR(22%,0%)"............ AVBRYT? (A) .............";
210 IF INP(56%)=65% 97 ELSE 184
211 Y%=H%+I% : IF Y%<0% THEN Y%=Y%+24% ELSE IF Y%>24% THEN Y%=Y%-24%
212 ; "  "RIGHT$(NUM$(100%+Y%),3%)":"RIGHT$(NUM$(100%+M%),3%)"  "; : RETURN