1 REM Ins{nt av 2839
100 REM ............................
110 REM .  FORMATTERINGSPRORAM
120 REM .  Rensar begangnade skivor
130 REM .  fr}n  A L L T
140 REM .        - - - -
150 REM .
160 REM .  f|r enkel sidiga skivor
170 REM .  med 40 sp}r
180 REM .
190 REM .  (c) Lars-B|rje Cid  83
191 REM .      Tel. 0150-539 43
200 REM .      DDK  1983-07-30
210 REM ............................
220 REM .  Detta {r en vidare
230 REM .  utveckling av prog-
240 REM .  rammet "RENSA".
250 REM .  av (c) Per-Olof Ahl
260 REM .  Se ABC-bladet 3/81.
270 REM .
280 REM .  Om man k|rde det 
290 REM .  pgmet kunde det om
300 REM .  man lagrade en text-
310 REM .  fil p} skivan bli
320 REM .  diverse  ERR vid in-
330 REM .  l{sning av filen.
340 REM .  P.g.a att gamla pgm-
350 REM .  snuttar blandades 
360 REM .  med den nya filen.
370 REM .
380 REM .  Detta program tar
390 REM .  bort alla delar av
400 REM .  program + biblioteket
410 REM ............................
420 REM .
421 A%=PEEK(-767%) : REM Drive
422 ; CHR$(12%)
430 ; : ; "***** FORMATTERING ******"
440 ; : ; ' Skivan i drive'A%' kommer att'
450 ; ' FORMATTERAS!!!'
460 ; : ; ' Inneh}llet p} skivan kommer'
470 ; : ; ' att  F \ R S T \ R A S'
480 ; '      = = = = = = = = ='
490 ; : ; "[r detta ok "; : INPUT A$
500 A$=A$+" " : IF LEFT$(A$,1%)<>"J" END 
501 POKE 65011,PEEK(65011)-1% : ; SPACE$(39%)CHR$(13%)"Verkligen ?"; : INPUT A$
510 A$=A$+" " : IF LEFT$(A$,1%)<>"J" END 
520 REM 
530 REM  BITKARTA 
540 REM 
541 REM Sp}r 7 inneh}ller en tom
542 REM bitkarta.
543 REM 
550 Z%=CALL(24678%,7%*32%) : Z%=CALL(24675%,6%*32%)
560 GOSUB 740
570 REM 
580 REM  BIBLIOTEKET 
590 REM 
591 REM G|r en tom biblioteks-
592 REM sektor och skriv |ver
593 REM biblioteket.
594 REM 
600 FOR I%=62720% TO 62975%
610 IF I%-62720%>15% POKE I%,255% ELSE POKE I%,0%
620 NEXT I%
630 FOR I%=0% TO 7% : GOSUB 740 : Z%=CALL(24675%,256%+32%*I%)+CALL(24675%,512%+I%*32%)
640 NEXT I%
650 REM 
660 REM  \VRIGA SEKTORER 
670 REM 
671 REM En tom sektor {r vid ny-
672 REM formattering fylld med '@'
673 REM ASCII(64).
674 REM 
680 FOR I%=62720% TO 62975% : POKE I%,64% : NEXT I%
690 FOR I%=0% TO 5% : GOSUB 740 : Z%=CALL(24675%,I%*32%) : NEXT I%
700 FOR I%=24% TO 319% : GOSUB 740 : Z%=CALL(24675%,I%*32%) : ; "Sektor"I%CHR$(13%); : NEXT I% : END 
710 REM 
720 REM  Fel ? 
730 REM 
740 IF PEEK(-747%) THEN ; : ; "Formatteringen misslyckades."; : END 
741 RETURN