1 REM PGM DIRFIX av Jon Kleiser  ]TERSKAPAR LIB SP]RET, BRA 
10 REM ************************
20 REM * DIRFIX.BAC           *
30 REM * VER 1.0 / 1981-01-28 *
40 REM * (C) ---------------- *
50 REM * gjort av Jon Kleiser *
60 REM * mod av ------------- *
70 REM * innsendt av J.K.     *
80 REM ************************
90 REM 
100 REM Programmets funksjon er } gjen-
110 REM skape directory (track 2,
120 REM hovedtrack) p} grunnlag av
130 REM track 1 (reserve).
140 REM 
150 ; CHR$(12%);
160 ; "*** DIRFIX - directory fix ***"
170 ; : ; 
180 DIM B$=256%,S$(2%)=256%
190 B$=SPACE$(256%)
200 A%=PEEK(65065%)+256%*PEEK(65066%)
210 POKE A%+6%,62720%,SWAP%(62720%)
220 ; "HVILKEN DRIVE BRUKES ? (0/1) ";
230 GET D$ : ; D$ : ; : ; 
240 POKE -767%,VAL(D$)
250 PRINT "VELG FUNKSJON :" : ; 
260 PRINT "  1) BYTT OM HOVED- OG ";
270 PRINT "RESERVE-TRACK"
280 PRINT "     (test s} skiven)" : ; 
290 PRINT "  2) KOPIER FRA HOVED- ";
300 PRINT "TIL RESERVE-TRACK";
310 PRINT "     ___" : ; 
320 PRINT "  3) Kopier direkte fra ";
330 PRINT "reserve- til"
340 PRINT "     hoved-track" : ; : ; 
350 PRINT "  ";
360 GET F$
370 IF F$<"1" OR F$>"3" THEN 360
380 PRINT F$"  - TRYKK RETURN ";
390 GET R$ : ; CUR(18%,7%)TAB(19%)
400 FOR S%=0% TO 7%
410 REM LES
420 FOR T%=1% TO 2%
430 Z%=CALL(24678%,SWAP%(T%)+32%*S%)
440 IF PEEK(-747%)=0% THEN 470
450 ; CUR(18%,7%)CHR$(7%)"LESEFEIL  "
460 GOTO 430
470 S$(T%)=B$
480 NEXT T%
490 REM SKRIV
500 T1%=2%
510 FOR T%=1% TO 2%
520 IF T%=1% AND F$="2" THEN 600
530 IF T%=2% AND F$="3" THEN 590
540 B$=S$(T%)
550 Z%=CALL(24675%,SWAP%(T1%)+32%*S%)
560 IF PEEK(-747%)=0% THEN 590
570 ; CUR(18%,7%)CHR$(7%)"SKRIVEFEIL"
580 GOTO 540
590 T1%=1%
600 NEXT T%
610 NEXT S%
620 PRINT CUR(18%,7%)"UTF\RT    " : ; 
630 END