6 REM KONVERTERING AV BIN[RA,OKTALA,DECIMALA ELLER HEXDECIMALA TAL
7 REM TILL BIN[RA,OKTALA,DECIMALA ELLER HEXDECIMALA TAL
8 REM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
10 DIM B(16),N(17),B$(16)
11 GET V$ : ; CHR$(12);TAB(12)"*** OMVANDLA ***"
12 ; CUR(2,0)"TALBAS F\R INPUT:" : ; CUR(2,18)"BIN[R    (B) "
13 ; CUR(3,18)"OKTAL    (O)" : ; CUR(4,18)"DECIMAL  (D)" : ; CUR(5,18)"HEX      (H)"
14 ; CUR(2,30)" "; : GET I$ : ; I$
15 ; CUR(7,0)"TALBAS F\R OUTPUT:" : ; CUR(7,18)"BIN[R    (B) "
16 ; CUR(8,18)"OKTAL    (O)" : ; CUR(9,18)"DECIMAL  (D)" : ; CUR(10,18)"HEX      (H)"
17 ; CUR(7,30)" "; : GET F$ : ; F$
18 ; CUR(11,0)""
20 IF I$="B" THEN 200
25 IF I$="O" THEN 300
30 IF I$="H" THEN 400
35 REM I$="D"
40 ; "SKRIV DECIMALTALET : "; : INPUT N(1)
45 IF F$="H" THEN 150
50 IF F$="O" THEN 100
53 IF F$="D" THEN ; N(1) : ; : GOTO 11
55 REM F$="B"
60 FOR K%=1 TO 16
65 M=2^(16%-K%)
70 B(K%)=INT(N(K%)/M) : N(K%+1)=N(K%)-B(K%)*M
75 ; B(K%);
80 NEXT K%
85 ; : ; : GOTO 11
90 REM F$="O"
100 FOR K%=1 TO 6
105 M=8^(6%-K%)
110 O(K%)=INT(N(K%)/M) : N(K%+1)=N(K%)-O(K%)*M
115 ; O(K%);
120 NEXT K%
125 ; : ; : GOTO 11
145 REM F$="H"
150 FOR K%=1 TO 4
155 M=16^(4%-K%)
160 H(K%)=INT(N(K%)/M) : N(K%+1)=N(K%)-H(K%)*M
165 Q$="ABCDEF"
170 A=H(K%)-9
173 IF A>=1 THEN ; " ";MID$(Q$,A,1); : GOTO 180
175 ; H(K%);
180 NEXT K%
190 ; : ; : GOTO 11
200 REM I$="B"
205 ; "SKRIV DET BIN[RA TALET : "; : INPUT B$
210 D=0 : J%=LEN(B$)
215 FOR K%=1 TO J%
220 M=2^(J%-K%)
225 IF MID$(B$,K%,1)="0" THEN 235
230 D=D+M
235 NEXT K%
240 N(1)=D
243 IF F$="B" THEN 60
245 IF F$="O" THEN 100
250 IF F$="H" THEN 150
255 ; D; : GOTO 11
295 REM I$="O"
300 ; "SKRIV DET OKTALA TALET : "; : INPUT O$
305 D=0 : J%=LEN(O$)
310 FOR K%=1 TO J%
315 M=8^(J%-K%)
320 O(K%)=VAL(MID$(O$,K%,1))
325 D=D+O(K%)*M
330 NEXT K%
335 GOTO 240
400 REM I$="H"
405 ; "SKRIV HEXTALET : "; : INPUT H$
410 D=0 : J%=LEN(H$)
415 FOR K%=1 TO J%
420 M=16^(J%-K%)
425 H(K%)=ASC(MID$(H$,K%,1))-55
430 IF H(K%)<=9 THEN H(K%)=H(K%)+7
435 D=D+H(K%)*M
440 NEXT K%
445 GOTO 240