1 REM Ins{nd av Lars Davidsson <7020>    1986-09-28 19.55.14 (SEND)
10 ! Program MULTLOG.BAC av Tomas Enblom
20 ! 
30 EXTEND 
40 Z$=CHR$(245%,229%,221%,229%,213%,221%,225%,221%,70%,4%,221%,110%,2%,221%,102%,3%)
50 Z$=Z$+CHR$(167%,126%,23%,119%,35%,16%,250%,221%,225%,225%,241%,201%)
60 ; CHR$(12)
70 FOR I%=0% TO 22% : PUT STRING$(40,ASCII('*'))+CHR$(13,10) : NEXT I% 
80 FOR I=4 TO 22-4
90   ; CUR(I,4) SPACE$(40-8)
100 NEXT I 
110 L$=""
120 ! 
130 ! PATH = X$
140 ! X$="DR1:"
150 ! 
160 ; CUR(6,8) 'Login:'; : L$=FNInput$(10)
170 IF LEN(L$)<10% THEN L$=L$+SPACE$(10%-LEN(L$))
180 ; CUR(8,8) 'Password:'; : GOSUB 610
190 P$=LEFT$(P$,LEN(P$)-1) : IF LEN(P$)<10% THEN P$=P$+SPACE$(10%-LEN(P$))
200 Z%=CALL(VARPTR(Z$),VAROOT(P$))
210 ! 
220 ! 
230 ! 
240 OPEN X$+'user' AS FILE 1%
250 GET #1%,M9$ COUNT 1%
260 FOR I%=1% TO ASCII(M9$)
270   GET #1%,L1$ COUNT 10%
280   GET #1%,P1$ COUNT 10%
290   IF (L1$=L$) AND (P1$=P$) THEN 350
300 NEXT I% 
310 GOTO 510
320 ! 
330 ! 
340 ! 
350 ; CUR(22,0) '****';SPACE$(40-8);'****'
360 ; '****';SPACE$(40-8);'****'
370 ; '****';SPACE$(40-8);'****'
380 ; '****     Multi-user activated       ****'
390 ; '****';SPACE$(40-8);'****'
400 ; '****               av               ****'
410 ; '**** Lars Davidsson & Tomas Enblom  ****'
420 ; '****';SPACE$(40-8);'****'
430 ; '****    1986-09-06     ver 1.0      ****'
440 ; '****';SPACE$(40-8);'****'
450 ; '****';SPACE$(40-8);'****'
460 ; '****      ';TIME$;'       ****'
470 ; : ; : ; : ; : ; : ; : ; : ; 
480 POKE 65413,PEEK(64512),PEEK(64513)
490 CHAIN "NULL:"
500 END 
510 ! 
520 ! 
530 ! 
540 ; 
550 ; '****                                ****'
560 ; '****    illegal login               ****'
570 CLOSE 1%
580 GOTO 110
590 ! 
600 ! 
610 ! 
620 P$=""
630 A$=""
640 WHILE A$<>CHR$(13)
650   GET A$
660   P$=P$+A$
670 WEND 
680 RETURN 
690 ! 
700 DEF FNInput$(M%)
710   S$="" : GET C$
720   WHILE C$<>CHR$(13%)
730     L%=LEN(S$)
740     IF C$=CHR$(8%) AND L% THEN S$=LEFT$(S$,LEN(S$)-1%) : PUT CHR$(8%,32%,8%)
750     IF C$=CHR$(24%) AND L% THEN FOR I%=1% TO L% : PUT CHR$(8%,32%,8%) : NEXT I% : S$=""
760     IF C$>=" " AND C$<="" AND L%<M% THEN S$=S$+C$ : PUT C$
770     GET C$
780   WEND 
790   RETURN S$
800 FNEND