1 REM Ins{nt av 415
5 REM LIST MON.GAM
9 REM F|rmedlat av medlem 415
10 REM ********************************
20 REM ***                          ***
30 REM ***          ETT             ***
40 REM ***   FROST   &   MESSO      ***
50 REM ***        PROGRAM           ***
60 REM ***                          ***
70 REM ***       GJORT AV           ***
80 REM *** NILS FROSTBERG           ***
90 REM *** BORGM[STAREGATAN 11C     ***
100 REM ** 81500 TIERP              ***
105 REM ** TEL 0293 11916           ***
110 REM **         &                ***
120 REM ** ELIE MESSO               ***
130 REM ** S]GARGATAN 13C           ***
135 REM ** 74052 GIMO               ***
140 REM **                          ***
145 REM ** Skriv och tala om vad du ***
146 REM ** tycker om spelet.        ***
150 REM *******************************
160 B%=-9% : C%=0% : Q=2
170 ; CHR$(12%)STRING$(900%,151%);
180 RESTORE 1350
190 FOR A%=C% TO B% STEP -1%
200 READ A$ : IF A%<0% THEN 220
210 ; CUR(A%,12%)A$
220 NEXT A%
230 FOR T=1 TO Q : NEXT T
240 Q=Q+Q*.6
250 B%=B%+1% : C%=C%+1%
260 IF C%>13% ; CUR(13%,19%)'  ' : GOTO 280
270 GOTO 180
280 RESTORE 1450
290 READ A%,B% : ONERRORGOTO 330
300 FOR T%=1% TO A% : OUT 6%,0% : OUT 6%,121% : FOR T1%=1% TO B% : NEXT T1% : NEXT T%
310 GOTO 290
320 REM ***** INSTRUKTIONER **************
330 ; CHR$(12%)
340 ; CUR(10%,5%)'VILL DU HA INSTRUKTIONER '; : GET A$
350 IF A$='J' OR A$='j' THEN 360 ELSE 440
360 ; CHR$(12%);TAB(6%)'*** SUPER MOON LANDER ***'
370 ; CUR(3%,1%)'DU SITTER I ETT RYMDSKEPP OCH SKALL     F\RS\KA LANDA.'
380 ; CUR(5%,1%)'DET FINS TV] LANDNINGS PLATSER ATT      LANDA P]. '
390 ; CUR(7%,1%)'DU F]R MER PO[NG OM DU HAR MYCKET       BR[NSLE KVAR'
400 ; CUR(9%,1%)'DU F]R INTE K\RA P] N]GOT VITT F\R D]   SM[LLER DET.'
410 ; CUR(11%,1%)'DU GASAR UPP]T MED MELLAN SLAG OCH STYR TILL V[NSTER MED (1/!) OCH TILL H\GER   MED (</>).'
420 ; CUR(15%,11%)'LYCKA TILL!'
430 ; CUR(19%,0%)'TRYCK P] N]GON TANGENT F\R ATT STARTA!' : IF PEEK(65013%) AND 128%<>0% 440 ELSE 430
440 REM ******* VARIABLER *************
445 ; CHR$(12%);CUR(10%,8%)'VAD HETER DU'; : INPUT C$
446 IF C$='' 445
450 P%=0% : V7=.2
460 S%=3% : G=0 : S3%=4%
470 V=0 : F%=10000% : L%=1% : H=100
480 X%=60% : X1%=X%+1% : Y%=8% : Y1%=Y%-1% : Y2%=Y%+1%
490 REM ***** GRAFIK ******************
500 ; CHR$(12%) : FOR I%=2% TO 23% : ; CUR(I%,0%)CHR$(151%); : NEXT I%
510 REM ***** UTSKRIFTER **************
520 ; CUR(0%,1%)'SPEED:      FUEL:         POINTS:'P%
530 ; CUR(1%,1%)'LANDINGS:    SHIPS:      HISCORE:      '
540 ; CUR(2%,1%)STRING$(39%,112%)
550 REM ****** RITA LANDSKAP ***********
560 RESTORE 1140
570 FOR Z%=3% TO 21%
580 READ I$
590 ; CUR(Z%,1%)I$
600 NEXT Z%
610 REM **** HUVUD PROGRAM ***********
620 B%=INP(56%)-128%
630 X1%=X% : Y1%=Y%
640 IF X%=60% 660
650 IF C%<1% 680
660 IF B%=32% V=V-.09 ELSE IF X%<60% V=V+.05
670 GOTO 690
680 IF B%=32% V=V-V7 ELSE V=V+V7
689 IF F%>1500% Q9%=25% ELSE Q9%=159%
690 IF B%=32% F%=F%-89% : OUT 6%,Q9%
700 IF F%<0% F%=0%
710 IF F%=0% GOTO 1080
720 C%=INT(V) : U%=INT(10*V) : ; CUR(0%,8%)ABS(U%)' '
730 IF L%=1% L%=2% ELSE L%=1%
740 RESTORE 1340
750 IF S3%>14% S3%=14%
760 FOR T%=1% TO S3%
770 READ E1%,E2%
780 IF L%=2% ; CUR(E1%,E2%)'91' ELSE ; CUR(E1%,E2%)'f$'
790 NEXT T%
800 ; CUR(0%,18%)CHR$(135%)F%' 'CUR(1%,19%)S%
810 IF P%>H1% H1%=P%
820 ; CUR(1%,10%)[%CUR(1%,33%)H1%
830 X%=X%+C% : X1%=X%+1%
840 IF B%=60% Y%=Y%+1%
850 IF B%=49% Y%=Y%-1%
860 Y1%=Y%-1% : Y2%=Y%+1%
870 IF X1%<63% 910
880 IF Y%<20% 1000
890 IF Y%>50% G%=INT(F%/30%) ELSE G%=INT(F%/20%)
900 GOTO 1040
910 IF DOT(X%,Y%) OR DOT(X1%,Y1%) OR DOT(X1%,Y2%) 1000
920 SETDOT X%,Y% : SETDOT X1%,Y1% : SETDOT X1%,Y2%
930 IF B%=32% SETDOT X%+1%,Y%
940 FOR T=1 TO 100 : NEXT T
950 CLRDOT X%,Y% : CLRDOT X1%,Y1% : CLRDOT X1%,Y2% : CLRDOT X%+1%,Y%
960 IF NOT B%=32% OUT 6,0%
970 POKE 65013,0
980 GOTO 620
990 REM ***** EXPLOSION ***************
1000 E1%=X%/3% : E2%=Y%/2%-2% : ; CUR(E1%-1%,E2%)' 89990 'CUR(E1%,E2%)'f9'CUR(E1%+1%,E2%)' )999= '
1010 FOR T=1 TO 30 : OUT 6,137% : OUT 6,159% : FOR J1=1 TO 20 : NEXT J1 : OUT 6,0 : NEXT T : S%=S%-1% : OUT 6,0
1020 IF S%<0% 1100 ELSE 470
1030 REM ***** LANDNING  ***************
1040 FOR T=1 TO G% : OUT 6,255% : ; CUR(10%,10%)'HAPPYLANDING' : P%=P%+1% : ; CUR(0%,34%)P% : NEXT T
1045 X%=60% : [%=[%+1%
1050 S3%=S3%+1% : V7=V7+.05 : IF V7>1 V7=1
1060 GOTO 470
1070 REM ***** BR[NSLET SLUT ***********
1080 FOR T=1 TO 200 : ; CUR(10%,10%)'OUT OF FUEL' : NEXT T : S%=S%-1% : GOTO 470
1090 REM ***** GAME OVER ***************
1100 ; CHR$(12%)CUR(3%,5%)'****** GAME OVER ******'CUR(7%,5%)'DU FICK 'P%' PO[NG 'C$
1101 IF H1%>H2% THEN H2%=H1% : Q1$=C$
1105 ; CUR(9%,5%)'HISCORE [R 'H1%' PO[NG'
1106 ; CUR(11%,5%)'OCH [R UPPN]TT AV 'Q1$
1108 ; CUR(15%,5%)'VILL DU F\RS\KA IGEN'; : GET M$
1110 IF M$='j' OR M$='J' THEN 160 ELSE END 
1120 GOTO 1108
1130 REM ****** LANDSKAP ***************
1140 DATA "5   $       $          $            $ j"
1150 DATA "5         $       $          $ $      j"
1160 DATA "5    $       $         $         $    j"
1170 DATA "5        $         $         $        j"
1180 DATA "5   $         $         $             j"
1190 DATA "5   $        $        $     $         j"
1200 DATA "5       $     $        $         $  $ j"
1210 DATA "5                                     j"
1220 DATA "5      $      zu $  $                 j"
1230 DATA "5            ~}                     j"
1240 DATA "5           ~7                     j"
1250 DATA "5          ~   0                  j"
1260 DATA "5         ~5  z}     $    $       j"
1270 DATA "5    $   ~7  z}   $         $   j"
1280 DATA "5       ~  k}  $    $  $    j"
1290 DATA "5      ~}  k}              j"
1300 DATA "5    ~}  }             j"
1310 DATA "}pp~  }ppppp~ j}  j"
1320 DATA "pppz"
1330 REM ****** STJ[RN POSITIONER *****
1340 DATA 10,9,15,30,10,6,4,4,15,7,17,34,12,10,9,19,18,32,7,15,13,19,5,30,12,32,14,27
1350 DATA "  `~}0   `~}0  "
1360 DATA "   j7 sss k5  "
1370 DATA "    x?h4ot   "
1380 DATA "   /o?o?/  "
1390 DATA "#*o?%#"
1400 DATA "nMOON LANDER="
1410 DATA "p`~SUPER}0p"
1420 DATA "   xt   "
1430 DATA "    (<   l$    "
1440 DATA "               "
1450 DATA 18,70,18,50,19,38,30,31,40,38,45,31