1 REM  MADE BY MATS WALLIN                   810820                  
2 DIM X2%(11%)
3 RANDOMIZE 
4 G%=1%
5 REM 
6 REM  V[RD 
7 H%=18% : B%=17% : J%=1% : A2%=RND*125%+25% : P$=" (,,, "
8 RESTORE 
9 FOR A%=1% TO 11% : READ X2%(A%) : NEXT A%
10 DATA 3,6,9,12,15,18,21,24,27,30,33
11 IF G%=0% THEN \=3% : P1%=0%
12 REM 
13 REM  GRAF 
14 ; CHR$(12%) : FOR A%=1% TO 24% : ; : ; CHR$(151%); : NEXT A%
15 REM 
16 REM  RAM 
17 FOR A%=4% TO 72% : SETDOT 0%,A% : SETDOT 1%,A% : NEXT A%
18 FOR A%=0% TO 60% : SETDOT A%,3% : SETDOT A%,4% : SETDOT A%,72% : SETDOT A%,73% : NEXT A%
19 IF G%=1% THEN FOR A%=3% TO 72% : FOR A1%=0% TO 1% : SETDOT 18%*3%+A1%,A% : NEXT A1% : NEXT A%
20 ; CUR(22%,0%)"Po{ng: "P1%TAB(15%)"Bollar kvar:"INT(\);
21 ; CUR(23%,0%)"Rekord:"P2%; : IF G%=1% THEN ; CUR(19%,11%)"TRYCK P] RETURN"; ELSE ; CUR(18%,17%)P$
22 REM 
23 REM  BRICK 
24 P9$="pp0pp0pp0pp0pp0pp0pp0pp0pp0pp0pp0"
25 FOR A%=1% TO 5% : ; CUR(A%,3%)P9$; : NEXT A%
26 REM 
27 REM  V[RD 
28 P$=" (,,, " : P1$="    " : T$="   " : P%=0% : H%=18% : B%=17%
29 Y=25% : X=37% : Y1%=25% : X1%=37%
30 K1=.7
31 K2=RND*2%-1% : IF (K2<0% AND K2>-.15) OR (K2>0% AND K2<.15) THEN 31
32 REM 
33 REM  START 
34 IF P%+P1%>P2% AND P%+P1%<10%+P2% AND G%=0% THEN ; CUR(10%,13%)"NYTT REKORD" : O0%=1% ELSE O0%=0%
35 IF J%=1% THEN FOR A1%=1% TO A2%
36 FOR A%=1% TO 35% : NEXT A%
37 IF G%=1% THEN IF INP(56%)=141% THEN G%=0% : GOTO 6
38 REM 
39 REM  SPELARE 
40 I%=INP(56%)
41 IF I%=214% AND B%>1% THEN B%=B%-1% ELSE IF I%=205% AND B%<31% THEN B%=B%+1%
42 IF G%=1% THEN 49 ELSE IF I%<128% THEN 46
43 IF B%<>1% AND B%<>31% THEN ; CUR(H%,B%)P$CUR(H%,2%)"5" : GOTO 46
44 IF B%=1% THEN ; CUR(H%,B%+1%)"=,,, "
45 IF B%=31% THEN ; CUR(H%,B%)" (,,,"
46 IF J%=1% THEN NEXT A1% : J%=0% : GOTO 33
47 IF O0%=1% THEN ; CUR(10%,13%)SPACE$(11%)
48 REM 
49 REM  BOLL 
50 Y=Y+K1 : Y%=Y : X=X+K2 : X%=X
51 IF P%=55% THEN IF G%=0% THEN J%=1% : \=\+.5 : P1%=P1%+P% : GOTO 13 ELSE 13
52 IF Y%<>Y1% OR X%<>X1% THEN IF DOT(Y%,X%) THEN 59
53 IF Y%>62% THEN IF INT(\)>0% THEN J%=1% : A2%=RND*125%+25% : \=\-1% ELSE 93 ELSE 56
54 CLRDOT Y1%,X1% : ; CUR(22%,27%)INT(\);
55 GOTO 29
56 IF Y%<>Y1% OR X%<>X1% THEN SETDOT Y%,X% : CLRDOT Y1%,X1% : Y1%=Y% : X1%=X%
57 GOTO 33
58 REM 
59 REM  STUDS 
60 IF X%<>X1% AND Y%<>Y1% THEN IF DOT(Y-K1,X%) AND DOT(Y%,X-K2) THEN 62
61 GOTO 64
62 K1=-K1 : K2=-K2 : OUT 6%,0% : OUT 6%,131% : GOTO 49
63 REM  V]GR[T 
64 IF X%<>X1% THEN IF DOT(Y-K1,X%) THEN K2=-K2 ELSE 71 ELSE 71
65 IF X%<5% OR X%>71% THEN OUT 6%,0% : OUT 6%,131% : GOTO 49
66 IF Y%>40% THEN OUT 6%,0% : OUT 6%,133% : GOTO 49
67 OUT 6%,0% : OUT 6%,137% : P%=P%+1%
68 IF K2>0% THEN ; CUR(Y%/3%,X%/2%-2%)T$; ELSE ; CUR(Y%/3%,X%/2%)T$;
69 GOTO 90
70 REM  LODR[T 
71 IF DOT(Y%,X-K2) THEN K1=-K1 ELSE 82
72 IF Y%<2% THEN OUT 6%,0% : OUT 6%,131% : GOTO 49
73 IF Y%>40% THEN OUT 6%,0% : OUT 6%,133% : GOTO 49
74 OUT 6%,0% : OUT 6%,137% : P%=P%+1%
75 X2%=X%/2%
76 FOR A1%=0% TO 2%
77 FOR A%=1% TO 11% : IF X2%-A1%=X2%(A%) THEN 79
78 NEXT A% : NEXT A1%
79 ; CUR(Y%/3%,X2%-A1%)T$;
80 GOTO 90
81 REM  VERTIKAL 
82 K1=-K1 : K2=-K2
83 IF Y%>40% THEN OUT 6%,0% : OUT 6%,133% : GOTO 90
84 OUT 6%,0% : OUT 6%,137% : P%=P%+1%
85 X2%=X%/2%
86 FOR A1%=0% TO 2%
87 FOR A%=1% TO 11% : IF X2%-A1%=X2%(A%) THEN 89
88 NEXT A% : NEXT A1%
89 ; CUR(Y%/3%,X2%-A1%)T$;
90 IF G%=0% THEN ; CUR(22%,7%)P1%+P%;
91 GOTO 49
92 REM 
93 REM  SLUT 
94 G%=1%
95 P1%=P1%+P% : IF P1%>P2% THEN P2%=P1%
96 GOTO 13