1 REM Ins{nd av Curt Rehnborg <1121>    1986-02-21 14.45.30
20 REM ver 1 810415 ver 2 810822
40 DIM R9$=40%,S$=1%
50 ; CHR$(12)TAB(15%)'-SNABBKOPIA-'
60 ; : ; : ; 'Programmet snabbkopierar disketten i    drive 0 till disketten i drive 1.'
70 ; : ; 'Om en programskiva anv{nds flitigt,med  ofta  }terkommande {ndringar av program och filer ';
80 ; 'b|r du d} och d} g|ra en "tv{ttad" kopia av originalskivan med hj{lp  av COPYLIB.ABS,';
90 ; 'ett av systemprogrammen.'
100 ; : ; 'Tv} alternativ ges:Helkopia som kopi-   erar ALLT p} originalet och Filkopia somendast kopierar upptagna';
110 ; 'filer.'
120 ; : ; 'Kom ih}g:Originalet i DR0, kopian i DR1!'
130 ; : ; 'Tryck p} RETURN n{r du {r klar'; : GET S$
140 DATA '-SNABBKOPIA-','HELKOPIA AV ORIGINALSKIVAN','FILKOPIA'
150 H=PEEK(65056%)+256*PEEK(65057%)+256% : T=PEEK(65063%)+256*PEEK(65064%)-1000% : POKE 65056%,T,SWAP%(T)
160 POKE 64769%,0% : POKE 64786%,0%,250%
170 Z%=CALL(24678%,224%) : REM SP 0 SEKT 7
180 S%=2% : FOR I%=64003% TO 64255% : IF PEEK(I%)=0% S%=S%+1% : NEXT I%
190 RESTORE : N9%=2% : GOSUB 480
200 ; CUR(15%,0%)'DISKETTEN I DR1 KOMMER ATT RADERAS !' : ; 'VILL DU DET (N)'; : INPUT S$
210 IF S$<>'J' AND S$<>'j' END 
220 REM HELKOPIA
230 ON I9% GOTO 240,340
240 GOSUB 540 : J=-32% : FOR I=0% TO 256*S% STEP 32%
250 Z%=CALL(24678%,I) : GOSUB 550
260 IF D>T GOSUB 290
270 NEXT I
280 GOSUB 290 : GOTO 560
290 REM L[GG \VER P] DR1
300 GOSUB 540 : POKE 64769%,1% : FOR J=J+32% TO 256*S% STEP 32%
310 Z%=CALL(24675%,J) : GOSUB 550
320 IF D<T NEXT J
330 GOSUB 540 : POKE 64769%,0% : RETURN 
340 REM FILKOPIA
350 Z%=CALL(24678%,192%)
360 Z0%=64000% : Z1%=Z0% : R0%=1% : R1%=R0% : GOSUB 540 : J=-32% : FOR I=0% TO 256*S% STEP 32%
370 IF PEEK(Z0%) AND R0% Z%=CALL(24678%,I) : GOSUB 550
380 IF R0%=128% R0%=1% : Z0%=Z0%+1% ELSE R0%=2%*R0%
390 IF D>T GOSUB 420
400 NEXT I
410 GOSUB 420 : GOTO 560
420 REM L[GG \VER P] DR1
430 GOSUB 540 : POKE 64769%,1% : FOR J=J+32% TO 256*S% STEP 32%
440 IF PEEK(Z1%) AND R1% Z%=CALL(24675%,J) : GOSUB 550
450 IF R1%=128% R1%=1% : Z1%=Z1%+1% ELSE R1%=2%*R1%
460 IF D<T NEXT J
470 GOSUB 540 : POKE 64769%,0% : RETURN 
480 REM MENY
490 ; CHR$(12%) : READ R9$ : ; TAB((39%-LEN(R9$))/2%)R9$ : ; : ; : ; 'V[LJ:'
500 FOR I9%=1% TO N9% : READ R9$ : ; CUR(6%+2%*I9%,3%)I9%;TAB(6%)R9$ : NEXT I9%
510 ONERRORGOTO 510 : ; CUR(4%,5%)SPACE$(35%);CUR(4%,5%); : INPUTLINE R9$ : R9$=LEFT$(R9$,LEN(R9$)-2%)
520 I9%=VAL(R9$) : IF I9%<1% OR I9%>N9% 510
530 ; CUR(6%+2%*I9%,2%)CHR$(127%) : ONERRORGOTO 0 : RETURN 
540 D=H : POKE 64786%,D,SWAP%(D) : RETURN 
550 D=D+256% : POKE 64786%,D,SWAP%(D) : RETURN 
560 ; CHR$(7%)'K L A R T !' : POKE 65056%,H,SWAP%(H) : END