10 REM +++++++++++++++++++++++++++++++++
11 REM ! Program ....   UB]T1281
12 REM ! Utg}va  1.0    ????
13 REM ! av (c) Jarri Ederth &
14 REM !        Freddy Lundmark
15 REM ! Minne 16 Kbytes
16 REM +++++++++++++++++++++++++++++++++
17 REM 
18 ; CHR$(12)
19 ; CHR$(151);"7#####################################k";
20 ; CHR$(151);"5            UB]TSATTACK              j";
21 ; CHR$(151);"upppppppppppppppppppppppppppppppppppppz";
22 ; : ; " Du sitter i en ub}t och har till" : ; " uppgift att s{nka de fartyg som" : ; " passerar."
23 ; : ; : ; " Det finns tre slags fartyg:"
24 ; : ; CHR$(151);"pxu";CHR$(135);TAB(15);"Jagare";TAB(30);"(10p.)"
25 ; : ; CHR$(151);"pp|~t0";CHR$(135);TAB(15);"Kryssare";TAB(30);"(5p.)"
26 ; : ; CHR$(151);"  u"
27 ; CHR$(151);"l|||||||,";CHR$(135);TAB(15);"Hangarfartyg";TAB(30);"(1p.)"
28 ; : ; : ; : ; " Du avfyrar torpederna med 'RETURN'."
29 ; CUR(23,38); : GET A$
30 ; CHR$(12)
31 ; "Du b|rjar din karri{r som menig och     befodras sedan enligt dina resultat."
32 ; : ; : ; "Du har femton torpeder till ditt" : ; "f|rfogande. Sedan presenteras dina"
33 ; "resultat, en kvot, samt din rang och" : ; "din gradbeteckning."
34 ; : ; "Du f}r sedan femton nya torpeder, n{r" : ; "du gjort slut p} dem, presenteras"
35 ; "dina resultat, rang o.s.v."
36 ; : ; "Kvoten {r en sammanst{llning av dina" : ; "resultat."
37 ; : ; : ; : ; "Tryck 'RETURN' n{r du {r klar att b|rja!"
38 ; CUR(23,38); : GET A$
39 ; CHR$(12)
40 FOR I%=4 TO 23
41 ; CUR(I%,0);CHR$(151);
42 NEXT I%
43 FOR V%=2 TO 79
44 SETDOT 18,V%
45 NEXT V%
46 ; CUR(17,3);"0"
47 ; CUR(18,2);"je `"
48 ; CUR(19,1);"8!"",&)0";TAB(21);"6"
49 ; CUR(20,1);"!";TAB(7);"i  `&d";TAB(20);":"
50 ; CUR(21,8);"ip%  )p8#dp&"
51 ; CUR(15,23);"6dp8!";TAB(36);"*p0"
52 ; CUR(14,27);"`' e,&dp,0"
53 ; CUR(13,28);"`80"
54 ; CUR(16,17);"j    :";TAB(38);"j"
55 ; CUR(17,15);"pz    5";TAB(39);"-"
56 ; CUR(18,12);" j"
57 K$=" pp|~t0"
58 J$=" pxu"
59 H1$="   u"
60 H2$=" l|||||||,"
61 ; CUR(0,2)"FARTYG:"F%, : ; "PO[NG:"P%, : ; "SKOTT:";S2%
62 RANDOMIZE 
63 V%=INT(RND*3)
64 X=(RND*3)
65 F%=F%+1
66 H%=0
67 FOR Q=1 TO X*1000 : NEXT Q
68 ; CUR(0,9);F% : ; CUR(0,20);P% : ; CUR(0,34);S2%
69 IF V%=1 THEN 80
70 IF V%=2 THEN 89
71 REM **** KRYSSARE ****
72 FOR X%=1 TO 33
73 ; CUR(5,X%);K$
74 IF H%=1 THEN 76
75 IF INP(56)=141 THEN GOSUB 100
76 FOR F=1 TO 25 : NEXT F
77 NEXT X%
78 ; CUR(5,33);STRING$(7,32)
79 GOTO 63
80 REM **** JAGARE ****
81 FOR X%=1 TO 36
82 ; CUR(5,X%);J$
83 IF H%=1 THEN 85
84 IF INP(56)=141 THEN GOSUB 100
85 FOR F=1 TO 15 : NEXT F
86 NEXT X%
87 ; CUR(5,36);STRING$(4,32)
88 GOTO 63
89 REM **** HANGAR ****
90 FOR X%=1 TO 29
91 ; CUR(4,X%);H1$
92 ; CUR(5,X%);H2$
93 IF H%=1 THEN 95
94 IF INP(56)=141 THEN GOSUB 100
95 FOR F=1 TO 35 : NEXT F
96 NEXT X%
97 ; CUR(4,32);" "
98 ; CUR(5,30)STRING$(10,32)
99 GOTO 63
100 REM **** SKOTT ****
101 H%=1
102 IF S2%=15 THEN 123
103 S2%=S2%+1
104 S1%=47
105 FOR S%=1 TO 29
106 SETDOT S1%,35
107 FOR T=1 TO 2 : NEXT T
108 CLRDOT S1%,35
109 S1%=S1%-1
110 NEXT S%
111 IF DOT(17,35) THEN 112 ELSE RETURN 
112 REM ** TR[FF **
113 N%=N%+1
114 ; CUR(4,1);STRING$(38,32);
115 ; CUR(5,1);STRING$(38,32);
116 OUT 6,11
117 FOR Z=1 TO 700 : NEXT Z
118 OUT 6,0
119 IF V%=0 THEN P%=P%+5
120 IF V%=1 THEN P%=P%+10
121 IF V%=2 THEN P%=P%+1
122 GOTO 63
123 REM **** AMM SLUT ****
124 F=F% : P=P% : N=N%
125 K=((P*N)/F)*10
126 K=INT(K)
127 ; CHR$(12)
128 ; "DU S[NKTE"N%" FARTYG OCH FICK"P%" PO[NG"
129 ; : ; "DET GER DIG KVOTEN";K
130 IF K<50 THEN F$="DU BLIR DEGRADERAD TILL " : B%=B%-2
131 IF K>=50 AND K<100 THEN B%=B%+0
132 IF K>=100 AND K<400 THEN B%=B%+1
133 IF K>=400 AND K<700 THEN B%=B%+2
134 IF K>=1000 AND K<1300 THEN B%=B%+3
135 IF K>=1300 THEN B%=B%+4
136 IF B%<1 THEN E$="MENIG" : G4$=""
137 IF B%>=1 AND B%<3 THEN E$="VICEKORPRAL" : G4$=CHR$(151,112)
138 IF B%>=3 AND B%<5 THEN E$="KORPRAL" : G4$=CHR$(151,115)
139 IF B%>=5 AND B%<7 THEN E$="FURIR" : G3$=CHR$(151,44) : G4$=CHR$(151,115)
140 IF B%>=7 AND B%<9 THEN E$="\VERFURIR" : G2$=CHR$(151,44) : G3$=CHR$(151,44) : G4$=CHR$(151,115)
141 IF B%>=9 AND B%<11 THEN E$="SERGEANT" : G4$=CHR$(151,112,112)
142 IF B%>=11 AND B%<13 THEN E$="FANJUNKARE" : G4$=CHR$(151,115,115)
143 IF B%>=13 AND B%<15 THEN E$="F[NRIK" : G4$=CHR$(151,124,124)
144 IF B%>=15 AND B%<17 THEN E$="L\JTNANT" : G3$=CHR$(151,124,124) : G4$=CHR$(151,124,124)
145 IF B%>=17 AND B%<19 THEN E$="KAPTEN" : G2$=CHR$(151,124,124) : G3$=CHR$(151,124,124) : G4$=CHR$(151,124,124)
146 IF B%>=19 AND B%<21 THEN E$="MAJOR" : G1$=CHR$(151,112,112) : G2$=CHR$(151,115,115) : G3$=CHR$(151,115,115)
147 IF B%>=19 AND B%<21 THEN E$="MAJOR" : G4$=CHR$(151,124,124)
148 IF B%<21% OR B%>22% 150
149 E$="KOMMEND\RKAPTEN" : G1$=CHR$(151,124,124) : G2$=CHR$(151,124,124) : G3$=CHR$(151,124,124)
150 IF B%>=21 AND B%<23 THEN E$="KOMMEND\RKAPTEN" : G4$=CHR$(151,124,124)
151 IF B%>=23 AND B%<25 THEN E$="KOMMEND\R" : G2$=CHR$(151,127,127) : G3$=CHR$(151,44,44) : G4$=CHR$(151,115,115)
152 IF B%>=25 AND B%<27 THEN E$="KONTERAMIRAL" : G4$=CHR$(42)
153 IF B%>=27 AND B%<29 THEN E$="VICEAMIRAL" : G3$=CHR$(42) : G4$=CHR$(42)
154 IF B%>=29 AND B%<31 THEN E$="AMIRAL" : G2$=CHR$(42) : G3$=CHR$(42) : G4$=CHR$(42)
155 IF B%>=31 THEN 167
156 IF K<50 THEN 174
157 ; : ; : ; "DU HAR ";E$;"S GRAD"
158 ; CUR(13,0);"DIN GRADBETECKNING:"
159 ; CUR(15,27);G1$;
160 ; CUR(16,27);G2$;
161 ; CUR(17,27);G3$;
162 ; CUR(18,27);G4$;
163 F%=0 : S%=0 : S1%=0 : S2%=0 : P%=0 : N%=0
164 G1$="" : G2$="" : G3$="" : G$=""
165 FOR X=1 TO 10000 : NEXT X
166 GET A$ : GOTO 39
167 REM ***** AMIRAL *****
168 ; CHR$(12)
169 ; "DU [R NU AMIRAL OCH KAN INTE KOMMA H\GRE";
170 ; "DET [R D[RF\R INGEN ID@ ATT DU SPELAR   L[NGRE"
171 ; : ; "OM DU VILL FORTS[TTA DIN MILIT[RA       KARRI[R F]R DU S\KA SOM MENIG VID N]GOT"
172 ; "ANNAT VAPENSLAG"
173 GOTO 177
174 REM ***** DEGRADERAD *****
175 ; : ; : ; F$;E$
176 GOTO 158
177 END