1 REM *****************************
2 REM * TJUGOETT.BAC - 16 K Minne *
3 REM * 79-10-05 / VER 1.0        *
4 REM * (c) Alf Wirdling   <4230> *
5 REM *****************************
9 ; CHR$(12);TAB(11);""
10 ; TAB(11);"               "
15 ; TAB(11);"          "
20 ; TAB(11);"           "
25 ; TAB(11);"           "
30 ; TAB(11);"             "
35 ; TAB(11);"             "
40 ; TAB(11);"             "
45 ; TAB(11);"             "
50 ; TAB(11);"             "
55 ; TAB(11);"    "
60 ; TAB(11);"               "
65 ; TAB(11);""
70 ; CUR(19,1);"     KAN DU SPEL-REGLERNA (J/N) "; : GET R$
75 IF R$="J" OR R$="j" THEN 165
80 ; CHR$(12);"       SPEL-REGLER F\R TJUGOETT"
85 ; SPACE$(7);STRING$(24,61) : ; 
90 ; "Spelet spelas enligt reglerna f|r kort-"
95 ; "spelet 21 med det undantaget att endast"
100 ; "Du och datorn deltar. Vidare {r alltid"
105 ; "datorn bankir." : ; 
110 ; "Datorns insats i banken {r mellan"
115 ; "500-1000 kr. Du f}r h{lften s} mycket"
120 ; "pengar att spela med." : ; 
125 ; "Efter det att Du f}tt f|rsta kortet"
130 ; "satsar Du. Om det var ett kl{tt kort"
135 ; "kan Du sedan m|rka." : ; 
140 ; "N{r Du inte vill ha fler kort straffar"
145 ; "datorn s}vida Du inte sprack." : ; 
150 ; "Spelet {r slut n{r datorn har gjort Dig"
155 ; "pank eller Du spr{nger banken." : ; 
160 ; : ; "TRYCK RETURN N[R DU L[ST F[RDIGT "; : GET R$
165 ; CHR$(12);"            SPELET B\RJAR !" : ; 
170 RANDOMIZE : DIM L$(52) : DIM L%(52)
175 B%=RND*501+500 : S%=B%/2
180 ; "JAG [R BANKIR, MIN INSATS [R";B%;" KR" : ; 
185 ; "JAG GER DIG";S%;" KR ATT SPELA MED"
190 ; : ; "JAG SKALL BARA BLANDA LEKEN !"
195 FOR U=1 TO 10000 : NEXT U
200 T%=0 : M%=0 : RESTORE 
205 FOR I%=1 TO 4 : READ F$
210 FOR J%=1 TO 13 : L$(T%+J%)=F$
215 L%(T%+J%)=J% : NEXT J%
220 T%=T%+13 : NEXT I% : RESTORE 905
225 FOR F%=1 TO 5 : READ F$
230 ; : ; "DITT ";F$;" KORT [R : ";
235 GOSUB 585 : ; L$(N%);" ";L2$
240 FOR W0=1 TO 1000 : NEXT W0
245 IF F%<>1 THEN 675
250 ; : ; "HUR MYCKET SATSAR DU ";
255 IF K%(1)=1 THEN P5%=14 ELSE P5%=K%(1)
260 ONERRORGOTO 260
265 INPUT C% : IF C%>0 THEN 275
270 ; : ; "DU M]STE SATSA N]GOT !" : GOTO 250
275 IF C%<=S% THEN 285
280 ; : ; "DU HAR BARA";S%;" KR !" : GOTO 250
285 IF C%<B% THEN 310
290 IF C%=B% THEN 305
295 ; : ; "BANKENS KAPITAL [R BARA";B%;" KR !"
300 GOTO 250
305 ; : ; "T[NKER DU SPR[NGA BANKEN !"
310 ; : ; "VILL DU HA MER KORT (J/N) "; : GET R$
315 IF R$="N" OR R$="n" THEN ; : GOTO 750
320 ; : IF F%<=1 THEN 330
325 NEXT F%
330 IF K%(F%)<11 THEN 325
335 ; : ; "M\RKAR DU (J/N) "; : GET R$
340 IF R$="N" OR R$="n" THEN ; : GOTO 325
345 ; : ; : ; "DITT SISTA KORT [R : "; : F%=2
350 GOSUB 585 : ; L$(N%);" ";L2$ : M%=1
355 FOR W1=1 TO 1000 : NEXT W1
360 GOSUB 510
365 ON Q% GOTO 370,370,450,460,460
370 B%=B%-C% : S%=S%+C%
375 ; : ; "GRATTIS ! DU FICK 21 !"
380 FOR W2=1 TO 1000 : NEXT W2 : GOSUB 650
385 IF E%<>0 THEN 480
390 ; : ; "BANKENS KAPITAL";TAB(25);"DITT KAPITAL"
395 ; STRING$(15,61);SPACE$(10);STRING$(12,61)
400 ; B%;"  (-";C%;")";
405 ; TAB(25);S%;"  (+";C%;")"
410 FOR W3=1 TO 2000 : NEXT W3
415 ; : ; "======================================" : GOTO 200
420 ; : ; "BANKENS KAPITAL";TAB(25);"DITT KAPITAL"
425 ; STRING$(15,61);SPACE$(10);STRING$(12,61)
430 ; B%;"  (+";C%;")";
435 ; TAB(25);S%;"  (-";C%;")"
440 FOR W4=1 TO 2000 : NEXT W4
445 ; : ; "======================================" : GOTO 200
450 ; : ; "JAG STRAFFAR !" : A%=P5%
455 FOR W5=1 TO 1000 : NEXT W5 : GOTO 760
460 B%=B%+C% : S%=S%-C%
465 ; : ; "DU SPRACK !"
470 FOR W6=1 TO 1000 : NEXT W6 : GOSUB 650
475 IF E%=0 THEN 420
480 ON E% GOTO 485,490
485 ; : ; "DU SPR[NGDE BANKEN !  JAG [R RUINERAD !" : GOTO 495
490 ; : ; "BEKLAGAR ! DU [R PANK !"
495 ; : ; "VILL DU SPELA MER (J/N) "; : GET R$
500 IF R$="J" OR R$="j" THEN 165
505 ; : ; : ; "TACK F\R GOTT SPEL !" : END 
510 IF F%<>2 THEN 525
515 IF K%(1)+K%(2)<>2 THEN 525
520 Q%=2 : GOTO 580
525 V%=0 : P%=0
530 FOR H%=1 TO F% : P%=P%+K%(H%)
535 IF K%(H%)=1 THEN V%=1
540 NEXT H%
545 IF V%=1 THEN P2%=P%+13 ELSE P2%=26
550 IF P2%<22 THEN P5%=P2% : GOTO 560
555 P5%=P%
560 IF P5%>21 THEN Q%=4 : GOTO 580
565 IF P5%=21 THEN Q%=1 : GOTO 580
570 IF F%=5 THEN Q%=5 : GOTO 580
575 Q%=3
580 RETURN 
585 N%=RND*52+1 : IF L%(N%)=0 THEN 585
590 K%(F%)=L%(N%)
595 IF L%(N%)<>11 THEN 605
600 L2$="KNEKT" : GOTO 640
605 IF L%(N%)<>12 THEN 615
610 L2$="DAM" : GOTO 640
615 IF L%(N%)<>13 THEN 625
620 L2$="KUNG" : GOTO 640
625 IF L%(N%)<>1 THEN 635
630 L2$="ESS" : GOTO 640
635 L2$=NUM$(L%(N%))
640 K$(F%)=L$(N%) : K2$(F%)=L2$
645 L%(N%)=0 : RETURN 
650 IF B%=0 OR S%=0 THEN 660
655 E%=0 : GOTO 670
660 IF B%=0 THEN E%=1 : GOTO 670
665 E%=2
670 RETURN 
675 GOSUB 510
680 ON Q% GOTO 370,685,705,460,730
685 B%=B%-C% : S%=S%+C%
690 ; : ; "2 ESS UTAN ANDRA KORT = 21 !"
695 FOR W7=1 TO 1000 : NEXT W7
700 GOSUB 650 : GOTO 385
705 ; : ; "DU HAR NU F\LJANDE KORT :" : ; 
710 FOR W8=1 TO 1000 : NEXT W8
715 FOR D%=1 TO F%
720 ; K$(D%);TAB(8);K2$(D%) : NEXT D%
725 GOTO 310
730 B%=B%-C% : S%=S%+C%
735 ; : ; "5 KORT UNDER 21 = 21 !"
740 FOR W9=1 TO 1000 : NEXT W9
745 GOSUB 650 : GOTO 385
750 ; : ; "OK, JAG STRAFFAR !" : A%=P5%
755 FOR Y0=1 TO 1000 : NEXT Y0
760 ; : ; "JAG FICK F\LJANDE KORT :" : ; 
765 FOR Y1=1 TO 1000 : NEXT Y1
770 FOR G%=1 TO 5 : F%=G% : GOSUB 585
775 ; L$(N%);TAB(8);L2$; : F%=G% : GOSUB 510
780 ON Q% GOTO 785,805,825,865,885
785 B%=B%+C% : S%=S%-C%
790 ; : ; : ; "JAG FICK 21 !"
795 FOR Y2=1 TO 1000 : NEXT Y2 : GOSUB 650
800 IF E%<>0 THEN 480 ELSE GOTO 420
805 B%=B%+C% : S%=S%-C%
810 ; : ; : ; "2 ESS UTAN ANDRA KORT = 21 !"
815 FOR Y3=1 TO 1000 : NEXT Y3
820 GOSUB 650 : GOTO 800
825 IF P5%>A% THEN 845
830 IF P5%=A% THEN 840
835 ; : NEXT G%
840 IF M%=1 THEN 835
845 B%=B%+C% : S%=S%-C%
850 ; TAB(15);"SUMMA =";P5%
855 ; : ; "DU HADE BARA";A%
860 FOR Y4=1 TO 1000 : NEXT Y4 : GOTO 820
865 B%=B%-C% : S%=S%+C%
870 ; : ; : ; "JAG SPRACK !"
875 FOR Y5=1 TO 1000 : NEXT Y5
880 GOSUB 650 : GOTO 385
885 B%=B%+C% : S%=S%-C%
890 ; : ; : ; "5 KORT UNDER 21 = 21 !"
895 FOR Y6=1 TO 1000 : NEXT Y6 : GOTO 820
900 DATA "HJ[RTER","RUTER","SPADER","KL\VER"
905 DATA "F\RSTA","ANDRA","TREDJE"
910 DATA "FJ[RDE","FEMTE"